[dotfiles.git] / etc / zsh / .zshrc

### options
setopt NO_BEEP NO_CLOBBER \
       AUTO_CD CDABLE_VARS \
       EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
       CORRECT_ALL INTERACTIVE_COMMENTS \
       GLOB_COMPLETE \
       AUTO_CONTINUE LONG_LIST_JOBS \
       NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS

### exports
## common
export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
## grep
# XXX: deprecated in GNU
export GREP_OPTIONS=--color=auto
## histfile
export HISTFILE=~/.histfile
export HISTSIZE=1000
export SAVEHIST=1000
## python
export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
## vim
export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"|execute"source"$MYVIMRC'
## wayland/gui env
export XDG_SESSION_TYPE=${XDG_SESSION_TYPE:-wayland}
export QT_QPA_PLATFORM=${QT_QPA_PLATFORM:-wayland-egl}
export QT_WAYLAND_DISABLE_WINDOWDECORATION=${QT_WAYLAND_DISABLE_WINDOWDECORATION:--1}
export SDL_VIDEODRIVER=${SDL_VIDEODRIVER:-wayland}
export TERMINAL=${TERMINAL:-$(whence -p konsole footclient urxvt xterm)[(f)1]}

### imports
autoload -Uz zmv
autoload -Uz zmathfunc && zmathfunc

## vcs
zstyle ':vcs_info:*' enable git
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true
autoload -Uz vcs_info

## compinit
zstyle ':completion:*' auto-description '[arg] %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
autoload -Uz compinit
cache=${XDG_CACHE_HOME:-~/.cache}/zsh
[[ -d $cache ]] || mkdir -p $cache
compinit -d $cache/.zcompdump
unset cache

### keys
bindkey -v
KEYTIMEOUT=10
## populate key array
if (( $#terminfo == 0 )) {
    # terminfo is not set or empty
    function find_keymap {
        for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
            [[ -f $f ]] && keymap=$f && break
    }
    find_keymap
    if [[ -z $keymap ]] {
        if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
            echo
            autoload -Uz zkbd && zkbd
            unfunction zkbd
            find_keymap
        fi
        echo
    }
    if [[ -n $keymap ]] {
        source $keymap
    } else {
        echo "Failed to source keymap file $keymap" >&2
    }
    unfunction find_keymap; unset keymap
} else {
    # activate application mode for zle so terminfo keys work
    # NOTE: don't do this for zkbd since application mode shouldn't have been
    #       enabled by zkbd when the keymap file was generated
    if [[ -v terminfo[smkx] && -v terminfo[rmkx] ]] {
        autoload -Uz add-zle-hook-widget
        function _enter-application-mode { echoti smkx }
        add-zle-hook-widget line-init _enter-application-mode
        function _exit-application-mode { echoti rmkx }
        add-zle-hook-widget line-finish _exit-application-mode
        trap _exit-application-mode EXIT
    }
    # match zkbd hash as best we can to terminfo
    typeset -gA key
    key=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
         F10 kf10 F11 kf11 F12 kf12
         Backspace kbs
         Backtab   kcbt
         Shift-Tab kcbt
         Insert    kich1
         Home      khome
         PageUp    kpp
         Delete    kdch1
         End       kend
         PageDown  knp
         Up        kcuu1
         Down      kcud1
         Left      kcub1
         Right     kcuf1
    )
    for k v in ${(kv)key}; do
        key[$k]=$terminfo[$v]
    done; unset k v
}

## load history search
autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search

