[dotfiles.git] / etc / zsh / .zshrc

### options
setopt NO_BEEP NO_CLOBBER \
       AUTO_CD CDABLE_VARS \
       EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
       CORRECT_ALL INTERACTIVE_COMMENTS \
       GLOB_COMPLETE \
       AUTO_CONTINUE LONG_LIST_JOBS \
       NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS

### exports
## common
export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
## grep
# XXX: deprecated in GNU
export GREP_OPTIONS=--color=auto
## histfile
export HISTFILE=~/.histfile
export HISTSIZE=1000
export SAVEHIST=1000
## python
export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
## vim
export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"|execute"source"$MYVIMRC'

### imports
autoload -Uz zmv
autoload -Uz zmathfunc && zmathfunc

## vcs
zstyle ':vcs_info:*' enable git
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true
autoload -Uz vcs_info

## compinit
zstyle ':completion:*' auto-description '[arg] %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
autoload -Uz compinit
cache=${XDG_CACHE_HOME:-~/.cache}/zsh
[[ -d $cache ]] || mkdir -p $cache
compinit -d $cache/.zcompdump
unset cache

### keys
## set up zkbd-style key array
if [[ ! -v _sev_force_zkbd && ( -v terminfo || -v termcap ) ]] {
    # use application (keypad transmit) mode if the terminal supports it
    # NOTE: we have to do this because termcap/terminfo keys are usually
    #       defined in application mode. terminals that do not define these
    #       capabilities are assumed to always be in application mode.
    if [[ ( -v terminfo[smkx] && -v terminfo[rmkx] ) ||
          ( -v termcap[ks]    && -v terminfo[ke] ) ]] {
        autoload -Uz add-zle-hook-widget
        function _enter-application-mode {
            [[ -v terminfo[smkx] ]] && echoti smkx || echotc ks
        }
        add-zle-hook-widget line-init _enter-application-mode
        function _exit-application-mode {
            [[ -v terminfo[rmkx] ]] && echoti rmkx || echotc ke
        }
        add-zle-hook-widget line-finish _exit-application-mode
        trap _exit-application-mode EXIT
    }
    # pull keys from terminfo/termcap
    # TODO: Menu and more Shift- modifiers
    typeset -gA key
    typeset -lA newkey
    if [[ -v terminfo ]] {
        src=terminfo
        newkey=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
                F10 kf10 F11 kf11 F12 kf12
                Backspace kbs
                Shift-Tab kcbt
                Insert    kich1
                Home      khome
                PageUp    kpp
                Delete    kdch1
                End       kend
                PageDown  knp
                Up        kcuu1
                Down      kcud1
                Left      kcub1
                Right     kcuf1
        )
    } elif [[ -v termcap ]] {
        src=termcap
        newkey=(F1 k1 F2 k2 F3 k3 F4 k4 F5 k5 F6 k6 F7 k7 F8 k8 F9 k9
                F10 k\; F11 F1 F12 F2
                Backspace kb
                Shift-Tab kB
                Insert    kI
                Home      kh
                PageUp    kP
                Delete    kD
                End       @7
                PageDown  kN
                Up        ku
                Down      kd
                Left      kl
                Right     kr
        )
    }
    for k v (${(kv)newkey}) {
        key[$k]=${${(P)src}[$v]}
    }
    unset k v src newkey
} else {
    # use zkbd if termcap/terminfo unavailable
    function find_keymap {
        for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
            [[ -f $f ]] && keymap=$f && break
    }
    find_keymap
    if [[ -z $keymap ]] {
        if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
            echo
            autoload -Uz zkbd && zkbd
            unfunction zkbd
            find_keymap
        fi
        echo
    }
    if [[ -n $keymap ]] {
        source $keymap
    } else {
        echo -E "Failed to source keymap file $keymap" >&2
    }
    unfunction find_keymap; unset keymap
}

## load history search
autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search

