base/.zprofile

   1 # NOTE:
   2 # our .zprofile is expensive, so we keep track of what has been run already,
   3 # and only set up what is necessary. additionally, we want to ensure that our
   4 # environment is set up as early as possible, so we also source .zprofile in
   5 # .zshenv for new non-login shells.
   6 #
   7 # these issues are handled by using these methods:
   8 #   * the parent shell that starts the user's session after logging in to some
   9 #     graphical environments may not be a login shell—due to misconfiguration
  10 #     or otherwise—which means .zprofile is not ran and the environment is not
  11 #     properly configured for any child processes.
  12 #   * some desktop environments/graphical terminal emulators will start new
  13 #     terminal windows with login shells, which runs .zprofile every time and
  14 #     leads to noticably slow startup times.
  15 #   * switching users without wiping the environment will result in paths and
  16 #     variables intended for the old user being used for the new user. while
  17 #     this may be considered an edge-case that should not be supported, there
  18 #     are legitimate reasons to want to do this, and in any case the shell
  19 #     should not choke or cause unexpected problems should it happen anyway.
  20
  21 ### cleanup
  22 # XXX: only call after relevant vars have been set up, defined early so that
  23 #      below code can utilize it after they do so
  24 function _sev_zcleanup {
  25     ## gpg forwarding
  26     if [[ -d $_sev_gpg_forward_dir && ( -z $1 || $1 == 'gpg-forward' ) ]] {
  27         # clean up forward dirs if its session is dead or we ask for it
  28         find $_sev_gpg_forward_dir -mindepth 1 -maxdepth 1 -type d |
  29           while {read -r x} {
  30             # NOTE: the only way we can get here is if we have not been
  31             #       forwarded before, if the user asks for it, or during
  32             #       logout. if our own pid already has a dir, it is most likely
  33             #       stale, the user wants it removed, or something is very
  34             #       broken—in all 3 of these cases the best choice is remove it.
  35             p=$(basename $x)
  36             if {[[ -v _sev_gpg_forward_clean || $$ == $p ]] ||
  37                 ! kill -0 $p 2>/dev/null} {
  38                 find $x -mindepth 1 -maxdepth 1 | while {read -r y} {
  39                     # XXX: real dirs will stop unlink, consider it a feature
  40                     unlink $y
  41                 }
  42                 # don't force in case something important is still there
  43                 rmdir $x
  44             }
  45         }
  46         # reset GNUPGHOME if we removed our own dir
  47         if [[ $GNUPGHOME =~ '/.ssh_forward/\d+/*$' && ! -e $GNUPGHOME ]]
  48             GNUPGHOME=${GNUPGHOME%$MATCH}
  49     }
  50
  51     ## tmp
  52     # NOTE: _sev_tmp is not unset so session dirs will not be recreated
  53     # NOTE: XDG dirs that use our tmp are not unset here, they are in zlogout
  54     if [[ -d $_sev_tmp && ( -z $1 || $1 == 'tmp' ) ]] {
  55         # clean up tmp dirs if its session is dead or we ask for it
  56         find $_sev_tmp -mindepth 1 -maxdepth 1 -name '.session.*' -type d |
  57           while {read -r x} {
  58             # NOTE: same rationale as above
  59             p=${$(basename $x)#.session.}
  60             if {[[ -v _sev_tmp_clean || $$ == $p ]] ||
  61                 ! kill -0 $p 2>/dev/null} {
  62                 rm -rf $x
  63             }
  64         }
  65     }
  66
  67     unset x p y
  68 }
  69
  70 ### lang
  71 export CHARSET=${CHARSET:-UTF-8}
  72 export LANG=${LANG:-en_US.UTF-8}
  73 export LC_CTYPE=${LC_TYPE:-$LANG}
  74
  75 ### path
  76 # NOTE: we utilize the fact that unique arrays keep the first occurrence and
  77 #       remove any further occurences to capture elements from the old PATH
  78 #       that we did not anticipate and shift them to the front, since they are
  79 #       probably important to the system
  80 if [[ ! -v _sev_setup_path || -o login ]] {
  81     typeset -U path fpath
  82     # add as many generic paths as possible to keep the order we want
  83     # NOTE: /usr/{local,pkg,games} are unix/bsdisms
  84     # XXX: PREFIX not validated, non-posix but Termux uses it
  85     syspath=("$path[@]")
  86     path=(~/{s,}bin
  87           {~/.local,{$PREFIX,}{,/opt,/usr{,/local,pkg}}}/sbin
  88           {~/.local,{$PREFIX,}{,/opt,/usr{,/local,pkg}}}/bin
  89           /usr/{X11R{7,6}/bin,games})
  90     ((len=$#path))
  91     path=("$path[@]" "$syspath[@]")
  92     # remove nonexistent and duplicate paths
  93     for (( i = 1; i <= $#path; i++ )) {
  94         if [[ ! -e $path[$i] ]] {
  95             path[$i]=()
  96             ((i <= len)) && ((len--))
  97             ((i--))
  98             continue
  99         }
 100     }
 101     # shift valid system paths to the front if there are any left
 102     ((len > 0 && len < $#path)) && path=("${(@)path[len + 1, -1]}" "${(@)path[1, len]}")
 103     unset syspath len i
 104     # include our zsh dir in fpath. unlike above, we always prefer our paths
 105     fpath=(${ZDOTDIR:-~/.zsh}/functions/{*,Completions/*}(N) "$fpath[@]")
 106     # FPATH is not exported by default
 107     export FPATH
 108     typeset +U path fpath
 109     export _sev_setup_path=
 110 }
 111
 112 ### tmp
 113 # NOTE: specs say that POSIX tmp and XDG runtime directories should exist
 114 #       until the last session is logged out (POSIX can exist for longer).
 115 #       since we can't reliably keep track of sessions in a cross-platform
 116 #       manner, the current implementation should use a separate directory per
 117 #       toplevel session (i.e. SHLVL=1). this should placate most applications,
 118 #       though it is not expressly spec compliant.
 119 if [[ ! -v _sev_tmp ]] {
 120     _sev_tmp=~/tmp
 121     # create personal tmp dir
 122     t=${TMPDIR:-${TEMP:-${TMP:-/tmp}}}/.home-$LOGNAME
 123     [[ ! -e $t ]] && mkdir -m700 $t 2>/dev/null
 124     if [[ ! -d $t ]] {
 125         [[ -o interactive ]] &&
 126           print -P "%F{red}!!! Can't create tmpdir $t%f"
 127         # fallback bare directories
 128         [[ -h $_sev_tmp ]] && unlink $_sev_tmp 2>/dev/null
 129         [[ ! -e $_sev_tmp ]] && mkdir -m700 $_sev_tmp 2>/dev/null
 130     }
 131     # link home tmp for convenience if there isn't anything meaningful there
 132     [[ -h $_sev_tmp || ! -e $_sev_tmp ]] && ln -sfn $t $_sev_tmp 2>/dev/null
 133     export _sev_tmp=$(realpath $_sev_tmp)
 134     # ensure dir is clean
 135     _sev_zcleanup tmp
 136     # finally create our subdir for this session
 137     h=$_sev_tmp/.session.$$
 138     mkdir -m700 $h 2>/dev/null
 139     export TMPDIR=$h TEMP=$h TMP=$h
 140     unset t h
 141 }
 142
 143 ### xdg
 144 if [[ ! -v _sev_setup_xdg ]] {
 145     # merge with any existing dirs and remove duplicates using unique arrays
 146     # NOTE: include and then remove CONFIG_HOME and DATA_HOME to ensure they
 147     #       are not present in the array if it was added before we got to it
 148     typeset -UT XDG_CONFIG_DIRS xdg_config_dirs
 149     export XDG_CONFIG_HOME=~/etc
 150     mkdir $XDG_CONFIG_HOME 2>/dev/null
 151     xdg_config_dirs=($XDG_CONFIG_HOME ~/.config
 152       {/opt,/usr/local,/usr/pkg,}/etc/xdg
 153       "${XDG_CONFIG_DIRS:+${xdg_config_dirs[@]}}")
 154     export XDG_CONFIG_DIRS=${XDG_CONFIG_DIRS#$XDG_CONFIG_HOME}
 155
 156     typeset -UT XDG_DATA_DIRS xdg_data_dirs
 157     export XDG_DATA_HOME=~/share
 158     mkdir $XDG_DATA_HOME 2>/dev/null
 159     xdg_data_dirs=($XDG_DATA_HOME ~/.local/share
 160       /{opt,usr/local,usr/pkg,usr}/share
 161       "${XDG_DATA_DIRS:+${xdg_data_dirs[@]}}")
 162     export XDG_DATA_DIRS=${XDG_DATA_DIRS#$XDG_DATA_HOME}
 163
 164     mkdir ~/var 2>/dev/null
 165     export XDG_STATE_HOME=~/var/lib
 166     mkdir $XDG_STATE_HOME 2>/dev/null
 167
 168     if [[ -v _sev_tmp ]] {
 169         export XDG_CACHE_HOME=$_sev_tmp/.xdg.cache
 170         mkdir $XDG_CACHE_HOME 2>/dev/null
 171
 172         export XDG_RUNTIME_DIR=$TMPDIR/.xdg.runtime
 173         # same as in tmpdir creation, ensure it doesn't exist
 174         if [[ -h $XDG_RUNTIME_DIR ]]; then
 175             unlink $XDG_RUNTIME_DIR 2>/dev/null
 176         elif [[ -e $XDG_RUNTIME_DIR ]]; then
 177             rm -rf $XDG_RUNTIME_DIR 2>/dev/null
 178         fi
 179         mkdir -m700 $XDG_RUNTIME_DIR 2>/dev/null
 180     }
 181
 182     # source user dirs after other vars
 183     [[ -e $XDG_CONFIG_HOME/user-dirs.dirs ]] &&
 184       emulate sh -c "source $XDG_CONFIG_HOME/user-dirs.dirs"
 185     export _sev_setup_xdg=
 186 }
 187
 188 ### dbus
 189 if [[ ! -v DBUS_SESSION_BUS_ADDRESS && -v commands[dbus-launch] ]] {
 190     eval $(dbus-launch)
 191     export DBUS_SESSION_BUS_ADDRESS DBUS_SESSION_BUS_PID
 192 }
 193
 194 ### gpg home
 195 if [[ ! -v GNUPGHOME ]] {
 196     export GNUPGHOME=~/etc/gnupg
 197     if [[ -d ~/.gnupg ]] {
 198         mv ~/.gnupg ~/etc/gnupg
 199     }
 200 }
 201
 202 ### gpg agent + forwarding
 203 # NOTE: while ssh manages its auth sock in its protocol when ForwardSsh is
 204 #       enabled, GPG must be forwarded manually over Unix socket. to support
 205 #       this, we forward the restricted gpg-agent extra socket to the remote
 206 #       host with a RemoteForward rule in ~/.ssh/config that uses the
 207 #       _GNUPG_SOCK_* env vars. to avoid conflicts with other ssh sessions
 208 #       where the same user is connecting to the same host from different
 209 #       machines, gpg in each environment should utilize its own forwarded
 210 #       socket, rather than replace the sockets in GNUPGHOME which will be
 211 #       overridden on the next connection. previously, you could provide a path
 212 #       to the agent socket in GPG_AGENT_INFO, but that was deprecated in GPG
 213 #       v2.1. instead, we must clone GNUPGHOME with links and replace the agent
 214 #       sockets there with the forwarded one.
 215 # NOTE: since Unix sockets are not supported under Windows, this will not work
 216 #       under msys, cygwin, mingw, etc., but may work under wsl2.
 217 # HACK: without SendEnv, which is disabled by default in most sshd configs,
 218 #       there is no foolproof way to prevent race conditions via filename
 219 #       collisions or to pass the desired forward path to the remote host
 220 #       environment. we just have to guess the path we choose is good on the
 221 #       desination, and assume the newest matching socket is the correct one
 222 #       after connecting. in theory, we could occlude the ssh binary on PATH
 223 #       with an alias or script that would allow us to communicate with the
 224 #       remote host before opening a shell, so that we can have the host
 225 #       communicate back to the client where it wants a socket created or ask
 226 #       the host if the path the client wants to use is writable. however, this
 227 #       would open up too many edge cases where it wouldn't work or be clunky
 228 #       (e.g. asking for password twice) to make it worth it.
 229 function _gpg_socketpath {
 230     # dirs are percent-encoded: https://stackoverflow.com/a/64312099
 231     echo ${1//(#b)%([[:xdigit:]](#c2))/${(#):-0x$match[1]}}
 232 }
 233 if [[ ! -v _sev_setup_gpg_forward && -v commands[gpg] ]] {
 234     export _GNUPG_SOCK_DEST_BASE=/tmp/.gpg-agent-forward
 235     export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
 236     export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
 237     export _sev_gpg_forward_dir=${GNUPGHOME:-~/.gnupg}/.ssh_forward
 238     _sev_zcleanup gpg-forward
 239
 240     # find our forwarded socket
 241     s=($_GNUPG_SOCK_DEST_BASE*(N=oc[1]))
 242     if [[ -n $s && -v SSH_CLIENT ]] {
 243         # create new forward dir
 244         export _sev_setup_gpg_forward=
 245         h=$_sev_gpg_forward_dir/$$
 246         mkdir -pm700 $h
 247         # XXX: is it safe to link scdaemon socket? can its name be changed?
 248         for x (S.scdaemon gpg.conf gpg-agent.conf sshcontrol random_seed
 249                pubring.kbx{,~} trustdb.gpg private-keys-v1.d crls.d) {
 250             ln -s ${GNUPGHOME:-~/.gnupg}/$x $h
 251         }
 252         export GNUPGHOME=$h
 253         unset h
 254         for x in $(gpgconf --list-dirs | grep 'agent-.*-\?socket:'); do
 255             x=$(_gpg_socketpath ${x/#agent-*socket:})
 256             if [[ ! -v orig ]] {
 257                 # move forwarded socket to first valid agent socket path
 258                 # XXX: if tmp is on different filesystem this may not work
 259                 mv $s $x
 260                 orig=$x
 261             } else {
 262                 # make links to forwarded socket for any others
 263                 ln -s $orig $x
 264             }
 265         done
 266         unset x orig
 267     }
 268     unset s
 269
 270     # what we will forward if we start a new ssh connection
 271     # NOTE: do this after setting up GNUPGHOME to pick up new socket path;
 272     #       if already connected over SSH, extra should be the remote one
 273     export _GNUPG_SOCK_SRC=$(_gpg_socketpath \
 274       $(gpgconf --list-dirs agent-extra-socket))
 275 } elif [[ ! -v _sev_setup_gpg_forward ]] {
 276     # required for RemoteForward to not error out if the vars are unset
 277     [[ ! -v _GNUPG_SOCK_SRC ]] && export _GNUPG_SOCK_SRC=/nonexistent
 278     [[ ! -v _GNUPG_SOCK_DEST ]] && export _GNUPG_SOCK_DEST=/nonexistent
 279 }
 280
 281 ### gpg agent
 282 if [[ -v commands[gpg-connect-agent] && ( ! -v _sev_setup_gpgagent ||
 283         ( -v _sev_first_display && -z $_sev_first_display ) ) ]] {
 284     # avoid printing if we have already set up tty before
 285     [[ ! -v _sev_setup_gpgagent && -o interactive ]] && p=true || p=false
 286     if {$p} {
 287         print -nP '%F{blue}>>>%f GPG: '
 288         if [[ -v _sev_setup_gpg_forward ]] {
 289             print -nP '%F{yellow}Forwarded agent '
 290         } else {
 291             print -nP '%F{green}Agent '
 292         }
 293     }
 294     gpg-connect-agent /bye >/dev/null 2>&1
 295     if [[ $? -ne 0 ]] {
 296         $p && print -P '%F{red}communication error'
 297     } else {
 298         if [[ ! -v _sev_setup_gpg_forward ]] {
 299             if [[ ${+GPG_TTY} -eq 0 && -o interactive ]]
 300                 export GPG_TTY=$(tty)
 301             if [[ ( -v DISPLAY || -v WAYLAND_DISPLAY ) &&
 302                   ${PINENTRY_USER_DATA/USE_TTY=0} == $PINENTRY_USER_DATA ]]
 303                 export PINENTRY_USER_DATA=USE_TTY=$((
 304                   ${+DISPLAY} + ${+WAYLAND_DISPLAY} == 0))
 305             # XXX: don't know if gpg-agent supports comments after directives
 306             # XXX: path could have #
 307             sed -Ei 's#^([[:space:]]*pinentry-program[[:space:]]).*$#\1'${commands[pinentry]:-/dev/null}'#' \
 308               ${GNUPGHOME:-~/.gnupg}/gpg-agent.conf
 309             # XXX: could check for changes before doing this to save perf
 310             gpg-connect-agent RELOADAGENT UPDATESTARTUPTTY /bye >/dev/null 2>&1
 311             if {$p} {
 312                 gpg-connect-agent /subst /serverpid \
 313                   "/echo pid \${get serverpid} on $GPG_TTY" /bye 2>/dev/null
 314                 print -nP '%f'
 315             }
 316         } elif {$p} {
 317             print -P '%f'
 318         }
 319         export _sev_setup_gpgagent=
 320     }
 321     unset p
 322 }
 323
 324 ### ssh agent
 325 if [[ ! -v _sev_setup_ssh ]] {
 326     # NOTE: preferred order of agents to check: okcagent, gnupg, openssh
 327     #       first block takes care of okcagent and openssh, second gnupg
 328     # XXX: doesn't actually check if ssh is enabled in gpg
 329     [[ -o interactive ]] && print -nP '%F{blue}>>>%f SSH: %F{green}'
 330     if [[ ! -v SSH_AUTH_SOCK && ( -v commands[okc-ssh-agent] ||
 331           ( -v commands[ssh-agent] && ! -v commands[gpg] ) ) ]] {
 332         okc=${commands[okc-ssh-agent]:+okc-}
 333         t=${_sev_tmp:-${TMPDIR:-${TEMP:-${TMP:-/tmp}}}}
 334         e=$t/${okc}ssh-agent-exports
 335         typeset sock=
 336         typeset -i pid=
 337         if [[ -f $e ]] {
 338             IFS=$'\0' read -r sock pid <$e
 339         }
 340         if [[ -S $sock && $pid > 0 ]] && kill -0 $pid; then
 341             [[ -o interactive ]] && print -P "Reusing agent PID $pid%f"
 342             export SSH_AUTH_SOCK=$sock
 343             export SSH_AGENT_PID=$pid
 344         else
 345             e='TMPDIR=$t ${okc}ssh-agent'
 346             # TODO: ensure ssh-agent path looks legit to avoid unsafe eval?
 347             # XXX: doesn't appear to be any other way to handle redirection.
 348             #      because eval needs to write to current scope environment
 349             #      subshells can't be used to capture output and print.
 350             if [[ -o interactive ]] {
 351                 eval $(eval $=e)
 352                 print -nP '%f'
 353             } else {
 354                 eval $(eval $=e) >/dev/null 2>&1
 355             }
 356             echo -n $SSH_AUTH_SOCK$'\0'$SSH_AGENT_PID >!$e
 357         fi
 358         unset okc t e sock pid
 359     } elif [[ ! -v SSH_AUTH_SOCK && -v commands[gpg] ]] {
 360         # since gpg should have been started above, just export and notify
 361         if [[ -o interactive ]] {
 362             if [[ -v _sev_setup_gpg_forward ]] {
 363                 echo 'Forwarded GPG agent'
 364             } else {
 365                 gpg-connect-agent /subst /serverpid \
 366                   '/echo GPG agent pid ${get serverpid}' /bye
 367             }
 368             print -nP '%f'
 369         }
 370         export SSH_AUTH_SOCK=$(_gpg_socketpath \
 371           $(gpgconf --list-dirs agent-ssh-socket))
 372     } elif [[ -v SSH_AUTH_SOCK ]] {
 373         [[ -o interactive ]] && print -P 'Preconfigured agent%f'
 374     } else {
 375         [[ -o interactive ]] && print -P '%F{red}No agent available%f'
 376     }
 377
 378     export _sev_setup_ssh=
 379 }
 380 unfunction _gpg_socketpath
 381
 382 ### perl local lib
 383 [[ -v commands[perl] && -d $XDG_DATA_HOME/perl5/lib/perl5 &&
 384    ! -v PERL_LOCAL_LIB_ROOT ]] &&
 385   eval $(perl -I$XDG_DATA_HOME/perl5/lib/perl5 \
 386               -Mlocal::lib=$XDG_DATA_HOME/perl5 2>/dev/null)
 387
 388
 389 ### load site-specific
 390 if [[ -f ~/.zprofile.local ]] { source ~/.zprofile.local }
 391
 392 # vim: et sts=4 sw=4 ts=8 tw=79