## bind keys in both viins and vicmd modes
typeset -A a
a=(
    #key       viins                         vicmd
    Backspace 'backward-delete-char          vi-backward-char'
    Insert    'overwrite-mode                vi-insert'
    Home      'beginning-of-line'
    PageUp    'up-history                    -'
    Delete    'delete-char'
    End       'end-of-line'
    PageDown  'down-history                  -'
    Up        'up-line-or-beginning-search   vi-up-line-or-history'
    Down      'down-line-or-beginning-search vi-down-line-or-history'
    Left      'backward-char'
    Right     'forward-char'
)
for k v in ${(kv)a}; do
    k=$key[$k]
    if [[ -z "$k" ]] { continue }
    v=($=v)
    bindkey -- $k $v[1]
    if [[ $v[2] == '-' ]] {
        # copy viins to vicmd verbatim
        bindkey -a -- $k $v[1]
    } elif (( $#v != 1 )) {
        # set vicmd to any other value
        bindkey -a -- $k $v[2]
    } else {
        # copy viins to vicmd and prepend vi- to it
        bindkey -a -- $k vi-$v[1]
    }
done
unset a k v

### aliases
## builtins
alias rehash='_sev_setpath; rehash'
## utils
alias h='fc -l -25'
alias j='jobs -l'
alias l='ls -AF'
if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
    alias ll='ls -lAFho'
} else {
    alias ll='ls -lAFh'
}
alias p=\$PAGER
alias e=\$EDITOR
alias se=sudoedit
# be paranoid
alias cp='cp -ip'
alias mv='mv -i'
if [[ "$OSTYPE" =~ '^freebsd' ]] {
    # don't confirm if only a few files are deleted
    alias rm='rm -I'
} else {
    # TODO: similar behavior for non-freebsd, or impliment in zsh
    alias rm='rm -i'
}
[[ -v commands[trash-put] ]] && alias t=trash-put
## py venv
alias va='source bin/activate'
alias vd=deactivate
## ps
source ~/.local/bin/.check-busybox
if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
    # use pstree, but NOT busybox pstree because it kinda sucks
    ps="pstree -wg3"
elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
    ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
       -o%cpu,%mem,tty,stat,start=START -oetime,command"
elif check-busybox ps; then
    # busybox compatible
    ps="ps -eouser='USR     ' -ogroup='GRP     ' \
       -opid='  PID' -onice=' NI' -ovsz=' MEM' \
       -otty,stat,etime,comm"
else
    # XXX: untested, posix
    # TODO: support gnu ps
    ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
       -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
fi
unfunction check-busybox
if [[ "$(basename "$PAGER")" = "less" ]] {
    ps="$ps | less -S"
} else {
    ps="$ps | \"${PAGER:-more}\""
}
alias pa=$ps
alias spa="sudo $ps"
unset ps
## git
alias gd='git diff'
alias gdh='git diff HEAD'
alias ga='git add'
alias gc='git commit'
alias gca='git commit --amend'
alias gp='git push'
alias gu='git pull'
## cd/zoxide
function up {
    \cd $(printf '../%.0s' {1..${1:-1}})
}
alias u=up
if [[ -v commands[zoxide] ]] {
    # https://github.com/ajeetdsouza/zoxide/issues/513
    eval "${$(zoxide init zsh):s#_files -/#_cd#}"
    alias cd=z
}
## dotfiles
alias dfu='d=${$(echo ~/.zshenv):P:h:h};GIT_DIR=$d/.git GIT_WORK_TREE=$d git pull'

### hooks
autoload -Uz add-zsh-hook
_sev_exectime=
function sev_preexec {
    # change terminal title to show command
    print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
    # save last exec time for bell
    # XXX: does not run for blank cmdline
    _sev_exectime=$SECONDS
    # update gpg forward, to always have unique filename and avoid clashes
    if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
        export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
        export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
    }
}
add-zsh-hook preexec sev_preexec
function sev_precmd {
    # change terminal title
    # TODO: update and send BEL when job status changes
    print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
    # bell if exec takes 5s
    if (( SECONDS - _sev_exectime >= 5 )) print "\a"
    # we could update vcs_info here, but let prompt take care of it
    # if it doesn't use vcs, it can be ignored safely
}
add-zsh-hook precmd sev_precmd
function sev_chpwd {
    # echo dir on cwd change
    ls -AF
}
add-zsh-hook chpwd sev_chpwd

### system-specific configs and aliases
case $OSTYPE; in
    freebsd*)
        ## colors
        export CLICOLOR=
        export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'

        ## sound
        function s { sysctl hw.snd.default_unit${1:+\=$1} }
        alias vol mixer

        ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
        # XXX: should probably use package-depends where possible, breaks when
        #      port name is different to package name
        #      (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
        function portpkg {
            case "$1" {
            build|run)
                sudo pkg install -AU $(make ${1}-depends-list |
                           sed 's_/usr/ports/_ _' | tr -d '\n')
                ;;
            *)  echo "Usage: \`portpkg <build|run>' in a port directory"
                return 1;;
            }
        };;
    netbsd)
        ## sound
        function s {
            if [[ -z "$1" ]] {
                ll /dev/mixer /dev/sound /dev/audio
                return
            }
            for x in mixer sound audio; do
                ln -sf /dev/$x"$1" /dev/$x
            done
        }
        function vol {
            if [[ -z "$1" ]] {
                for x in $(mixerctl -a | grep 'outputs\.master'); do
                    echo $x
                done
                return
            }
            mixerctl -w outputs.master"$2"="$1"
        };;
    *)
        ## sound
        # TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
        function s {}
        function vol {}