## bind keys in both viins and vicmd modes
# NOTE: cursor keys are bound to normal/raw/nontransmit mode strings by
#       default, and keys like Home and End are not bound at all, so we rebind
#       everything to cover all scenarios
typeset -A a
a=(
    #key       viins                         vicmd
    Backspace 'backward-delete-char          vi-backward-char'
    Insert    'overwrite-mode                vi-insert'
    Home      'beginning-of-line'
    PageUp    'up-history                    -'
    Delete    'delete-char'
    End       'end-of-line'
    PageDown  'down-history                  -'
    Up        'up-line-or-beginning-search   vi-up-line-or-history'
    Down      'down-line-or-beginning-search vi-down-line-or-history'
    Left      'backward-char'
    Right     'forward-char'
)
for k v (${(kv)a}) {
    k=$key[$k]
    if [[ -z $k ]] { continue }
    v=($=v)
    bindkey -- $k $v[1]
    if [[ $v[2] == - ]] {
        # copy viins to vicmd verbatim
        bindkey -a -- $k $v[1]
    } elif (( $#v != 1 )) {
        # set vicmd to any other value
        bindkey -a -- $k $v[2]
    } else {
        # copy viins to vicmd and prepend vi- to it
        bindkey -a -- $k vi-$v[1]
    }
}
unset a k v

### aliases
## builtins
alias rehash='_sev_setpath; rehash'
## utils
alias h='fc -l -25'
alias j='jobs -l'
alias l='ls -AF'
if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
    alias ll='ls -lAFho'
} else {
    alias ll='ls -lAFh'
}
alias p=\$PAGER
alias e=\$EDITOR
alias se=sudoedit
# be paranoid
alias cp='cp -ip'
alias mv='mv -i'
alias zm='noglob zmv -WiM'
alias zc='noglob zmv -WiC'
alias zl='noglob zmv -WiL'
alias sm='noglob zmv -Wip"sudo mv"'
alias sc='noglob zmv -Wip"sudo cp"'
alias sl='noglob zmv -Wip"sudo ln"'
if [[ "$OSTYPE" =~ '^freebsd' ]] {
    # don't confirm if only a few files are deleted
    alias rm='rm -I'
} else {
    # TODO: similar behavior for non-freebsd, or impliment in zsh
    alias rm='rm -i'
}
[[ -v commands[trash-put] ]] && alias t=trash-put
## py venv
alias va='source bin/activate'
alias vd=deactivate
## ps
source ~/.local/bin/.check-busybox
if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
    # use pstree, but NOT busybox pstree because it kinda sucks
    ps="pstree -wg3"
elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
    ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
       -o%cpu,%mem,tty,stat,start=START -oetime,command"
elif check-busybox ps; then
    # busybox compatible
    ps="ps -eouser='USR     ' -ogroup='GRP     ' \
       -opid='  PID' -onice=' NI' -ovsz=' MEM' \
       -otty,stat,etime,comm"
else
    # XXX: untested, posix
    # TODO: support gnu ps
    ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
       -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
fi
unfunction check-busybox
if [[ "$(basename "$PAGER")" = "less" ]] {
    ps="$ps | less -S"
} else {
    ps="$ps | \"${PAGER:-more}\""
}
alias pa=$ps
alias spa="sudo $ps"
unset ps
## git
alias gd='git diff'
alias gdh='git diff HEAD'
alias ga='git add'
alias ga.='git add .'
alias gc='git commit'
alias gca='git commit --amend'
alias gp='git push'
alias gu='git pull'
## cd/zoxide
function up {
    \cd $(printf '../%.0s' {1..${1:-1}})
}
alias u=up
if [[ -v commands[zoxide] ]] {
    # https://github.com/ajeetdsouza/zoxide/issues/513
    eval "${$(zoxide init zsh):s#_files -/#_cd#}"
    alias cd=z
}
alias cd..=up
## dotfiles
alias dfu='d=${$(echo -E - ~/.zshenv):P:h:h};GIT_DIR=$d/.git GIT_WORK_TREE=$d {
  git pull &&
  git submodules init &&
  git submodules sync &&
  git submodules update
}'

