zprofile: remove unnecessary variable

[dotfiles.git] / base / .zshenv

### load site-specific
[[ -f ~/.zshenv.local ]] && source ~/.zshenv.local

### fix broken term
if [[ -o interactive && $#terminfo -eq 0 ]] {
    _oldterm=$TERM
    TERM=xterm-256color >/dev/null 2>&1
    print -P "%F{red}!!! Can't find terminfo for $_oldterm, using $TERM%f"
    unset _oldterm
}

if [[ -o login ]] {
    ### cd on login shell for convenience
    cd ~
} else {
    if [[ ! -v _sev_first_display && ( -v DISPLAY || -v WAYLAND_DISPLAY ) ]] {
        # this is to allow gpg and pinentry env to be updated
        # XXX: will be sourced by every new child shell if zsh is not used to
        #      start the graphical session, but since .zprofile is light that
        #      shouldn't cause a noticeable performance impact
        # NOTE: above happens with sway without a display manager or launcher
        export _sev_first_display=
        source ${ZDOTDIR:-~}/.zprofile
        export _sev_first_display=0
    } elif [[ $SHLVL == 1 ]] {
        ### early zprofile sourcing for first shell
        # NOTE: ensure profile is loaded for toplevel shells; should hopefully be 1
        #       under some Xorg or cron implementations, which is where this would be most useful
        source ${ZDOTDIR:-~}/.zprofile
    }
}

# vim: et sts=4 sw=4 ts=8 tw=79