update submodules, remove bsd shims, fix bugs

[dotfiles.git] / base / .zshrc

### options
setopt autocd extendedglob
unsetopt beep

### history
setopt appendhistory
HISTFILE=~/.histfile
HISTSIZE=100
SAVEHIST=100

### keys
bindkey -v
KEYTIMEOUT=1
## xorg
bindkey    "^[[7~" beginning-of-line #Home
bindkey -a "^[[7~" beginning-of-line
bindkey    "^[[8~" end-of-line       #End
bindkey -a "^[[8~" end-of-line
bindkey    "^[[3~" delete-char       #Del
bindkey -a "^[[3~" delete-char
## history search
autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search
[[ -n "$key[Up]"   ]] && bindkey -- "$key[Up]"   up-line-or-beginning-search
[[ -n "$key[Down]" ]] && bindkey -- "$key[Down]" down-line-or-beginning-search

### aliases
alias h="history -25"
alias j="jobs -l"
alias l="ls -AF"
if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
    alias ll="ls -lAFho"
} else {
    alias ll="ls -lAFh"
}
## ps
local p=""
if { which pstree >/dev/null 2>&1 && [[ ! "$(readlink -f $(which pstree))" =~ "/busybox" ]] } {
    p="pstree -wg3"
} elif [[ "$OSTYPE" =~ '^freebsd' ]] {
    p="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
       -o%cpu,%mem,tty,stat,start=START -oetime,command"
} elif [[ "$(readlink -f $(which ps))" =~ "/busybox" ]] {
    # busybox compatible
    p="ps -eouser='USR     ' -ogroup='GRP     ' \
       -opid='  PID' -onice=' NI' -ovsz=' MEM' \
       -otty,stat,etime,comm"
} else {
    # XXX: untested, posix
    # TODO: support gnu ps
    p="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
       -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
}
p="$p | ${PAGER:-more} -Se"
alias pa="$p"
alias spa="sudo $p"
unset p
## py venv
alias va="source bin/activate"
alias vd="deactivate"
## be paranoid
alias cp='cp -ip'
alias mv='mv -i'
if [[ "$OSTYPE" =~ '^freebsd' ]] {
    # don't confirm if only a few files are deleted
    alias rm='rm -I'
} else {
    # TODO: similar behavior for non-freebsd
    alias rm='rm -i'
}

### prompt
setopt prompt_subst
# DEPR: color reset added to NetBSD in PR/53245, following is not needed for recent releases
#local f=
#XXX: can't think of a way to tell if ssh client is on wscons, just kludge 24/7
#if [[ "$OSTYPE" = "netbsd" && ( "$TERM" =~ "^wsvt" || "$TERM" =~ '^vt' ) ]] {
#    # fix for wscons
#    f="%F{white}"
#} else {
#    f="%f"
#}
PROMPT='%F{$VICOL}%n%f@%F{$VICOL}%2m%f%(?../%F{red}$?%f)%# '
RPROMPT='%F{yellow}${vcs_info_msg_0_:-%~}%f %T'

## change color based on zle vi mode
function zle-line-init zle-keymap-select {
    VICOL="${${KEYMAP:/vicmd/red}:/(main|viins)/green}"
    zle reset-prompt
}
zle -N zle-line-init
zle -N zle-keymap-select

## vcs
autoload -Uz vcs_info
zstyle ':vcs_info:*' enable git
zstyle ':vcs_info:git*' formats '%c%u%%F{green}%r/%b%%F{white}/%%F{yellow}%S%%f'
zstyle ':vcs_info:git*' actionformats '%%F{red}(%a)%f %c%u%%F{green}%r/%b%f/%%F{yellow}%S%f'
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true
zstyle ':vcs_info:git*' stagedstr   "%F{blue}+"
zstyle ':vcs_info:git*' unstagedstr "%F{red}*"

#unset f

### hooks
local _exectime=
function precmd {
    # change terminal title
    print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
    # update vcs
    vcs_info
    # bell if exec takes 5s
    if ((SECONDS - _exectime >= 5)) print "\a"
}
function preexec {
    # change terminal title to show command
    print -Pnf "\e]2;%s\e\\" "%#${SSH_CLIENT+$USER@$HOST:}$1"
    # save last exec time for bell
    # XXX: does not run for blank cmdline
    _exectime=$SECONDS
}
function chpwd {
    # echo dir on cwd change
    l
}

### system-specific configs and aliases
case "$OSTYPE"; in
    freebsd*)
        ## vt binds
        bindkey    "^[[H" beginning-of-line  #Home
        bindkey -a "^[[H" beginning-of-line
        bindkey    "^[[F" end-of-line        #End
        bindkey -a "^[[F" end-of-line

        ## sound
        function s { sysctl hw.snd.default_unit${1:+\=$1} }
        alias vol mixer

        ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
        #XXX: should probably use package-depends where possible, breaks when
        #     port name is different to package name
        #     (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
        function portpkg {
            case "$1" {
            build|run)
                sudo pkg install -AU $(make ${1}-depends-list |
                           sed 's_/usr/ports/_ _' | tr -d '\n')
                ;;
            *)  echo "Usage: \`portpkg <build|run>' in a port directory"
                return 1;;
            }
        };;
    netbsd)
        ## sound
        function s {
            if [[ -z "$1" ]] {
                ll /dev/mixer /dev/sound /dev/audio
                return
            }
            for x in mixer sound audio; do
                ln -sf /dev/$x"$1" /dev/$x
            done
        }
        function vol {
            if [[ -z "$1" ]] {
                for x in $(mixerctl -a | grep 'outputs\.master'); do
                    echo $x
                done
                return
            }
            mixerctl -w outputs.master"$2"="$1"
        };;
    *)
        ## sound
        # TODO: test alsa/oss/sndio/portaudio/pulse in order of importance
esac

# The following lines were added by compinstall
zstyle ':completion:*' auto-description 'specify: %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
zstyle :compinstall filename '/home/ds6/.zshrc'

autoload -Uz compinit
compinit
# End of lines added by compinstall

# vim: ts=8:sts=4:sw=4:et:tw=79