reorganized tint2, i3->volumeicon vol control

[dotfiles.git] / base / .zshrc

# modules
autoload -Uz vcs_info
zstyle ':vcs_info:*' enable git
zstyle ':vcs_info:*' get-revision true
zstyle ':vcs_info:git*' formats "(%F{green}%r/%b%f) %m%u%c "

function precmd {
    print -Pn "\e]0;${SSH_CLIENT+$USER@$HOST}%#%(1j,:%j,):%~\a"
    vcs_info
    if ((SECONDS - _exectime >= 5)) {
        # bell after long exec
        print "\a"
    }
}
function preexec {
    printf "\033]0;%s\a" "$1"
    _exectime=$SECONDS
}

# prompt
setopt prompt_subst
PROMPT='%F{$VICOL}%n%f@%F{$VICOL}%m%f%(?../%F{red}$?%f)%# '
RPROMPT='${vcs_info_msg_0_}%F{yellow}%~%f %T'

function zle-line-init zle-keymap-select {
    VICOL="${${KEYMAP:/vicmd/red}:/(main|viins)/green}"
    zle reset-prompt
}
zle -N zle-line-init
zle -N zle-keymap-select

# common aliases
alias h="history -25"
alias j="jobs -l"
alias la="ls -aF"
alias lf="ls -AF"
alias ll="ls -lhAF"
alias pa="sudo ps -Sudax"
function s { sysctl hw.snd.default_unit=$1 }

# be paranoid
alias cp='cp -ip'
alias mv='mv -i'
alias rm='rm -I'

# venv
alias activate="source bin/activate"

# ports
function portpkg {
    case "$1" {
        build|run) ;;
        *)
            echo "Usage: \`portpkg <build|run>' in a port directory"
            return 1;;
    }
    sudo pkg install -AU $(make ${1}-depends-list | sed 's_/usr/ports/_ _' | tr -d '\n')
}

# keys
bindkey "^[[7~" beginning-of-line #Home
bindkey "^[[8~" end-of-line       #End
bindkey "^[[3~" delete-char       #Del
# vt keys
bindkey "^[[H" beginning-of-line #Home
bindkey "^[[F" end-of-line       #End

autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search
[[ -n "$key[Up]"   ]] && bindkey -- "$key[Up]"   up-line-or-beginning-search
[[ -n "$key[Down]" ]] && bindkey -- "$key[Down]" down-line-or-beginning-search

# The following lines were added by compinstall
zstyle ':completion:*' auto-description 'specify: %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
zstyle :compinstall filename '/home/ds6/.zshrc'

autoload -Uz compinit
compinit
# End of lines added by compinstall

# Lines configured by zsh-newuser-install
HISTFILE=~/.histfile
HISTSIZE=100
SAVEHIST=100
setopt appendhistory autocd extendedglob
unsetopt beep
bindkey -v
# End of lines configured by zsh-newuser-install

# vim: ts=8:sts=4:sw=4:et:tw=79