esac

### prompt
autoload -Uz promptinit && promptinit
prompt arrows

### load site-specific
load-site-dotfile zshrc
Commit	Line	Data
43016843	1	### options
a7e41770	2	setopt NO_BEEP NO_CLOBBER \
	3	AUTO_CD CDABLE_VARS \
	4	EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
	5	CORRECT_ALL INTERACTIVE_COMMENTS \
	6	GLOB_COMPLETE \
	7	AUTO_CONTINUE LONG_LIST_JOBS \
	8	NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS
43016843	9
79d4a356	10	### exports
79d4a356	11	## common
8d4a98e1	12	export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
8d4a98e1	13	export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
79d4a356	14	## grep
	15	# XXX: deprecated in GNU
	16	export GREP_OPTIONS=--color=auto
	17	## histfile
	18	export HISTFILE=~/.histfile
	19	export HISTSIZE=1000
	20	export SAVEHIST=1000
	21	## python
8d4a98e1	22	export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
8d4a98e1	23	## vim
e69caf64	24	export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"\|execute"source"$MYVIMRC'
67052349	25	## wayland/gui env
	26	export XDG_SESSION_TYPE=${XDG_SESSION_TYPE:-wayland}
	27	export QT_QPA_PLATFORM=${QT_QPA_PLATFORM:-wayland-egl}
	28	export QT_WAYLAND_DISABLE_WINDOWDECORATION=${QT_WAYLAND_DISABLE_WINDOWDECORATION:--1}
	29	export SDL_VIDEODRIVER=${SDL_VIDEODRIVER:-wayland}
	30	export TERMINAL=${TERMINAL:-$(whence -p konsole footclient urxvt xterm)[(f)1]}
79d4a356	31
2bf94bab	32	### imports
	33	autoload -Uz zmv
	34	autoload -Uz zmathfunc && zmathfunc
	35
	36	## vcs
	37	zstyle ':vcs_info:*' enable git
	38	#zstyle ':vcs_info:git*' check-for-changes true #too slow
	39	zstyle ':vcs_info:git*:dotfiles' check-for-changes true
	40	zstyle ':vcs_info:git*' check-for-staged-changes true
	41	autoload -Uz vcs_info
	42
	43	## compinit
	44	zstyle ':completion:*' auto-description '[arg] %d'
	45	zstyle ':completion:*' expand suffix
	46	zstyle ':completion:*' format '# %d'
	47	zstyle ':completion:*' group-name ''
	48	zstyle ':completion:*' ignore-parents parent
	49	zstyle ':completion:*' insert-unambiguous false
	50	zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
	51	zstyle ':completion:*' list-prompt '%B%i%b'
	52	zstyle ':completion:*' list-suffixes true
	53	zstyle ':completion:' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:\|[._-]= r:\|=' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:\|= r:\|=*'
	54	zstyle ':completion:*' menu select=1
	55	zstyle ':completion:*' original false
	56	zstyle ':completion:*' select-prompt '%B%l%b'
	57	zstyle ':completion:*' verbose true
	58	autoload -Uz compinit
	59	cache=${XDG_CACHE_HOME:-~/.cache}/zsh
	60	[[ -d $cache ]] \|\| mkdir -p $cache
	61	compinit -d $cache/.zcompdump
	62	unset cache
	63
