etc/zsh/.zshrc

   1 ### options
   2 setopts=(
   3   ## 16.2.1  Changing Directories
   4   AUTO_CD CDABLE_VARS
   5   ## 16.2.2  Completion
   6   COMPLETE_IN_WORD GLOB_COMPLETE REC_EXACT
   7   ## 16.2.3  Expansion and Globbing
   8   EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MAGIC_EQUAL_SUBST MARK_DIRS
   9   NUMERIC_GLOB_SORT
  10   ## 16.2.4  History
  11   # NOTE: NO_HIST_SAVE_BY_COPY to allow saving histfile if updating another
  12   #       user's histfile. this is for compatibility with zsu.
  13   HIST_FCNTL_LOCK HIST_IGNORE_DUPS HIST_IGNORE_SPACE HIST_LEX_WORDS
  14   HIST_NO_STORE HIST_REDUCE_BLANKS NO_HIST_SAVE_BY_COPY SHARE_HISTORY
  15   ## 16.2.6  Input/Output
  16   NO_CLOBBER CLOBBER_EMPTY CORRECT_ALL INTERACTIVE_COMMENTS
  17   HASH_EXECUTABLES_ONLY
  18   ## 16.2.7  Job Control
  19   AUTO_CONTINUE LONG_LIST_JOBS
  20   ## 16.2.12 Zle
  21   NO_BEEP
  22 )
  23 setopt $setopts
  24 unset setopts
  25
  26 ### exports
  27 ## common
  28 export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
  29 export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
  30 ## grep
  31 # XXX: deprecated in GNU
  32 export GREP_OPTIONS=--color=auto
  33 ## histfile
  34 export HISTFILE=~/.histfile
  35 export HISTSIZE=10000
  36 export SAVEHIST=$HISTSIZE
  37 ## python
  38 export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
  39 ## vim
  40 export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"|execute"source"$MYVIMRC'
  41
  42 ### imports
  43 autoload -Uz zmv
  44 autoload -Uz zmathfunc && zmathfunc
  45
  46 ## vcs
  47 zstyle ':vcs_info:*' enable git
  48 #zstyle ':vcs_info:git*' check-for-changes true #too slow
  49 zstyle ':vcs_info:git*:dotfiles' check-for-changes true
  50 zstyle ':vcs_info:git*' check-for-staged-changes true
  51 autoload -Uz vcs_info
  52
  53 ## compinit
  54 zstyle ':completion:*' auto-description '[arg] %d'
  55 zstyle ':completion:*' expand suffix
  56 zstyle ':completion:*' format '# %d'
  57 zstyle ':completion:*' group-name ''
  58 zstyle ':completion:*' ignore-parents parent
  59 zstyle ':completion:*' insert-unambiguous false
  60 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
  61 zstyle ':completion:*' list-prompt '%B%i%b'
  62 zstyle ':completion:*' list-suffixes true
  63 zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
  64 zstyle ':completion:*' menu select=1
  65 zstyle ':completion:*' original false
  66 zstyle ':completion:*' select-prompt '%B%l%b'
  67 zstyle ':completion:*' verbose true
  68 autoload -Uz compinit
  69 cache=${XDG_CACHE_HOME:-~/.cache}/zsh
  70 [[ -d $cache ]] || mkdir -p $cache
  71 compinit -d $cache/.zcompdump
  72 unset cache
  73
  74 ### keys
  75 ## set up zkbd-style key array
  76 if [[ ! -v _sev_force_zkbd && ( -v terminfo || -v termcap ) ]] {
  77     # use application (keypad transmit) mode if the terminal supports it
  78     # NOTE: we have to do this because termcap/terminfo keys are usually
  79     #       defined in application mode. terminals that do not define these
  80     #       capabilities are assumed to always be in application mode.
  81     if [[ ( -v terminfo[smkx] && -v terminfo[rmkx] ) ||
  82           ( -v termcap[ks]    && -v terminfo[ke] ) ]] {
  83         autoload -Uz add-zle-hook-widget
  84         function _enter-application-mode {
  85             [[ -v terminfo[smkx] ]] && echoti smkx || echotc ks
  86         }
  87         add-zle-hook-widget line-init _enter-application-mode
  88         function _exit-application-mode {
  89             [[ -v terminfo[rmkx] ]] && echoti rmkx || echotc ke
  90         }
  91         add-zle-hook-widget line-finish _exit-application-mode
  92         trap _exit-application-mode EXIT
  93     }
  94     # pull keys from terminfo/termcap
  95     # TODO: Menu and more Shift- modifiers
  96     typeset -gA key
  97     typeset -lA newkey
  98     if [[ -v terminfo ]] {
  99         src=terminfo
 100         newkey=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
 101                 F10 kf10 F11 kf11 F12 kf12
 102                 Backspace kbs
 103                 Shift-Tab kcbt
 104                 Insert    kich1
 105                 Home      khome
 106                 PageUp    kpp
 107                 Delete    kdch1
 108                 End       kend
 109                 PageDown  knp
 110                 Up        kcuu1
 111                 Down      kcud1
 112                 Left      kcub1
 113                 Right     kcuf1
 114         )
 115     } elif [[ -v termcap ]] {
 116         src=termcap
 117         newkey=(F1 k1 F2 k2 F3 k3 F4 k4 F5 k5 F6 k6 F7 k7 F8 k8 F9 k9
 118                 F10 k\; F11 F1 F12 F2
 119                 Backspace kb
 120                 Shift-Tab kB
 121                 Insert    kI
 122                 Home      kh
 123                 PageUp    kP
 124                 Delete    kD
 125                 End       @7
 126                 PageDown  kN
 127                 Up        ku
 128                 Down      kd
 129                 Left      kl
 130                 Right     kr
 131         )
 132     }
 133     for k v (${(kv)newkey}) {
 134         key[$k]=${${(P)src}[$v]}
 135     }
 136     unset k v src newkey
 137 } else {
 138     # use zkbd if termcap/terminfo unavailable
 139     function find_keymap {
 140         for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
 141             [[ -f $f ]] && keymap=$f && break
 142     }
 143     find_keymap
 144     if [[ -z $keymap ]] {
 145         if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
 146             echo
 147             autoload -Uz zkbd && zkbd
 148             unfunction zkbd
 149             find_keymap
 150         fi
 151         echo
 152     }
 153     if [[ -n $keymap ]] {
 154         source $keymap
 155     } else {
 156         echo -E "Failed to source keymap file $keymap" >&2
 157     }
 158     unfunction find_keymap; unset keymap
 159 }
 160
 161 ## load history search
 162 autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
 163 zle -N up-line-or-beginning-search
 164 zle -N down-line-or-beginning-search
 165
 166 ## bind keys in both viins and vicmd modes
 167 # NOTE: cursor keys are bound to normal/raw/nontransmit mode strings by
 168 #       default, and keys like Home and End are not bound at all, so we rebind
 169 #       everything to cover all scenarios
 170 typeset -A a
 171 a=(
 172     #key       viins                         vicmd
 173     Backspace 'backward-delete-char          vi-backward-char'
 174     Insert    'overwrite-mode                vi-insert'
 175     Home      'beginning-of-line'
 176     PageUp    'up-history                    -'
 177     Delete    'delete-char'
 178     End       'end-of-line'
 179     PageDown  'down-history                  -'
 180     Up        'up-line-or-beginning-search   vi-up-line-or-history'
 181     Down      'down-line-or-beginning-search vi-down-line-or-history'
 182     Left      'backward-char'
 183     Right     'forward-char'
 184 )
 185 for k v (${(kv)a}) {
 186     k=$key[$k]
 187     if [[ -z $k ]] { continue }
 188     v=($=v)
 189     bindkey -- $k $v[1]
 190     if [[ $v[2] == - ]] {
 191         # copy viins to vicmd verbatim
 192         bindkey -a -- $k $v[1]
 193     } elif (( $#v != 1 )) {
 194         # set vicmd to any other value
 195         bindkey -a -- $k $v[2]
 196     } else {
 197         # copy viins to vicmd and prepend vi- to it
 198         bindkey -a -- $k vi-$v[1]
 199     }
 200 }
 201 unset a k v
 202
 203 ### aliases
 204 ## builtins
 205 alias rehash='_sev_setpath; rehash'
 206 ## utils
 207 alias h='fc -l -25'
 208 alias j='jobs -l'
 209 alias l='ls -AF'
 210 if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
 211     alias ll='ls -lAFho'
 212 } else {
 213     alias ll='ls -lAFh'
 214 }
 215 alias p=\$PAGER
 216 alias e=\$EDITOR
 217 alias se=sudoedit
 218 alias syncwatch='sync & watch -d grep -Fe Dirty: -e Writeback: /proc/meminfo'
 219 if [[ -v commands[grep] ]] {
 220     [[ -v commands[fgrep] ]] || alias fgrep='grep -F'
 221     [[ -v commands[egrep] ]] || alias fgrep='grep -E'
 222 }
 223 for x (cat cmp diff grep test update) {
 224     [[ -v commands[zutils-z$x] ]] || alias z$x=zutils-z$x
 225 }
 226 # be paranoid
 227 alias cp='cp -ip'
 228 alias mv='mv -i'
 229 # zsh zmv with noglob wildcards
 230 alias zm='noglob zmv -WiM'
 231 alias zc='noglob zmv -WiC'
 232 alias zl='noglob zmv -WiL'
 233 alias sm='noglob zmv -Wip"sudo mv"'
 234 alias sc='noglob zmv -Wip"sudo cp"'
 235 alias sl='noglob zmv -Wip"sudo ln"'
 236 if [[ "$OSTYPE" =~ '^freebsd' ]] {
 237     # don't confirm if only a few files are deleted
 238     alias rm='rm -I'
 239 } else {
 240     # TODO: similar behavior for non-freebsd, or impliment in zsh
 241     alias rm='rm -i'
 242 }
 243 [[ -v commands[trash-put] ]] && alias t=trash-put
 244 # ps
 245 if [[ -v commands[pstree] && $commands[pstree]:A:t != busybox ]] {
 246     # use pstree, but NOT busybox pstree because it kinda sucks
 247     ps="pstree -wg3"
 248 } elif [[ "$OSTYPE" =~ '^freebsd' ]] {
 249     ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
 250        -o%cpu,%mem,tty,stat,start=START -oetime,command"
 251 } elif [[ $commands[ps]:A:t == busybox ]] {
 252     # busybox compatible
 253     ps="ps -eouser='USR     ' -ogroup='GRP     ' \
 254        -opid='  PID' -onice=' NI' -ovsz=' MEM' \
 255        -otty,stat,etime,comm"
 256 } else {
 257     # XXX: untested, posix
 258     # TODO: support gnu ps
 259     ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
 260        -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
 261 }
 262 if [[ "$(basename "$PAGER")" = "less" ]] {
 263     ps="$ps | less -S"
 264 } else {
 265     ps="$ps | \"${PAGER:-more}\""
 266 }
 267 alias pa=$ps
 268 alias spa="sudo $ps"
 269 unset ps
 270 ## py venv
 271 alias va='source bin/activate'
 272 alias vd=deactivate
 273 alias vu="python3 -mvenv --upgrade"
 274 alias svu="sudo python3 -mvenv --upgrade"
 275 ## git
 276 alias g=git
 277 alias gd='git diff'
 278 alias gdh='git diff HEAD'
 279 alias ga='git add'
 280 alias ga.='git add .'
 281 alias gc='git commit'
 282 alias gca='git commit --amend'
 283 alias gp='git push'
 284 alias gu='git pull'
 285 alias gl='git log'
 286 alias gt='git tree' # from gitconfig
 287 ## cd/zoxide
 288 function up {
 289     \cd $(printf '../%.0s' {1..${1:-1}})
 290 }
 291 alias u=up
 292 if [[ -v commands[zoxide] ]] {
 293     # https://github.com/ajeetdsouza/zoxide/issues/513
 294     eval "${$(zoxide init zsh):s#_files -/#_cd#}"
 295     alias cd=z
 296 }
 297 alias cd..=up
 298 ## dotfiles
 299 alias dfu='function {
 300     pushd -q ${$(echo -E - ~/.zshenv):P:h:h}
 301     git pull &&
 302     git submodule init &&
 303     git submodule sync &&
 304     git submodule update
 305     popd -q
 306 }'
 307 ## nocorrect
 308 # zsh doesnt really handle sudo very well, so ignore it
 309 alias sudo='nocorrect sudo'
 310 ## docker compose
 311 alias dcp='sudo docker compose pull'
 312 alias dcu='sudo docker compose up -d'
 313 alias dcr='sudo docker compose restart'
 314 alias dcl='sudo docker compose logs -f'
 315
 316 ### hooks
 317 autoload -Uz add-zsh-hook
 318 typeset -gi _sev_exectime
 319 function sev_preexec {
 320     # change terminal title to show command
 321     print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
 322     # save last exec time for bell
 323     # XXX: does not run for blank cmdline
 324     _sev_exectime=$SECONDS
 325     # update gpg forward, to always have unique filename and avoid clashes
 326     if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
 327         export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
 328         export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
 329     }
 330 }
 331 add-zsh-hook preexec sev_preexec
 332 function sev_precmd {
 333     # change terminal title
 334     # TODO: update and send BEL when job status changes
 335     print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
 336     # bell if exec takes 5s
 337     if (( SECONDS - _sev_exectime >= 5 )) print "\a"
 338     # we could update vcs_info here, but let prompt take care of it
 339     # if it doesn't use vcs, it can be ignored safely
 340 }
 341 add-zsh-hook precmd sev_precmd
 342 function sev_chpwd {
 343     # echo dir on cwd change
 344     ls -AF
 345 }
 346 add-zsh-hook chpwd sev_chpwd
 347
 348 ### system-specific configs and aliases
 349 case $OSTYPE; in
 350     freebsd*)
 351         ## colors
 352         export CLICOLOR=
 353         export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'
 354
 355         ## sound
 356         function s { sysctl hw.snd.default_unit${1:+\=$1} }
 357         alias vol mixer
 358
 359         ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
 360         # XXX: should probably use package-depends where possible, breaks when
 361         #      port name is different to package name
 362         #      (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
 363         function portpkg {
 364             case "$1" {
 365             build|run)
 366                 sudo pkg install -AU $(make ${1}-depends-list |
 367                            sed 's_/usr/ports/_ _' | tr -d '\n')
 368                 ;;
 369             *)  echo "Usage: \`portpkg <build|run>' in a port directory"
 370                 return 1;;
 371             }
 372         };;
 373     netbsd)
 374         ## sound
 375         function s {
 376             if [[ -z "$1" ]] {
 377                 ll /dev/mixer /dev/sound /dev/audio
 378                 return
 379             }
 380             for x in mixer sound audio; do
 381                 ln -sf /dev/$x"$1" /dev/$x
 382             done
 383         }
 384         function vol {
 385             if [[ -z "$1" ]] {
 386                 for x in $(mixerctl -a | grep 'outputs\.master'); do
 387                     echo -E - $x
 388                 done
 389                 return
 390             }
 391             mixerctl -w outputs.master"$2"="$1"
 392         };;
 393     *)
 394         ## sound
 395         # TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
 396         function s {}
 397         function vol {}
 398 esac
 399
 400 ### prompt
 401 autoload -Uz promptinit && promptinit
 402 prompt arrows
 403
 404 ### load site-specific
 405 load-site-dotfile zshrc