fix DVTM_TERM

[dotfiles.git] / base / .zshrc

## options
setopt autocd extendedglob
unsetopt beep

## history
setopt appendhistory
HISTFILE=~/.histfile
HISTSIZE=100
SAVEHIST=100

## keys
bindkey -v
KEYTIMEOUT=1
# xorg
bindkey    "^[[7~" beginning-of-line #Home
bindkey -a "^[[7~" beginning-of-line
bindkey    "^[[8~" end-of-line       #End
bindkey -a "^[[8~" end-of-line
bindkey    "^[[3~" delete-char       #Del
bindkey -a "^[[3~" delete-char
# bsd vt
bindkey    "^[[H" beginning-of-line  #Home
bindkey -a "^[[H" beginning-of-line
bindkey    "^[[F" end-of-line        #End
bindkey -a "^[[F" end-of-line

autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search
[[ -n "$key[Up]"   ]] && bindkey -- "$key[Up]"   up-line-or-beginning-search
[[ -n "$key[Down]" ]] && bindkey -- "$key[Down]" down-line-or-beginning-search

## aliases
alias h="history -25"
alias j="jobs -l"
alias l="ls -AF"
alias ll="ls -lAFho"
# ps
local p="ps -aSdxwwouser=USR -ogroup=GRP -opid,nice=N \
         -o%cpu,%mem,tt,stat,start=START -oetime,command | ${PAGER:-more} -Se"
alias pa="$p"
alias spa="sudo $p"
unset p
# sound source
function s { sysctl hw.snd.default_unit${1:+\=$1} }
# py venv
alias va="source bin/activate"
alias vd="deactivate"
# be paranoid
alias cp='cp -ip'
alias mv='mv -i'
alias rm='rm -I'
# ports
function portpkg {
    case "$1" {
        build|run)
            sudo pkg install -AU $(make ${1}-depends-list |
                                   sed 's_/usr/ports/_ _' | tr -d '\n')
            ;;
        *)  echo "Usage: \`portpkg <build|run>' in a port directory"
            return 1;;
    }
}

## prompt
setopt prompt_subst
PROMPT='%F{$VICOL}%n%f@%F{$VICOL}%2m%f%(?../%F{red}$?%f)%# '
RPROMPT='%F{yellow}${vcs_info_msg_0_:-%~}%f %T'

function zle-line-init zle-keymap-select {
    VICOL="${${KEYMAP:/vicmd/red}:/(main|viins)/green}"
    zle reset-prompt
}
zle -N zle-line-init
zle -N zle-keymap-select

autoload -Uz vcs_info
zstyle ':vcs_info:*' enable git
zstyle ':vcs_info:git*' formats       "%c%u%%F{green}%r/%b%%f/%%F{yellow}%S%%f"
zstyle ':vcs_info:git*' actionformats "%%F{red}(%a)%%f %c%u%%F{green}%r/%b%%f/\
%%F{yellow}%S%%f"
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:.dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true
zstyle ':vcs_info:git*' stagedstr   "%F{blue}+"
zstyle ':vcs_info:git*' unstagedstr "%F{red}*"

# hooks
function precmd {
    # change terminal title
    print -Pn "\e]0;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\a"
    # update vcs
    vcs_info
    # bell if exec takes 5s
    if ((SECONDS - _exectime >= 5)) print "\a"
}
function preexec {
    # change terminal title to show command
    print -Pnf "\e]0;%s\a" "%#${SSH_CLIENT+$USER@$HOST:}$1"
    # save last exec time for bell
    _exectime=$SECONDS
}
function chpwd {
    l
}

# The following lines were added by compinstall
zstyle ':completion:*' auto-description 'specify: %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
zstyle :compinstall filename '/home/ds6/.zshrc'

autoload -Uz compinit
compinit
# End of lines added by compinstall

# vim: ts=8:sts=4:sw=4:et:tw=79