major rework

[dotfiles.git] / base / .zshenv

export ZDOTDIR=${XDG_CONFIG_HOME:-~/.config}/zsh

### load site-specific
[[ -f ${ZDOTDIR:-~}/.zshenv.local ]] && source ${ZDOTDIR:-~}/.zshenv.local

### fix broken term
if [[ ! -v TERM ]] {
    TERM=xterm-256color >/dev/null 2>&1
}
if [[ -o interactive && $#terminfo -eq 0 ]] {
    _oldterm=$TERM
    export TERM=xterm >/dev/null 2>&1
    print -P "%F{red}!!! Can't find terminfo for $_oldterm, using $TERM%f"
    unset _oldterm
}

if [[ -o login ]] {
    ### cd on login shell for convenience
    # NOTE: we do this here and not in .zprofile since we occasionally might
    # re-source .zprofile, and it's easier to just put the logic here...
    cd ~
} else {
    if [[ ! -v _sev_first_display && ( -v DISPLAY || -v WAYLAND_DISPLAY ) ]] {
        ### update gpgagent to use graphical pinentry
        # XXX: will be sourced by every new child shell if zsh is not used to
        #      start the graphical session and the _sev_first_disaply var isn't
        #      exported; for example, this happens with sway without a display
        #      manager or launcher in front of it
        export _sev_first_display=
        _sev_refresh_gpgagent= source ${ZDOTDIR:-~}/.zprofile
    } elif [[ $SHLVL == 1 ]] {
        ### early zprofile sourcing for first shell even if not a login shell
        # NOTE: ensure profile is loaded for toplevel shells; should hopefully be 1
        #       under some Xorg or cron implementations, which is where this would be most useful
        source ${ZDOTDIR:-~}/.zprofile
    }
}

# vim: et sts=4 sw=4 ts=8 tw=79