43016843	64	### keys
43016843	65	bindkey -v
	66	KEYTIMEOUT=10
	67	## populate key array
	68	if (( $#terminfo == 0 )) {
	69	# terminfo is not set or empty
	70	function find_keymap {
8d4a98e1	71	for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
43016843	72	[[ -f $f ]] && keymap=$f && break
	73	}
	74	find_keymap
	75	if [[ -z $keymap ]] {
	76	if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
	77	echo
	78	autoload -Uz zkbd && zkbd
	79	unfunction zkbd
	80	find_keymap
	81	fi
	82	echo
	83	}
	84	if [[ -n $keymap ]] {
	85	source $keymap
	86	} else {
c3608beb	87	echo "Failed to source keymap file $keymap" >&2
43016843	88	}
	89	unfunction find_keymap; unset keymap
	90	} else {
	91	# activate application mode for zle so terminfo keys work
c3608beb	92	# NOTE: don't do this for zkbd since application mode shouldn't have been
c3608beb	93	# enabled by zkbd when the keymap file was generated
43016843	94	if [[ -v terminfo[smkx] && -v terminfo[rmkx] ]] {
	95	autoload -Uz add-zle-hook-widget
	96	function _enter-application-mode { echoti smkx }
	97	add-zle-hook-widget line-init _enter-application-mode
	98	function _exit-application-mode { echoti rmkx }
	99	add-zle-hook-widget line-finish _exit-application-mode
	100	trap _exit-application-mode EXIT
	101	}
	102	# match zkbd hash as best we can to terminfo
	103	typeset -gA key
5b9a654a	104	key=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
	105	F10 kf10 F11 kf11 F12 kf12
	106	Backspace kbs
	107	Backtab kcbt
	108	Shift-Tab kcbt
	109	Insert kich1
	110	Home khome
	111	PageUp kpp
	112	Delete kdch1
	113	End kend
	114	PageDown knp
	115	Up kcuu1
	116	Down kcud1
	117	Left kcub1
	118	Right kcuf1
	119	)
	120	for k v in ${(kv)key}; do
	121	key[$k]=$terminfo[$v]
	122	done; unset k v
43016843	123	}
2bf94bab	124
5b9a654a	125	## load history search
43016843	126	autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
43016843	127	zle -N up-line-or-beginning-search
43016843	128	zle -N down-line-or-beginning-search
43016843	129
5b9a654a	130	## bind keys in both viins and vicmd modes
	131	typeset -A a
	132	a=(
	133	#key viins vicmd
	134	Backspace 'backward-delete-char vi-backward-char'
	135	Insert 'overwrite-mode vi-insert'
	136	Home 'beginning-of-line'
	137	PageUp 'up-history -'
	138	Delete 'delete-char'
	139	End 'end-of-line'
	140	PageDown 'down-history -'
	141	Up 'up-line-or-beginning-search vi-up-line-or-history'
	142	Down 'down-line-or-beginning-search vi-down-line-or-history'
	143	Left 'backward-char'
	144	Right 'forward-char'
	145	)
	146	for k v in ${(kv)a}; do
	147	k=$key[$k]
	148	if [[ -z "$k" ]] { continue }
	149	v=($=v)
	150	bindkey -- $k $v[1]
	151	if [[ $v[2] == '-' ]] {
	152	# copy viins to vicmd verbatim
	153	bindkey -a -- $k $v[1]
	154	} elif (( $#v != 1 )) {
	155	# set vicmd to any other value
	156	bindkey -a -- $k $v[2]
	157	} else {
	158	# copy viins to vicmd and prepend vi- to it
	159	bindkey -a -- $k vi-$v[1]
	160	}
	161	done
	162	unset a k v
	163
8a92a2c0	164	### aliases
	165	## builtins
	166	alias rehash='_sev_setpath; rehash'
	167	## utils
8d4a98e1	168	alias h='fc -l -25'
5b9a654a	169	alias j='jobs -l'
5b9a654a	170	alias l='ls -AF'
43016843	171	if [[ "$OSTYPE" =~ '^(free\|net)bsd' ]] {
5b9a654a	172	alias ll='ls -lAFho'
43016843	173	} else {
5b9a654a	174	alias ll='ls -lAFh'
43016843	175	}
b053a418	176	alias p=\$PAGER
b053a418	177	alias e=\$EDITOR
43016843	178	alias se=sudoedit
5b9a654a	179	# be paranoid
43016843	180	alias cp='cp -ip'
	181	alias mv='mv -i'
	182	if [[ "$OSTYPE" =~ '^freebsd' ]] {
	183	# don't confirm if only a few files are deleted
	184	alias rm='rm -I'
	185	} else {
	186	# TODO: similar behavior for non-freebsd, or impliment in zsh
	187	alias rm='rm -i'
	188	}
8d4a98e1	189	[[ -v commands[trash-put] ]] && alias t=trash-put
43016843	190	## py venv
79d4a356	191	alias va='source bin/activate'
79d4a356	192	alias vd=deactivate
43016843	193	## ps
8d4a98e1	194	source ~/.local/bin/.check-busybox
79d4a356	195	if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
43016843	196	# use pstree, but NOT busybox pstree because it kinda sucks
	197	ps="pstree -wg3"
	198	elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
	199	ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
	200	-o%cpu,%mem,tty,stat,start=START -oetime,command"
	201	elif check-busybox ps; then
	202	# busybox compatible
	203	ps="ps -eouser='USR ' -ogroup='GRP ' \
	204	-opid=' PID' -onice=' NI' -ovsz=' MEM' \
	205	-otty,stat,etime,comm"
	206	else
	207	# XXX: untested, posix
	208	# TODO: support gnu ps
	209	ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
	210	-opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
	211	fi
	212	unfunction check-busybox
	213	if [[ "$(basename "$PAGER")" = "less" ]] {
109fad20	214	ps="$ps \| less -S"
43016843	215	} else {
	216	ps="$ps \| \"${PAGER:-more}\""
	217	}
79d4a356	218	alias pa=$ps
43016843	219	alias spa="sudo $ps"
43016843	220	unset ps
2bf94bab	221	## git
4851c231	222	alias gd='git diff'
2bf94bab	223	alias gdh='git diff HEAD'
	224	alias ga='git add'
	225	alias gc='git commit'
	226	alias gca='git commit --amend'
	227	alias gp='git push'
4851c231	228	alias gu='git pull'
2bf94bab	229	## cd/zoxide
5b9a654a	230	function up {
b053a418	231	\cd $(printf '../%.0s' {1..${1:-1}})
5b9a654a	232	}
79d4a356	233	alias u=up
b053a418	234	if [[ -v commands[zoxide] ]] {
8a92a2c0	235	# https://github.com/ajeetdsouza/zoxide/issues/513
8a92a2c0	236	eval "${$(zoxide init zsh):s#_files -/#_cd#}"
6c74cef6	237	alias cd=z
b053a418	238	}
4851c231	239	## dotfiles
4851c231	240	alias dfu='d=${$(echo ~/.zshenv):P:h:h};GIT_DIR=$d/.git GIT_WORK_TREE=$d git pull'
5b9a654a	241
43016843	242	### hooks
	243	autoload -Uz add-zsh-hook
	244	_sev_exectime=
	245	function sev_preexec {
	246	# change terminal title to show command
	247	print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
	248	# save last exec time for bell
	249	# XXX: does not run for blank cmdline
	250	_sev_exectime=$SECONDS
1ef46e01	251	# update gpg forward, to always have unique filename and avoid clashes
	252	if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
	253	export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
	254	export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
	255	}
43016843	256	}
	257	add-zsh-hook preexec sev_preexec
	258	function sev_precmd {
	259	# change terminal title
	260	# TODO: update and send BEL when job status changes
	261	print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
	262	# bell if exec takes 5s
	263	if (( SECONDS - _sev_exectime >= 5 )) print "\a"
	264	# we could update vcs_info here, but let prompt take care of it
	265	# if it doesn't use vcs, it can be ignored safely
	266	}
	267	add-zsh-hook precmd sev_precmd
	268	function sev_chpwd {
	269	# echo dir on cwd change
	270	ls -AF
	271	}
	272	add-zsh-hook chpwd sev_chpwd
	273
	274	### system-specific configs and aliases
