etc/zsh/.zshenv

   1 ### functions
   2 ## cleanup
   3 # XXX: only call after relevant vars have been set up, defined early so that
   4 #      below code can utilize it after they do so
   5 function _sev_zcleanup {
   6     local x p y
   7
   8     # gpg forwarding
   9     if [[ -d $_sev_gpg_forward_dir && ( -z $1 || $1 == 'gpg-forward' ) ]] {
  10         # clean up forward dirs if its session is dead or we ask for it
  11         find $_sev_gpg_forward_dir -mindepth 1 -maxdepth 1 -type d |
  12           while {read -r x} {
  13             # NOTE: the only way we can get here is if we have not been
  14             #       forwarded before, if the user asks for it, or during
  15             #       logout. if our own pid already has a dir, it is most likely
  16             #       stale, the user wants it removed, or something is very
  17             #       broken—in all 3 of these cases the best choice is remove it.
  18             p=$(basename $x)
  19             if {[[ -v _sev_gpg_forward_clean || $$ == $p ]] ||
  20                     ! kill -0 $p 2>/dev/null} {
  21                 find $x -mindepth 1 -maxdepth 1 | while {read -r y} {
  22                     # XXX: real dirs will stop unlink, consider it a feature
  23                     unlink $y
  24                 }
  25                 # don't force in case something important is still there
  26                 rmdir $x
  27             }
  28         }
  29         # reset GNUPGHOME if we removed our own dir
  30         if [[ $GNUPGHOME =~ '/.ssh_forward/\d+/*$' && ! -d $GNUPGHOME ]]
  31             GNUPGHOME=${GNUPGHOME%$MATCH}
  32     }
  33
  34     # custom tmp
  35     # NOTE: _sev_tmp is not unset so session dirs will not be recreated if
  36     #       called during runtime; unset _sev_tmp and re-source to fix
  37     # NOTE: XDG dirs that use our tmp are not unset here, they are in zlogout
  38     #       after this function is called
  39     if [[ -d $_sev_tmp && ( -z $1 || $1 == 'tmp' ) ]] {
  40         # clean up tmp dirs if its session is dead or we ask for it
  41         find $_sev_tmp -mindepth 1 -maxdepth 1 -name '.session.*' -type d |
  42           while {read -r x} {
  43             # NOTE: same rationale as above
  44             p=${$(basename $x)#.session.}
  45             if {[[ -v _sev_tmp_clean || $$ == $p ]] ||
  46                     ! kill -0 $p 2>/dev/null} {
  47                 rm -rf $x
  48             }
  49         }
  50     }
  51 }
  52
  53 function _sev_setpath {
  54     # add as many generic paths as possible to keep the order we want
  55     # NOTE: tied arrays path and fpath already exist, but are not unique (-U);
  56     #       we utilize the fact that unique arrays keep the first occurrence
  57     #       and remove any further occurences to check for elements from the
  58     #       old PATH that we did not anticipate and shift them to the front,
  59     #       since they are probably important to the system
  60     typeset -gU path fpath
  61     local -a syspath=("$path[@]")
  62     # NOTE: /usr/{pkg,games} are unix/bsdisms
  63     # NOTE: some systems (esp. research machines) may have multiple versions of
  64     #       packages installed in /opt/[pkg]/[ver]/bin or other dirs, managed
  65     #       with something like Environment Modules. this code does not account
  66     #       for this type of usage and will add all valid paths. any undesired
  67     #       paths can be removed using .zshenv.local.
  68     # XXX: PREFIX not validated, non-POSIX but Termux uses it, maybe others
  69     # XXX: XDG specifies ~/.local/bin as the only user-writable dir for
  70     #      executables, but we specify more; technically this is against spec
  71     path=({{${_sev_home:-~},~}{/.local,},{$PREFIX,}{,/usr{,/local,/pkg},/opt{,/*{/*,}}}}/{s,}bin(N)
  72           {$PREFIX,}/usr/{X11R{7,6}/bin,games}
  73           # emulate Arch Linux flatpak-bindir.sh for use on other systems
  74           {${XDG_DATA_HOME:-~/.local/share},{$PREFIX,}/var/lib}/flatpak/exports/bin)
  75     local -i i len=$#path
  76     path=("$path[@]" "$syspath[@]")
  77     # remove bad paths
  78     for (( i = 1; i <= $#path; i++ )) {
  79         if [[ ! -d $path[$i] ]] {
  80             path[$i]=()
  81             ((i <= len)) && ((len--))
  82             ((i--))
  83             continue
  84         }
  85     }
  86     # shift valid system paths to the front if there are any left
  87     ((len > 0 && len < $#path)) && path=("${(@)path[len + 1, -1]}" "${(@)path[1, len]}")
  88     # include our zsh dir in fpath. unlike above, we always prefer our paths
  89     fpath=({${ZDOTDIR:-~/.zsh},{${_sev_home:-~},~}/.zsh}/functions/**/*(/N) "$fpath[@]")
  90     # remove bad paths
  91     for (( i = 1; i <= $#fpath; i++ )) {
  92         if [[ ! -d $fpath[$i] ]] {
  93             fpath[$i]=()
  94             ((i--))
  95             continue
  96         }
  97     }
  98     # FPATH is not exported by default
  99     export FPATH
 100     # un-unique system arrays for consistency
 101     typeset +U path fpath
 102 }
 103
 104 ### common exports
 105 export CHARSET=${CHARSET:-UTF-8}
 106 export LANG=${LANG:-en_US.UTF-8}
 107
 108 ## alternative home for pulling in bin & config, used for zsu
 109 [[ -v _sev_home ]] || export _sev_home=$HOME
 110
 111 ## fix broken term
 112 # NOTE: we do this here instead of .zshrc since we might print stuff
 113 if [[ -t 1 ]] { # only if stdout is tty
 114     [[ ! -v TERM ]] && export TERM=xterm-256color >/dev/null 2>&1
 115     if [[ $#terminfo -eq 0 ]] {
 116         _oldterm=$TERM
 117         export TERM=xterm >/dev/null 2>&1
 118         [[ -o interactive ]] &&
 119           print -P "%F{red}!!! Can't find terminfo for $_oldterm, using $TERM%f"
 120         unset _oldterm
 121     }
 122 }
 123
 124 ## path
 125 if [[ ! -v _sev_setup_path || -o login ]] {
 126     _sev_setpath
 127     # NOTE: do not set _sev_setup_path, it is set in zprofile
 128 }
 129
 130 ### home dir setup & exports
 131 # XXX: traditionally, zshenv should just contain exports, and not touch the
 132 #      filesystem. however, some system profile scripts that are sourced in the
 133 #      system zprofile may attempt to do things that rely on some of these
 134 #      vars. for example, `flatpak-bindir.sh` in the Arch Linux flatpak package
 135 #      references $XDG_DATA_HOME with no fallback. since we do special handling
 136 #      for these vars before we export them, we're forced to do it all here
 137 #      instead of zprofile.
 138
 139 ## xdg local dir
 140 # NOTE: need this for tmp, so confirm it exists.
 141 # XXX: perms are not specified for XDG dirs except runtime, but I think 760
 142 #      makes the most sense. shouldn't break anything since no one else should
 143 #      be poking around in our dir.
 144 [[ -e ~/.local ]] || mkdir -m760 ~/.local
 145
 146 ## tmp
 147 # NOTE: specs say that POSIX tmp and XDG runtime directories should exist
 148 #       until the last session is logged out (POSIX can exist for longer).
 149 #       since we can't reliably keep track of sessions in a cross-platform
 150 #       manner, the current implementation should use a separate directory per
 151 #       toplevel session (i.e. SHLVL=1). this should placate most applications,
 152 #       though it is not expressly spec compliant. this may also cause problems
 153 #       with disowned applications that still try to use the directories after
 154 #       the toplevel shell has already logged out and the dirs removed, but the
 155 #       chances of that are slim.
 156 if [[ ! -v _sev_tmp ]] {
 157     # create personal TMPDIR under system tmp
 158     t=${TMPDIR:-${TEMPDIR:-${TEMP:-${TMP:-${${TMPPREFIX%/zsh}:-/tmp}}}}}/.home-$LOGNAME
 159     [[ -e $t ]] || mkdir -m700 $t 2>/dev/null
 160     _sev_tmp=~/.local/tmp
 161     if [[ ! -d $t ]] {
 162         # fallback TMPDIR to bare local directory or existing softlink
 163         [[ -o interactive ]] &&
 164           print -P "%F{orange}*** Can't create tmp dir $t, using $_sev_tmp%f"
 165         [[ -h $_sev_tmp && ! -d _sev_tmp ]] && unlink $_sev_tmp 2>/dev/null
 166         [[ ! -e $_sev_tmp ]] && mkdir -m700 $_sev_tmp 2>/dev/null
 167         if [[ ! -d $_sev_tmp ]] {
 168             _sev_tmp=${$(mktemp 2>/dev/null):/tmp}
 169             [[ -o interactive ]] &&
 170               print -P "%F{red}!!! Can't create tmp dir, using $_sev_tmp%f"
 171         }
 172     } elif [[ -f $_sev_tmp || ( -d $_sev_tmp && ! -h $_sev_tmp ) ]] {
 173         # file or non-softlink directory is on our local dir
 174         [[ -o interactive ]] &&
 175           print -P "%F{orange}*** $_sev_tmp exists, can't link to tmp dir $t, ignoring it%f"
 176         _sev_tmp=$t
 177     } else {
 178         # link local dir to tmp dir
 179         if [[ -h $_sev_tmp && $_sev_tmp:P != $t:P ]] {
 180             [[ -o interactive ]] &&
 181               print -P "%F{orange}*** $_sev_tmp links to ${_sev_tmp:P} and not ${t:P}, unlinking it%f"
 182             # XXX: race condition for existing sessions still using this dir
 183             unlink $_sev_tmp 2>/dev/null
 184         }
 185         ln -s $t $_sev_tmp 2>/dev/null
 186     }
 187     if [[ -v _sev_tmp ]] {
 188         # ensure dir is clean
 189         _sev_zcleanup tmp
 190         # finally create our subdir for this session
 191         t=$_sev_tmp/.session.$$
 192         if ! mkdir -m700 $t 2>/dev/null; then
 193             [[ -o interactive ]] &&
 194               print -P "%F{red}!!! Can't create session tmp subdir $t, using $_sev_tmp%f"
 195             t=$_sev_tmp
 196         fi
 197         export _sev_tmp TMPDIR=$t TEMPDIR=$t TEMP=$t TMP=$t TMPPREFIX=$t/zsh
 198     }
 199     unset t
 200 }
 201
 202 ## xdg
 203 if [[ ! -v _sev_setup_xdg ]] {
 204     ## merge with any existing dirs and remove duplicates using unique arrays
 205     # NOTE: we are accepting whatever value might be set for CONFIG and DATA;
 206     #       if it wasn't set, we just use default and leave it unset
 207     # NOTE: include and then remove CONFIG_HOME and DATA_HOME to ensure they
 208     #       are not present in the array if it was added before we got to it
 209
 210     # source user dirs before other vars; technically it is against spec to
 211     # include any of the below dirs there, but you never know what crazy shit
 212     # people will do. I rather handle them sanely with our own code than let
 213     # them override after the fact.
 214     [[ -f $XDG_CONFIG_HOME/user-dirs.dirs ]] &&
 215       emulate sh -c "source $XDG_CONFIG_HOME/user-dirs.dirs"
 216
 217     typeset -UT XDG_DATA_DIRS xdg_data_dirs
 218     if [[ -v XDG_DATA_HOME ]] {
 219         export XDG_DATA_HOME
 220     } elif [[ ! -e ~/.local/share ]] {
 221         mkdir -m760 ~/.local/share
 222     }
 223     xdg_data_dirs=($XDG_DATA_HOME /{opt,usr/local,usr/pkg,usr}/share
 224       ${XDG_DATA_DIRS:+${xdg_data_dirs%%/}})
 225     export XDG_DATA_DIRS
 226
 227     typeset -UT XDG_CONFIG_DIRS xdg_config_dirs
 228     if [[ -v XDG_CONFIG_HOME ]] {
 229         export XDG_CONFIG_HOME
 230     } elif [[ ! -e ~/.config ]] {
 231         mkdir -m760 ~/.config
 232     }
 233     # I am of the belief .local should follow FHS /usr/local...
 234     [[ -e ~/.local/etc ]] || ln -s ~/.config ~/.local/etc
 235     xdg_config_dirs=($XDG_CONFIG_HOME
 236       ${XDG_CONFIG_DIRS:+${xdg_config_dirs%%/}}
 237       {/opt,/usr/local,/usr/pkg,}/etc/xdg)
 238     export XDG_CONFIG_DIRS
 239
 240     if [[ -v XDG_STATE_HOME ]] {
 241         export XDG_STATE_HOME
 242     } elif [[ ! -e ~/.local/state ]] {
 243         mkdir -m760 ~/.local/state
 244     }
 245
 246     if [[ -v XDG_CACHE_HOME ]] {
 247         export XDG_CACHE_HOME
 248     } else {
 249         if [[ -v _sev_tmp ]] {
 250             export XDG_CACHE_HOME=$_sev_tmp/.xdg.cache
 251             [[ -e $XDG_CACHE_HOME ]] || mkdir -m700 $XDG_CACHE_HOME
 252         } elif [[ ! -e ~/.cache ]] {
 253             mkdir -m700 ~/.cache
 254         }
 255     }
 256
 257     if [[ -v XDG_RUNTIME_DIR ]] {
 258         # NOTE: this can be set by systemd or other pre-shell supervisor, and
 259         #       if any services were started such as pipewire, we need to use
 260         #       the existing runtime dir so that we can get any existing
 261         #       program sockets or other data
 262         export XDG_RUNTIME_DIR
 263     } elif [[ -v TMPDIR ]] {
 264         # make runtime dir in our session-specific tmpdir
 265         export XDG_RUNTIME_DIR=$TMPDIR/.xdg.runtime
 266         # same as in tmpdir creation, ensure dir doesn't exist
 267         if [[ -h $XDG_RUNTIME_DIR ]] {
 268             unlink $XDG_RUNTIME_DIR 2>/dev/null
 269         } elif [[ -e $XDG_RUNTIME_DIR ]] {
 270             rm -rf $XDG_RUNTIME_DIR 2>/dev/null
 271         }
 272         mkdir -m700 $XDG_RUNTIME_DIR 2>/dev/null
 273     }
 274
 275     export _sev_setup_xdg=
 276 }
 277
 278 ### app setup & exports
 279 # NOTE: we set these up here since some scripts might need them
 280 ## gpg home
 281 if [[ ! -v GNUPGHOME ]] {
 282     export GNUPGHOME=${XDG_CONFIG_HOME:-~/.config}/gnupg
 283     # move existing gnupg dir to our new home
 284     if [[ -d ~/.gnupg && ! -d $GNUPGHOME ]] {
 285         mv ~/.gnupg $GNUPGHOME
 286     }
 287 }
 288
 289 ## perl local lib
 290 [[ ! -v PERL_LOCAL_LIB_ROOT && -v commands[perl] &&
 291    -d $XDG_DATA_HOME/perl5/lib/perl5 ]] &&
 292   eval $(perl -I$XDG_DATA_HOME/perl5/lib/perl5 \
 293               -Mlocal::lib=$XDG_DATA_HOME/perl5 2>/dev/null)
 294
 295 ## go
 296 if [[ -v commands[go] ]] {
 297     [[ ! -v GOPATH ]] && export GOPATH=${XDG_DATA_HOME:-~/.local/share}/go:~/go
 298     [[ ! -v GOBIN  ]] && export GOBIN=~/.local/bin
 299 }
 300
 301 ### load zshenv site-specific
 302 autoload -Uz load-site-dotfile
 303 load-site-dotfile zshenv
 304
 305 ### source .zprofile early for non-login shells that should be
 306 if [[ ! -v _sev_first_display && ( -v DISPLAY || -v WAYLAND_DISPLAY ) ]] {
 307     # most graphical login/session managers will spawn the user's shell as a
 308     # parent of all child processes for that session. however, if the parent shell
 309     # isn't a login shell for some reason, our .zprofile won't be run, and the
 310     # environment won't be configured for child processes.
 311     #
 312     # XXX: .zprofile will be sourced by every new child shell if zsh is not
 313     #      used to start the graphical session and the _sev_first_display var
 314     #      isn't exported; for example, this previously happened when using
 315     #      sway without a display manager in front of it to run a login shell.
 316     #
 317     #      this issue is not mitigated by .zprofile only loading what has not
 318     #      already been loaded if the env vars preventing the load are not set;
 319     #      in that case, every shell will think it is a fresh login shell.
 320
 321     # update gpgagent to use graphical pinentry
 322     # XXX: will steal display from any other logged in graphical sessions, but
 323     #      I consider this to be an unlikely scenario
 324     _sev_refresh_gpgagent=
 325
 326     export _sev_first_display=
 327     [[ ! -o login ]] && source ${ZDOTDIR:-~}/.zprofile
 328 } elif [[ ${+TERMUX_VERSION} -eq 0 && ! -o login && $SHLVL -eq 1 ]] {
 329     # Termux first process isn't login shell, so source early
 330     source ${ZDOTDIR:-~}/.zprofile
 331 }