sway: also bind kp_enter to terminal

[dotfiles.git] / base / .zshenv

### load site-specific
[[ -f ~/.zshenv.local ]] && source ~/.zshenv.local

### fix broken term
if (( $#terminfo == 0 )) {
    [[ -o interactive ]] &&
      print -P "%F{red}!!! Can't find terminfo for $TERM, using xterm%f"
    TERM=xterm
}

### early zprofile sourcing
# NOTE: see comments in .zprofile for additional rationale for this
if [[ ! -o login ]] {
    if [[ -v _sev_olduser && $_sev_olduser != $USERNAME ]] {
        # set up some user-dependent stuff since we switched users
        # XXX: _sev_switched_users is no longer implemented
        _sev_switched_users= source ${ZDOTDIR:-~}/.zprofile
    } elif [[ $SHLVL == 1 ]] {
        # ensure profile is loaded for toplevel shells; should hopefully be 1
        # under Xorg or cron, which is where this would be most useful
        source ${ZDOTDIR:-~}/.zprofile
    }
} else {
    # for convenience
    cd ~
}
export _sev_olduser=$USERNAME

# vim: et sts=4 sw=4 ts=8 tw=79