### hooks
autoload -Uz add-zsh-hook
_sev_exectime=
function sev_preexec {
    # change terminal title to show command
    print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
    # save last exec time for bell
    # XXX: does not run for blank cmdline
    _sev_exectime=$SECONDS
    # update gpg forward, to always have unique filename and avoid clashes
    if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
        export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
        export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
    }
}
add-zsh-hook preexec sev_preexec
function sev_precmd {
    # change terminal title
    # TODO: update and send BEL when job status changes
    print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
    # bell if exec takes 5s
    if (( SECONDS - _sev_exectime >= 5 )) print "\a"
    # we could update vcs_info here, but let prompt take care of it
    # if it doesn't use vcs, it can be ignored safely
}
add-zsh-hook precmd sev_precmd
function sev_chpwd {
    # echo dir on cwd change
    ls -AF
}
add-zsh-hook chpwd sev_chpwd

### system-specific configs and aliases
case $OSTYPE; in
    freebsd*)
        ## colors
        export CLICOLOR=
        export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'

        ## sound
        function s { sysctl hw.snd.default_unit${1:+\=$1} }
        alias vol mixer

        ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
        # XXX: should probably use package-depends where possible, breaks when
        #      port name is different to package name
        #      (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
        function portpkg {
            case "$1" {
            build|run)
                sudo pkg install -AU $(make ${1}-depends-list |
                           sed 's_/usr/ports/_ _' | tr -d '\n')
                ;;
            *)  echo "Usage: \`portpkg <build|run>' in a port directory"
                return 1;;
            }
        };;
    netbsd)
        ## sound
        function s {
            if [[ -z "$1" ]] {
                ll /dev/mixer /dev/sound /dev/audio
                return
            }
            for x in mixer sound audio; do
                ln -sf /dev/$x"$1" /dev/$x
            done
        }
        function vol {
            if [[ -z "$1" ]] {
                for x in $(mixerctl -a | grep 'outputs\.master'); do
                    echo -E - $x
                done
                return
            }
            mixerctl -w outputs.master"$2"="$1"
        };;
    *)
        ## sound
        # TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
        function s {}
        function vol {}
esac

### prompt
autoload -Uz promptinit && promptinit
prompt arrows

### load site-specific
load-site-dotfile zshrc
Commit	Line	Data
43016843	1	### options
a7e41770	2	setopt NO_BEEP NO_CLOBBER \
	3	AUTO_CD CDABLE_VARS \
	4	EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
	5	CORRECT_ALL INTERACTIVE_COMMENTS \
	6	GLOB_COMPLETE \
	7	AUTO_CONTINUE LONG_LIST_JOBS \
	8	NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS
43016843	9
79d4a356	10	### exports
79d4a356	11	## common
8d4a98e1	12	export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
8d4a98e1	13	export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
79d4a356	14	## grep
	15	# XXX: deprecated in GNU
	16	export GREP_OPTIONS=--color=auto
	17	## histfile
	18	export HISTFILE=~/.histfile
	19	export HISTSIZE=1000
	20	export SAVEHIST=1000
	21	## python
8d4a98e1	22	export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
8d4a98e1	23	## vim
e69caf64	24	export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"\|execute"source"$MYVIMRC'
79d4a356	25
2bf94bab	26	### imports
	27	autoload -Uz zmv
	28	autoload -Uz zmathfunc && zmathfunc
	29
	30	## vcs
	31	zstyle ':vcs_info:*' enable git
	32	#zstyle ':vcs_info:git*' check-for-changes true #too slow
	33	zstyle ':vcs_info:git*:dotfiles' check-for-changes true
	34	zstyle ':vcs_info:git*' check-for-staged-changes true
	35	autoload -Uz vcs_info
	36
	37	## compinit
	38	zstyle ':completion:*' auto-description '[arg] %d'
	39	zstyle ':completion:*' expand suffix
	40	zstyle ':completion:*' format '# %d'
	41	zstyle ':completion:*' group-name ''
	42	zstyle ':completion:*' ignore-parents parent
	43	zstyle ':completion:*' insert-unambiguous false
	44	zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
	45	zstyle ':completion:*' list-prompt '%B%i%b'
	46	zstyle ':completion:*' list-suffixes true
	47	zstyle ':completion:' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:\|[._-]= r:\|=' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:\|= r:\|=*'
	48	zstyle ':completion:*' menu select=1
	49	zstyle ':completion:*' original false
	50	zstyle ':completion:*' select-prompt '%B%l%b'
	51	zstyle ':completion:*' verbose true
	52	autoload -Uz compinit
	53	cache=${XDG_CACHE_HOME:-~/.cache}/zsh
	54	[[ -d $cache ]] \|\| mkdir -p $cache
	55	compinit -d $cache/.zcompdump
	56	unset cache
	57
