base/.zshrc

   1 ### imports
   2 source ~/bin/.check-busybox
   3
   4 ### user-local fpath
   5 fpath=(~/.zsh ~/.zsh/functions/Prompts "${fpath[@]}")
   6
   7 ### options
   8 setopt NO_BEEP NO_CLOBBER
   9 ## cd
  10 setopt AUTO_CD CDABLE_VARS
  11 ## completion
  12 setopt GLOB_COMPLETE
  13 ## line
  14 setopt EXTENDED_GLOB GLOB_DOTS MARK_DIRS NOMATCH NUMERIC_GLOB_SORT
  15 ## prompt
  16 setopt PROMPT_SUBST
  17 ## jobs
  18 setopt AUTO_CONTINUE
  19 ## history
  20 setopt NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY
  21 HISTFILE=~/.histfile
  22 HISTSIZE=1000
  23 SAVEHIST=1000
  24
  25 ### keys
  26 bindkey -v
  27 KEYTIMEOUT=1
  28 ## xorg
  29 bindkey    "^[[7~" beginning-of-line #Home
  30 bindkey -a "^[[7~" beginning-of-line
  31 bindkey    "^[[8~" end-of-line       #End
  32 bindkey -a "^[[8~" end-of-line
  33 bindkey    "^[[3~" delete-char       #Del
  34 bindkey -a "^[[3~" delete-char
  35 ## history search
  36 autoload -Uz up-line-or-beginning-search down-line-or-beginning-search && {
  37     if [[ -n "$key[Up]" ]] {
  38         zle -N up-line-or-beginning-search
  39         bindkey -- "$key[Up]"   up-line-or-beginning-search
  40     }
  41     if [[ -n "$key[Down]" ]] {
  42         bindkey -- "$key[Down]" down-line-or-beginning-search
  43         zle -N down-line-or-beginning-search
  44     }
  45 }
  46
  47 ### aliases
  48 alias h="history -25"
  49 alias j="jobs -l"
  50 alias l="ls -AF"
  51 alias e="${EDITOR:-vi}" # TODO: make sure vi is there or use safe default
  52 if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
  53     alias ll="ls -lAFho"
  54 } else {
  55     alias ll="ls -lAFh"
  56 }
  57 ## ps
  58 local p=
  59 if which pstree >/dev/null 2>&1 && ! check-busybox pstree; then
  60     # use pstree, but NOT busybox pstree because it kinda sucks
  61     p="pstree -wg3"
  62 elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
  63     p="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
  64        -o%cpu,%mem,tty,stat,start=START -oetime,command"
  65 elif check-busybox ps; then
  66     # busybox compatible
  67     p="ps -eouser='USR     ' -ogroup='GRP     ' \
  68        -opid='  PID' -onice=' NI' -ovsz=' MEM' \
  69        -otty,stat,etime,comm"
  70 else
  71     # XXX: untested, posix
  72     # TODO: support gnu ps
  73     p="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
  74        -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
  75 fi
  76 if [[ "$(basename "$PAGER")" = "less" ]] {
  77     p="$p | less -SE"
  78 } else {
  79     p="$p | \"${PAGER:-more}\""
  80 }
  81 alias pa="$p"
  82 alias spa="sudo $p"
  83 unset p
  84 ## py venv
  85 alias va="source bin/activate"
  86 alias vd="deactivate"
  87 ## be paranoid
  88 alias cp='cp -ip'
  89 alias mv='mv -i'
  90 if [[ "$OSTYPE" =~ '^freebsd' ]] {
  91     # don't confirm if only a few files are deleted
  92     alias rm='rm -I'
  93 } else {
  94     # TODO: similar behavior for non-freebsd, or impliment in zsh
  95     alias rm='rm -i'
  96 }
  97 ## go up directories
  98 function up() {
  99     cd $(printf '../%.0s' {1..${1:-1}})
 100 }
 101
 102 ### hooks
 103 local _exectime=
 104 function precmd {
 105     # change terminal title
 106     # TODO: update and send BEL when job status changes
 107     print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
 108     # bell if exec takes 5s
 109     if ((SECONDS - _exectime >= 5)) print "\a"
 110     # we could update vcs_info here, but let prompt take care of it
 111     # if it doesn't use vcs, it can be ignored safely
 112 }
 113 function preexec {
 114     # change terminal title to show command
 115     print -Pnf "\e]2;%s\e\\" "%#${SSH_CLIENT+$USER@$HOST:}$1"
 116     # save last exec time for bell
 117     # XXX: does not run for blank cmdline
 118     _exectime=$SECONDS
 119 }
 120 function chpwd {
 121     # echo dir on cwd change
 122     l
 123 }
 124
 125 ### system-specific configs and aliases
 126 case "$OSTYPE"; in
 127     freebsd*)
 128         ## vt binds
 129         bindkey    "^[[H" beginning-of-line  #Home
 130         bindkey -a "^[[H" beginning-of-line
 131         bindkey    "^[[F" end-of-line        #End
 132         bindkey -a "^[[F" end-of-line
 133
 134         ## sound
 135         function s { sysctl hw.snd.default_unit${1:+\=$1} }
 136         alias vol mixer
 137
 138         ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
 139         #XXX: should probably use package-depends where possible, breaks when
 140         #     port name is different to package name
 141         #     (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
 142         function portpkg {
 143             case "$1" {
 144             build|run)
 145                 sudo pkg install -AU $(make ${1}-depends-list |
 146                            sed 's_/usr/ports/_ _' | tr -d '\n')
 147                 ;;
 148             *)  echo "Usage: \`portpkg <build|run>' in a port directory"
 149                 return 1;;
 150             }
 151         };;
 152     netbsd)
 153         ## sound
 154         function s {
 155             if [[ -z "$1" ]] {
 156                 ll /dev/mixer /dev/sound /dev/audio
 157                 return
 158             }
 159             for x in mixer sound audio; do
 160                 ln -sf /dev/$x"$1" /dev/$x
 161             done
 162         }
 163         function vol {
 164             if [[ -z "$1" ]] {
 165                 for x in $(mixerctl -a | grep 'outputs\.master'); do
 166                     echo $x
 167                 done
 168                 return
 169             }
 170             mixerctl -w outputs.master"$2"="$1"
 171         };;
 172     *)
 173         ## sound
 174         # TODO: test alsa/oss/sndio/portaudio/pulse in order of importance
 175         function s() {}
 176         function vol() {}
 177 esac
 178
 179 ### modules & styles
 180 ## vcs
 181 autoload -Uz vcs_info
 182 zstyle ':vcs_info:*' enable git
 183 #zstyle ':vcs_info:git*' check-for-changes true #too slow
 184 zstyle ':vcs_info:git*:dotfiles' check-for-changes true
 185 zstyle ':vcs_info:git*' check-for-staged-changes true
 186
 187 ## compinit
 188 # The following lines were added by compinstall
 189 zstyle ':completion:*' auto-description '[arg] %d'
 190 zstyle ':completion:*' expand suffix
 191 zstyle ':completion:*' format '# %d'
 192 zstyle ':completion:*' group-name ''
 193 zstyle ':completion:*' ignore-parents parent
 194 zstyle ':completion:*' insert-unambiguous false
 195 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
 196 zstyle ':completion:*' list-prompt '%B%i%b'
 197 zstyle ':completion:*' list-suffixes true
 198 zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
 199 zstyle ':completion:*' menu select=1
 200 zstyle ':completion:*' original false
 201 zstyle ':completion:*' select-prompt '%B%l%b'
 202 zstyle ':completion:*' verbose true
 203 zstyle :compinstall filename '/home/ds6/.zshrc'
 204
 205 autoload -Uz compinit
 206 compinit
 207 # End of lines added by compinstall
 208
 209 ## prompt
 210 # do this last so prompt can potentially override
 211 autoload -Uz promptinit && promptinit
 212 prompt arrows
 213
 214
 215 ### unset imports
 216 unfunction check-busybox
 217
 218 # vim: set et sts=4 sw=4 ts=8 tw=79 :