etc/vim/.vimrc

   1 """ paths
   2 "" config dir in xdg config
   3 let x = ($XDG_CONFIG_HOME??($HOME.'/.config')).'/vim'
   4 execute 'set runtimepath='.x.','.&runtimepath.','.x.'/after'
   5 execute 'set packpath='.x.','.&packpath.','.x.'/after'
   6
   7 "" state files in xdg state
   8 let x = ($XDG_STATE_HOME??($HOME.'/.local/state')).'/vim'
   9 if !isdirectory(x)
  10     call mkdir(x, 'p', 0700)
  11 endif
  12
  13 " backup
  14 " NOTE: keep backup files in vim state dir for both vim and neovim
  15 let y = x.'/backup'
  16 if !isdirectory(y)
  17     call mkdir(y, 'p', 0700)
  18 endif
  19 execute 'set backupdir='.y.'//'
  20 set backup backupcopy=yes
  21
  22 " NOTE: neovim uses ShaDa (SHAred DAta) format for viminfo and swap, and uses a
  23 "       different version of undo file, so these types of files when created by
  24 "       vim cannot be used with neovim, and the 'viminfofile', 'directory', and
  25 "       'undodir' directories cannot be shared.
  26 " NOTE: neovim has a nice default for these directories and files so
  27 "       customizing them is not necessary for it.
  28 if !has('nvim')
  29     " viminfo
  30     " NOTE: 'viminfofile' is a deprecated alias for 'shada' in neovim
  31     execute 'set viminfofile='.x.'/.viminfo'
  32
  33     " swap
  34     let y = x.'/swap'
  35     if !isdirectory(y)
  36         call mkdir(y, 'p', 0700)
  37     endif
  38     execute 'set directory='.y.'//'
  39
  40     " undo
  41     let y = x.'/undo'
  42     if !isdirectory(y)
  43         call mkdir(y, 'p', 0700)
  44     endif
  45     execute 'set undodir='.y.'//'
  46 endif
  47
  48 unlet x
  49 unlet y
  50
  51
  52 """ vim-only defaults
  53 if !has('nvim')
  54     " neovim defaults are already set
  55     source $VIMRUNTIME/defaults.vim
  56
  57     " disable jumping to last edit, we use vim-lastplace instead
  58     autocmd! vimStartup
  59
  60     " packages
  61     packadd! matchit        " included with [n]vim but disabled by default
  62     packadd! editorconfig   " now included with [n]vim but disabled by default
  63     packadd! vim-commentary " nvim has this built in now, vim still needs it
  64
  65     " options
  66     set hlsearch
  67     autocmd BufRead * set autoindent
  68 endif
  69
  70
  71 """ styling
  72 " nice default theme
  73 colorscheme murphy
  74
  75 " always use color column with less intrusive colors
  76 autocmd VimEnter,WinNew * set colorcolumn=80
  77 " always use cursor line for better visibility
  78 autocmd VimEnter,WinNew * set cursorline
  79
  80 " unique highlighting for leading spaces and in-line spaces
  81 " NOTE: this leaves tabs and other special whitespace untouched intentionally
  82 autocmd VimEnter,ColorScheme * highlight SpaceInner ctermfg=Grey guifg=#686868
  83 autocmd VimEnter,ColorScheme * highlight link SpaceOuter NonText
  84 autocmd VimEnter,WinNew * match SpaceInner / /
  85 autocmd VimEnter,WinNew * 2match SpaceOuter /\(^ \+\)\|\( \+$\)/
  86
  87 " always show statusline
  88 set laststatus=2
  89
  90 " truncate > lastline; lastline is nvim default, sensible.vim may also set it
  91 set display=truncate
  92
  93 " more context while scrolling
  94 set scrolloff=5
  95 set sidescrolloff=8
  96
  97 " show number column on all buffers
  98 autocmd VimEnter,WinNew * set number
  99 " use relative numbers in normal modes when focused, but not if number is off
 100 function! s:SetRelativeNumber(enable)
 101     if !getwinvar(winnr(), '&number')
 102         return
 103     endif
 104     if a:enable
 105         set relativenumber
 106     else
 107         set norelativenumber
 108     endif
 109 endfunction
 110 autocmd InsertEnter,FocusLost,WinLeave * call s:SetRelativeNumber(0)
 111 autocmd VimEnter,WinNew,
 112        \InsertLeave,FocusGained,WinEnter * call s:SetRelativeNumber(1)
 113
 114 " always show custom listchars
 115 autocmd VimEnter,WinNew * set list
 116 set listchars=tab:├─,extends:»,precedes:«,space:·,trail:∙,nbsp:■
 117
 118
 119 """ editor
 120 " always save undo file for all file buffers
 121 autocmd BufReadPre * setlocal undofile
 122
 123 " explicitly use modeline, even on systems where it's disabled by system vimrc
 124 autocmd BufRead * set modeline
 125 " should be default disabled but just in case
 126 set nomodelineexpr
 127
 128 "" indent
 129 " always use shiftwidth instead of tabsize
 130 set smarttab
 131 " filetype preferences
 132 autocmd FileType python     set softtabstop=4 shiftwidth=4 expandtab
 133 autocmd FileType markdown   set softtabstop=4 shiftwidth=4 expandtab
 134 autocmd FileType javascript set softtabstop=2 shiftwidth=2 expandtab
 135 autocmd FileType json       set softtabstop=2 shiftwidth=2 expandtab
 136 autocmd FileType html       set softtabstop=2 shiftwidth=2 expandtab
 137 let g:EditorConfig_enable_for_new_buf = 1
 138
 139 "" syntax
 140 autocmd Syntax php          syn clear phpHereDoc phpNowDoc
 141
 142 "" mappings
 143 " use more accessible escapes, as C-n and C-o are shadowed by some terminals
 144 if has('nvim')
 145     tnoremap <C-\>n <C-\><C-N>
 146     tnoremap <C-\>o <C-\><C-O>
 147 endif
 148
 149 " move windows any time
 150 if has('nvim')
 151     " terminal
 152     tnoremap <A-h> <C-\><C-N><C-w>h
 153     tnoremap <A-j> <C-\><C-N><C-w>j
 154     tnoremap <A-k> <C-\><C-N><C-w>k
 155     tnoremap <A-l> <C-\><C-N><C-w>l
 156 endif
 157 " insert
 158 inoremap <A-h> <C-\><C-N><C-w>h
 159 inoremap <A-j> <C-\><C-N><C-w>j
 160 inoremap <A-k> <C-\><C-N><C-w>k
 161 inoremap <A-l> <C-\><C-N><C-w>l
 162 " normal
 163 nnoremap <A-h> <C-w>h
 164 nnoremap <A-j> <C-w>j
 165 nnoremap <A-k> <C-w>k
 166 nnoremap <A-l> <C-w>l
 167
 168 "" CTRL-L to clear highlighting and also update diff
 169 " NOTE: sensible.vim and nvim already do this, so copy sensible.vim
 170 "       functionality if it hasn't been set or we aren't nvim. taken from
 171 "       sensible.vim by Tim Pope, under Vim license; see :help license
 172 "       https://github.com/tpope/vim-sensible/blob/0ce2d843d6f588bb0c8c7eec6449171615dc56d9/plugin/sensible.vim#L57
 173 if !has('nvim') && maparg('<C-L>', 'n') ==# ''
 174   nnoremap <silent> <C-L> :nohlsearch<C-R>=has('diff')?'<Bar>diffupdate':''<CR><CR><C-L>
 175 endif
 176
 177
 178 """ package config
 179 "" suda
 180 " https://github.com/lambdalisue/vim-suda/issues/32#issuecomment-829608925
 181 if ! &diff
 182     let g:suda_smart_edit = 1
 183 endif
 184 " re-enable backup, swap, undo for suda buffers that we can read
 185 " https://github.com/lambdalisue/vim-suda/issues/25
 186 function s:SudaSettingsSave()
 187     let b:sev_suda_backup = &backup
 188     let b:sev_suda_swapfile = &swapfile
 189     let b:sev_suda_undofile = &undofile
 190 endfunction
 191 function s:SudaSettingsRestore()
 192     if filereadable(expand('<afile>')[7:])
 193         if exists('b:sev_suda_backup') && b:sev_suda_backup
 194             " XXX: suda.vim uses setlocal for this, even though it's global...
 195             "      https://github.com/lambdalisue/vim-suda/issues/85
 196             setlocal backup
 197         endif
 198         if exists('b:sev_suda_swapfile') && b:sev_suda_swapfile
 199             setlocal swapfile
 200         endif
 201         if exists('b:sev_suda_undofile') && b:sev_suda_undofile
 202             setlocal undofile
 203         endif
 204     endif
 205 endfunction
 206 autocmd BufReadPre suda://* call s:SudaSettingsSave()
 207 autocmd BufReadPost suda://* call s:SudaSettingsRestore()