43016843	58	### keys
b484bab8	59	## set up zkbd-style key array
	60	if [[ ! -v _sev_force_zkbd && ( -v terminfo \|\| -v termcap ) ]] {
	61	# use application (keypad transmit) mode if the terminal supports it
	62	# NOTE: we have to do this because termcap/terminfo keys are usually
	63	# defined in application mode. terminals that do not define these
	64	# capabilities are assumed to always be in application mode.
	65	if [[ ( -v terminfo[smkx] && -v terminfo[rmkx] ) \|\|
	66	( -v termcap[ks] && -v terminfo[ke] ) ]] {
	67	autoload -Uz add-zle-hook-widget
	68	function _enter-application-mode {
	69	[[ -v terminfo[smkx] ]] && echoti smkx \|\| echotc ks
	70	}
	71	add-zle-hook-widget line-init _enter-application-mode
	72	function _exit-application-mode {
	73	[[ -v terminfo[rmkx] ]] && echoti rmkx \|\| echotc ke
	74	}
	75	add-zle-hook-widget line-finish _exit-application-mode
	76	trap _exit-application-mode EXIT
	77	}
	78	# pull keys from terminfo/termcap
	79	# TODO: Menu and more Shift- modifiers
	80	typeset -gA key
	81	typeset -lA newkey
	82	if [[ -v terminfo ]] {
	83	src=terminfo
	84	newkey=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
	85	F10 kf10 F11 kf11 F12 kf12
	86	Backspace kbs
	87	Shift-Tab kcbt
	88	Insert kich1
	89	Home khome
	90	PageUp kpp
	91	Delete kdch1
	92	End kend
	93	PageDown knp
	94	Up kcuu1
	95	Down kcud1
	96	Left kcub1
	97	Right kcuf1
	98	)
	99	} elif [[ -v termcap ]] {
	100	src=termcap
	101	newkey=(F1 k1 F2 k2 F3 k3 F4 k4 F5 k5 F6 k6 F7 k7 F8 k8 F9 k9
	102	F10 k\; F11 F1 F12 F2
	103	Backspace kb
	104	Shift-Tab kB
	105	Insert kI
	106	Home kh
	107	PageUp kP
	108	Delete kD
	109	End @7
	110	PageDown kN
	111	Up ku
	112	Down kd
	113	Left kl
	114	Right kr
	115	)
	116	}
	117	for k v (${(kv)newkey}) {
	118	key[$k]=${${(P)src}[$v]}
	119	}
	120	unset k v src newkey
	121	} else {
	122	# use zkbd if termcap/terminfo unavailable
43016843	123	function find_keymap {
8d4a98e1	124	for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
43016843	125	[[ -f $f ]] && keymap=$f && break
	126	}
	127	find_keymap
	128	if [[ -z $keymap ]] {
	129	if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
	130	echo
	131	autoload -Uz zkbd && zkbd
	132	unfunction zkbd
	133	find_keymap
	134	fi
	135	echo
	136	}
	137	if [[ -n $keymap ]] {
	138	source $keymap
	139	} else {
294ed44e	140	echo -E "Failed to source keymap file $keymap" >&2
43016843	141	}
43016843	142	unfunction find_keymap; unset keymap
43016843	143	}
2bf94bab	144
5b9a654a	145	## load history search
43016843	146	autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
43016843	147	zle -N up-line-or-beginning-search
43016843	148	zle -N down-line-or-beginning-search
43016843	149
5b9a654a	150	## bind keys in both viins and vicmd modes
b484bab8	151	# NOTE: cursor keys are bound to normal/raw/nontransmit mode strings by
	152	# default, and keys like Home and End are not bound at all, so we rebind
	153	# everything to cover all scenarios