79d4a356	275	case $OSTYPE; in
43016843	276	freebsd*)
8a92a2c0	277	## colors
43016843	278	export CLICOLOR=
	279	export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'
	280
	281	## sound
	282	function s { sysctl hw.snd.default_unit${1:+\=$1} }
	283	alias vol mixer
	284
	285	## install port dependencies from pkg (like pkgsrc `bmake bin-install')
	286	# XXX: should probably use package-depends where possible, breaks when
8a92a2c0	287	# port name is different to package name
8a92a2c0	288	# (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
43016843	289	function portpkg {
	290	case "$1" {
	291	build\|run)
	292	sudo pkg install -AU $(make ${1}-depends-list \|
	293	sed 's_/usr/ports/_ _' \| tr -d '\n')
	294	;;
	295	*) echo "Usage: \`portpkg <build\|run>' in a port directory"
	296	return 1;;
	297	}
	298	};;
	299	netbsd)
	300	## sound
	301	function s {
	302	if [[ -z "$1" ]] {
	303	ll /dev/mixer /dev/sound /dev/audio
	304	return
	305	}
	306	for x in mixer sound audio; do
	307	ln -sf /dev/$x"$1" /dev/$x
	308	done
	309	}
	310	function vol {
	311	if [[ -z "$1" ]] {
	312	for x in $(mixerctl -a \| grep 'outputs\.master'); do
	313	echo $x
	314	done
	315	return
	316	}
	317	mixerctl -w outputs.master"$2"="$1"
	318	};;
	319	*)
	320	## sound
8d4a98e1	321	# TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
43016843	322	function s {}
	323	function vol {}
	324	esac
	325
43016843	326	### prompt
	327	autoload -Uz promptinit && promptinit
	328	prompt arrows
	329
8eb81f95	330	### load site-specific
4ced48ed	331	load-site-dotfile zshrc