5b9a654a	154	typeset -A a
	155	a=(
	156	#key viins vicmd
	157	Backspace 'backward-delete-char vi-backward-char'
	158	Insert 'overwrite-mode vi-insert'
	159	Home 'beginning-of-line'
	160	PageUp 'up-history -'
	161	Delete 'delete-char'
	162	End 'end-of-line'
	163	PageDown 'down-history -'
	164	Up 'up-line-or-beginning-search vi-up-line-or-history'
	165	Down 'down-line-or-beginning-search vi-down-line-or-history'
	166	Left 'backward-char'
	167	Right 'forward-char'
	168	)
b484bab8	169	for k v (${(kv)a}) {
5b9a654a	170	k=$key[$k]
b484bab8	171	if [[ -z $k ]] { continue }
5b9a654a	172	v=($=v)
5b9a654a	173	bindkey -- $k $v[1]
b484bab8	174	if [[ $v[2] == - ]] {
5b9a654a	175	# copy viins to vicmd verbatim
	176	bindkey -a -- $k $v[1]
	177	} elif (( $#v != 1 )) {
	178	# set vicmd to any other value
	179	bindkey -a -- $k $v[2]
	180	} else {
	181	# copy viins to vicmd and prepend vi- to it
	182	bindkey -a -- $k vi-$v[1]
	183	}
b484bab8	184	}
5b9a654a	185	unset a k v
5b9a654a	186
8a92a2c0	187	### aliases
	188	## builtins
	189	alias rehash='_sev_setpath; rehash'
	190	## utils
8d4a98e1	191	alias h='fc -l -25'
5b9a654a	192	alias j='jobs -l'
5b9a654a	193	alias l='ls -AF'
43016843	194	if [[ "$OSTYPE" =~ '^(free\|net)bsd' ]] {
5b9a654a	195	alias ll='ls -lAFho'
43016843	196	} else {
5b9a654a	197	alias ll='ls -lAFh'
43016843	198	}
b053a418	199	alias p=\$PAGER
b053a418	200	alias e=\$EDITOR
43016843	201	alias se=sudoedit
5b9a654a	202	# be paranoid
43016843	203	alias cp='cp -ip'
43016843	204	alias mv='mv -i'
bfbd0519	205	alias zm='noglob zmv -WiM'
	206	alias zc='noglob zmv -WiC'
	207	alias zl='noglob zmv -WiL'
	208	alias sm='noglob zmv -Wip"sudo mv"'
	209	alias sc='noglob zmv -Wip"sudo cp"'
	210	alias sl='noglob zmv -Wip"sudo ln"'
43016843	211	if [[ "$OSTYPE" =~ '^freebsd' ]] {
	212	# don't confirm if only a few files are deleted
	213	alias rm='rm -I'
	214	} else {
	215	# TODO: similar behavior for non-freebsd, or impliment in zsh
	216	alias rm='rm -i'
	217	}
8d4a98e1	218	[[ -v commands[trash-put] ]] && alias t=trash-put
43016843	219	## py venv
79d4a356	220	alias va='source bin/activate'
79d4a356	221	alias vd=deactivate
43016843	222	## ps
8d4a98e1	223	source ~/.local/bin/.check-busybox
79d4a356	224	if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
43016843	225	# use pstree, but NOT busybox pstree because it kinda sucks
	226	ps="pstree -wg3"
	227	elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
	228	ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
	229	-o%cpu,%mem,tty,stat,start=START -oetime,command"
	230	elif check-busybox ps; then
	231	# busybox compatible
	232	ps="ps -eouser='USR ' -ogroup='GRP ' \
	233	-opid=' PID' -onice=' NI' -ovsz=' MEM' \
	234	-otty,stat,etime,comm"
	235	else
	236	# XXX: untested, posix
	237	# TODO: support gnu ps
	238	ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
	239	-opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
	240	fi
	241	unfunction check-busybox
	242	if [[ "$(basename "$PAGER")" = "less" ]] {
109fad20	243	ps="$ps \| less -S"
43016843	244	} else {
	245	ps="$ps \| \"${PAGER:-more}\""
	246	}
79d4a356	247	alias pa=$ps
43016843	248	alias spa="sudo $ps"
43016843	249	unset ps
2bf94bab	250	## git
4851c231	251	alias gd='git diff'
2bf94bab	252	alias gdh='git diff HEAD'
2bf94bab	253	alias ga='git add'
0ca7cf36	254	alias ga.='git add .'
2bf94bab	255	alias gc='git commit'
	256	alias gca='git commit --amend'
	257	alias gp='git push'
4851c231	258	alias gu='git pull'
2bf94bab	259	## cd/zoxide
5b9a654a	260	function up {
b053a418	261	\cd $(printf '../%.0s' {1..${1:-1}})
5b9a654a	262	}
79d4a356	263	alias u=up
b053a418	264	if [[ -v commands[zoxide] ]] {
8a92a2c0	265	# https://github.com/ajeetdsouza/zoxide/issues/513
8a92a2c0	266	eval "${$(zoxide init zsh):s#_files -/#_cd#}"
6c74cef6	267	alias cd=z
b053a418	268	}
0ca7cf36	269	alias cd..=up
4851c231	270	## dotfiles
8ec56e91	271	alias dfu='d=${$(echo -E - ~/.zshenv):P:h:h};GIT_DIR=$d/.git GIT_WORK_TREE=$d {
	272	git pull &&
	273	git submodules init &&
	274	git submodules sync &&
	275	git submodules update
	276	}'
5b9a654a	277
43016843	278	### hooks
	279	autoload -Uz add-zsh-hook
	280	_sev_exectime=
	281	function sev_preexec {
	282	# change terminal title to show command
	283	print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
	284	# save last exec time for bell
	285	# XXX: does not run for blank cmdline
	286	_sev_exectime=$SECONDS
1ef46e01	287	# update gpg forward, to always have unique filename and avoid clashes
	288	if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
	289	export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
	290	export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
	291	}
43016843	292	}
	293	add-zsh-hook preexec sev_preexec
	294	function sev_precmd {
	295	# change terminal title
	296	# TODO: update and send BEL when job status changes
	297	print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
	298	# bell if exec takes 5s
	299	if (( SECONDS - _sev_exectime >= 5 )) print "\a"
	300	# we could update vcs_info here, but let prompt take care of it
	301	# if it doesn't use vcs, it can be ignored safely
	302	}
	303	add-zsh-hook precmd sev_precmd
	304	function sev_chpwd {
	305	# echo dir on cwd change
	306	ls -AF
	307	}
	308	add-zsh-hook chpwd sev_chpwd
	309
	310	### system-specific configs and aliases
79d4a356	311	case $OSTYPE; in
43016843	312	freebsd*)
8a92a2c0	313	## colors
43016843	314	export CLICOLOR=
	315	export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'
	316
	317	## sound
	318	function s { sysctl hw.snd.default_unit${1:+\=$1} }
	319	alias vol mixer
	320
	321	## install port dependencies from pkg (like pkgsrc `bmake bin-install')
	322	# XXX: should probably use package-depends where possible, breaks when
8a92a2c0	323	# port name is different to package name
8a92a2c0	324	# (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
43016843	325	function portpkg {
	326	case "$1" {
	327	build\|run)
	328	sudo pkg install -AU $(make ${1}-depends-list \|
	329	sed 's_/usr/ports/_ _' \| tr -d '\n')
	330	;;
	331	*) echo "Usage: \`portpkg <build\|run>' in a port directory"
	332	return 1;;
	333	}
	334	};;
	335	netbsd)
	336	## sound
	337	function s {
	338	if [[ -z "$1" ]] {
	339	ll /dev/mixer /dev/sound /dev/audio
	340	return
	341	}
	342	for x in mixer sound audio; do
	343	ln -sf /dev/$x"$1" /dev/$x
	344	done
	345	}
	346	function vol {
	347	if [[ -z "$1" ]] {
	348	for x in $(mixerctl -a \| grep 'outputs\.master'); do
294ed44e	349	echo -E - $x
43016843	350	done
	351	return
	352	}
	353	mixerctl -w outputs.master"$2"="$1"
	354	};;
	355	*)
	356	## sound
8d4a98e1	357	# TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
43016843	358	function s {}
	359	function vol {}
	360	esac
	361
43016843	362	### prompt
	363	autoload -Uz promptinit && promptinit
	364	prompt arrows
	365
8eb81f95	366	### load site-specific
4ced48ed	367	load-site-dotfile zshrc