base/.zprofile

   1 # NOTE:
   2 # our .zprofile is expensive, so we keep track of what has been run already,
   3 # and only set up what is necessary. additionally, we want to ensure that our
   4 # environment is set up as early as possible, so we also source .zprofile in
   5 # .zshenv for new non-login shells.
   6 #
   7 # these issues are handled by using these methods:
   8 #   * the parent shell that starts the user's session after logging in to some
   9 #     graphical environments may not be a login shell—due to misconfiguration
  10 #     or otherwise—which means .zprofile is not ran and the environment is not
  11 #     properly configured for any child processes.
  12 #   * some desktop environments/graphical terminal emulators will start new
  13 #     terminal windows with login shells, which runs .zprofile every time and
  14 #     leads to noticably slow startup times.
  15 #   * switching users without wiping the environment will result in paths and
  16 #     variables intended for the old user being used for the new user. while
  17 #     this may be considered an edge-case that should not be supported, there
  18 #     are legitimate reasons to want to do this, and in any case the shell
  19 #     should not choke or cause unexpected problems should it happen anyway.
  20
  21 ### cleanup
  22 # XXX: only call after relevant vars have been set up, defined early so that
  23 #      below code can utilize it after they do so
  24 function _sev_zcleanup {
  25     ## gpg forwarding
  26     if [[ -d $_sev_gpg_forward_dir && ( -z $1 || $1 == 'gpg-forward' ) ]] {
  27         # clean up forward dirs if its session is dead or we ask for it
  28         find $_sev_gpg_forward_dir -type d -mindepth 1 -maxdepth 1 |
  29           while {read -r x} {
  30             # NOTE: the only way we can get here is if we have not been
  31             #       forwarded before, if the user asks for it, or during
  32             #       logout. if our own pid already has a dir, it is most likely
  33             #       stale, the user wants it removed, or something is very
  34             #       broken—in all 3 of these cases the best choice is remove it.
  35             p=$(basename $x)
  36             if {[[ -v _sev_gpg_forward_clean || $$ == $p ]] ||
  37                 ! kill -0 $p 2>/dev/null} {
  38                 find $x -mindepth 1 -maxdepth 1 | while {read -r y} {
  39                     # XXX: real dirs will stop unlink, consider it a feature
  40                     unlink $y
  41                 }
  42                 # don't force in case something important is still there
  43                 rmdir $x
  44             }
  45         }
  46         # reset GNUPGHOME if we removed our own dir
  47         if [[ $GNUPGHOME =~ '/.ssh_forward/\d+/*$' && ! -e $GNUPGHOME ]] {
  48             x=$GNUPGHOME
  49             [[ -o GLOB_ASSIGN ]]; y=$?
  50             setopt GLOB_ASSIGN
  51             GNUPGHOME=$GNUPGHOME/../..(:a)
  52             (( y != 0 )) && unsetopt GLOB_ASSIGN
  53         }
  54     }
  55
  56     ## tmp
  57     # NOTE: _sev_tmp is not unset so session dirs will not be recreated
  58     # NOTE: XDG dirs that use our tmp are not unset here, they are in zlogout
  59     if [[ -d $_sev_tmp && ( -z $1 || $1 == 'tmp' ) ]] {
  60         # clean up tmp dirs if its session is dead or we ask for it
  61         find $_sev_tmp -name '.session.*' -type d -mindepth 1 -maxdepth 1 |
  62           while {read -r x} {
  63             # NOTE: same rationale as above
  64             p=${$(basename $x)#.session.}
  65             if {[[ -v _sev_tmp_clean || $$ == $p ]] ||
  66                 ! kill -0 $p 2>/dev/null} {
  67                 rm -rf $x
  68             }
  69         }
  70     }
  71
  72     unset x p y
  73 }
  74
  75 ### lang
  76 export CHARSET=${CHARSET:-UTF-8}
  77 export LANG=${LANG:-en_US.UTF-8}
  78 export LC_CTYPE=${LC_TYPE:-$LANG}
  79
  80 ### path
  81 # NOTE: we utilize the fact that unique arrays keep the first occurrence and
  82 #       remove any further occurences to capture elements from the old PATH
  83 #       that we did not anticipate and shift them to the front, since they are
  84 #       probably important to the system
  85 if [[ ! -v _sev_setup_path || -o login ]] {
  86     typeset -U path fpath
  87     # add as many generic paths as possible to keep the order we want
  88     # NOTE: /usr/{local,pkg,games} are unix/bsdisms
  89     syspath=("$path[@]")
  90     path=({~,~/.local,,/usr,/opt,/usr/local,/usr/pkg}/sbin
  91           {~,~/.local,,/usr,/opt,/usr/local,/usr/pkg}/bin
  92           /usr/X11R{7,6}/bin /usr/games)
  93     ((len=$#path))
  94     path=("$path[@]" "$syspath[@]")
  95     # remove nonexistent and duplicate paths
  96     for (( i = 1; i <= $#path; i++ )) {
  97         if [[ ! -e $path[$i] ]] {
  98             path[$i]=()
  99             ((i <= len)) && ((len--))
 100             ((i--))
 101             continue
 102         }
 103     }
 104     # shift valid system paths to the front if there are any left
 105     ((len > 0 && len < $#path)) && path=("${(@)path[len + 1, -1]}" "${(@)path[1, len]}")
 106     unset syspath len i j
 107     # include our zsh dir in fpath. unlike above, we always prefer our paths
 108     fpath=(${ZDOTDIR:-~/.zsh}/functions/{*,Completions/*}(N) "$fpath[@]")
 109     # FPATH is not exported by default
 110     export FPATH
 111     typeset +U path fpath
 112     export _sev_setup_path=
 113 }
 114
 115 ### tmp
 116 # NOTE: specs say that POSIX tmp and XDG runtime directories should exist
 117 #       until the last session is logged out (POSIX can exist for longer).
 118 #       since we can't reliably keep track of sessions in a cross-platform
 119 #       manner, the current implementation should use a separate directory per
 120 #       toplevel session (i.e. SHLVL=1). this should placate most applications,
 121 #       though it is not expressly spec compliant.
 122 if [[ ! -v _sev_tmp ]] {
 123     _sev_tmp=~/tmp
 124     # create personal tmp dir
 125     t=${TMPDIR:-${TEMP:-${TMP:-/tmp}}}/.home-$LOGNAME
 126     [[ ! -e $t ]] && mkdir -m700 $t 2>/dev/null
 127     if [[ ! -d $t ]] {
 128         [[ -o interactive ]] &&
 129           print -P "%F{red}!!! Can't create tmpdir $t%f"
 130         # fallback bare directories
 131         [[ -h $_sev_tmp ]] && unlink $_sev_tmp 2>/dev/null
 132         [[ ! -e $_sev_tmp ]] && mkdir -m700 $_sev_tmp 2>/dev/null
 133     }
 134     # link home tmp for convenience if there isn't anything meaningful there
 135     [[ -h $_sev_tmp || ! -e $_sev_tmp ]] && ln -sfn $t $_sev_tmp 2>/dev/null
 136     export _sev_tmp=$(realpath $_sev_tmp)
 137     # ensure dir is clean
 138     _sev_zcleanup tmp
 139     # finally create our subdir for this session
 140     h=$_sev_tmp/.session.$$
 141     mkdir -m700 $h 2>/dev/null
 142     export TMPDIR=$h TEMP=$h TMP=$h
 143     unset t h
 144 }
 145
 146 ### xdg
 147 if [[ ! -v _sev_setup_xdg ]] {
 148     # merge with any existing dirs and remove duplicates using unique arrays
 149     # NOTE: include and then remove CONFIG_HOME and DATA_HOME to ensure they
 150     #       are not present in the array if it was added before we got to it
 151     typeset -UT XDG_CONFIG_DIRS xdg_config_dirs
 152     export XDG_CONFIG_HOME=~/etc
 153     mkdir $XDG_CONFIG_HOME 2>/dev/null
 154     xdg_config_dirs=($XDG_CONFIG_HOME ~/.config
 155       {/opt,/usr/local,/usr/pkg,}/etc/xdg
 156       "${XDG_CONFIG_DIRS:+${xdg_config_dirs[@]}}")
 157     export XDG_CONFIG_DIRS=${XDG_CONFIG_DIRS#$XDG_CONFIG_HOME}
 158
 159     typeset -UT XDG_DATA_DIRS xdg_data_dirs
 160     export XDG_DATA_HOME=~/share
 161     mkdir $XDG_DATA_HOME 2>/dev/null
 162     xdg_data_dirs=($XDG_DATA_HOME ~/.local/share
 163       /{opt,usr/local,usr/pkg,usr}/share
 164       "${XDG_DATA_DIRS:+${xdg_data_dirs[@]}}")
 165     export XDG_DATA_DIRS=${XDG_DATA_DIRS#$XDG_DATA_HOME}
 166
 167     mkdir ~/var 2>/dev/null
 168     export XDG_STATE_HOME=~/var/lib
 169     mkdir $XDG_STATE_HOME 2>/dev/null
 170
 171     if [[ -v _sev_tmp ]] {
 172         export XDG_CACHE_HOME=$_sev_tmp/.xdg.cache
 173         mkdir $XDG_CACHE_HOME 2>/dev/null
 174
 175         export XDG_RUNTIME_DIR=$TMPDIR/.xdg.runtime
 176         # same as in tmpdir creation, ensure it doesn't exist
 177         if [[ -h $XDG_RUNTIME_DIR ]]; then
 178             unlink $XDG_RUNTIME_DIR 2>/dev/null
 179         elif [[ -e $XDG_RUNTIME_DIR ]]; then
 180             rm -rf $XDG_RUNTIME_DIR 2>/dev/null
 181         fi
 182         mkdir -m700 $XDG_RUNTIME_DIR 2>/dev/null
 183     }
 184
 185     # source user dirs after other vars
 186     [[ -e $XDG_CONFIG_HOME/user-dirs.dirs ]] &&
 187       emulate sh -c "source $XDG_CONFIG_HOME/user-dirs.dirs"
 188     export _sev_setup_xdg=
 189 }
 190
 191 ### dbus
 192 if [[ ! -v DBUS_SESSION_BUS_ADDRESS && -v commands[dbus-launch] ]] {
 193     eval $(dbus-launch)
 194     export DBUS_SESSION_BUS_ADDRESS DBUS_SESSION_BUS_PID
 195 }
 196
 197 ### gpg home
 198 if [[ ! -v GNUPGHOME ]] {
 199     export GNUPGHOME=~/etc/gnupg
 200     if [[ -d ~/.gnupg ]] {
 201         mv ~/.gnupg ~/etc/gnupg
 202     }
 203 }
 204
 205 ### gpg agent + forwarding
 206 # NOTE: while ssh manages its auth sock in its protocol when ForwardSsh is
 207 #       enabled, GPG must be forwarded manually over Unix socket. to support
 208 #       this, we forward the restricted gpg-agent extra socket to the remote
 209 #       host with a RemoteForward rule in ~/.ssh/config that uses the
 210 #       _GNUPG_SOCK_* env vars. to avoid conflicts with other ssh sessions
 211 #       where the same user is connecting to the same host from different
 212 #       machines, gpg in each environment should utilize its own forwarded
 213 #       socket, rather than replace the sockets in GNUPGHOME which will be
 214 #       overridden on the next connection. previously, you could provide a path
 215 #       to the agent socket in GPG_AGENT_INFO, but that was deprecated in GPG
 216 #       v2.1. instead, we must clone GNUPGHOME with links and replace the agent
 217 #       sockets there with the forwarded one.
 218 # NOTE: since Unix sockets are not supported under Windows, this will not work
 219 #       under msys, cygwin, mingw, etc., but may work under wsl2.
 220 # HACK: without SendEnv, which is disabled by default in most sshd configs,
 221 #       there is no foolproof way to prevent race conditions via filename
 222 #       collisions or to pass the desired forward path to the remote host
 223 #       environment. we just have to guess the path we choose is good on the
 224 #       desination, and assume the newest matching socket is the correct one
 225 #       after connecting. in theory, we could occlude the ssh binary on PATH
 226 #       with an alias or script that would allow us to communicate with the
 227 #       remote host before opening a shell, so that we can have the host
 228 #       communicate back to the client where it wants a socket created or ask
 229 #       the host if the path the client wants to use is writable. however, this
 230 #       would open up too many edge cases where it wouldn't work or be clunky
 231 #       (e.g. asking for password twice) to make it worth it.
 232 function _gpg_socketpath {
 233     # dirs are percent-encoded: https://stackoverflow.com/a/64312099
 234     echo ${1//(#b)%([[:xdigit:]](#c2))/${(#):-0x$match[1]}}
 235 }
 236 if [[ ! -v _sev_setup_gpg_forward && -v commands[gpg] ]] {
 237     export _GNUPG_SOCK_DEST_BASE=/tmp/.gpg-agent-forward
 238     export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
 239     export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
 240     export _sev_gpg_forward_dir=${GNUPGHOME:-~/.gnupg}/.ssh_forward
 241     _sev_zcleanup gpg-forward
 242
 243     # find our forwarded socket
 244     s=($_GNUPG_SOCK_DEST_BASE*(N=oc[1]))
 245     if [[ -n $s && -v SSH_CLIENT ]] {
 246         # create new forward dir
 247         export _sev_setup_gpg_forward=
 248         h=$_sev_gpg_forward_dir/$$
 249         mkdir -pm700 $h
 250         # XXX: is it safe to link scdaemon socket? can its name be changed?
 251         for x (S.scdaemon gpg.conf gpg-agent.conf sshcontrol
 252                pubring.kbx trustdb.gpg private-keys-v1.d crls.d) {
 253             ln -s ${GNUPGHOME:-~/.gnupg}/$x $h
 254         }
 255         export GNUPGHOME=$h
 256         unset h
 257         for x in $(gpgconf --list-dirs | grep 'agent-.*-\?socket:'); do
 258             x=$(_gpg_socketpath ${x/#agent-*socket:})
 259             if [[ ! -v orig ]] {
 260                 # move forwarded socket to first valid agent socket path
 261                 # XXX: if tmp is on different filesystem this may not work
 262                 mv $s $x
 263                 orig=$x
 264             } else {
 265                 # make links to forwarded socket for any others
 266                 ln -s $orig $x
 267             }
 268         done
 269         unset x orig
 270     }
 271     unset s
 272
 273     # what we will forward if we start a new ssh connection
 274     # NOTE: do this after setting up GNUPGHOME to pick up new socket path;
 275     #       if already connected over SSH, extra should be the remote one
 276     export _GNUPG_SOCK_SRC=$(_gpg_socketpath \
 277       $(gpgconf --list-dirs agent-extra-socket))
 278 } elif [[ ! -v _sev_setup_gpg_forward ]] {
 279     # required for RemoteForward to not error out if the vars are unset
 280     [[ ! -v _GNUPG_SOCK_SRC ]] && export _GNUPG_SOCK_SRC=/nonexistent
 281     [[ ! -v _GNUPG_SOCK_DEST ]] && export _GNUPG_SOCK_DEST=/nonexistent
 282 }
 283
 284 ### gpg agent
 285 if [[ -v commands[gpg-connect-agent] && ( ! -v _sev_setup_gpgagent ||
 286         ( -v _sev_first_display && -z $_sev_first_display ) ) ]] {
 287     # avoid printing if we have already set up tty before
 288     [[ ! -v _sev_setup_gpgagent && -o interactive ]] && p=true || p=false
 289     if {$p} {
 290         print -nP '%F{blue}>>>%f GPG: '
 291         if [[ -v _sev_setup_gpg_forward ]] {
 292             a=agent
 293             print -nP '%F{yellow}Forwarded%f '
 294         } else { a=Agent }
 295         print -nP '%F{green}'
 296     }
 297     gpg-connect-agent /bye >/dev/null 2>&1
 298     if [[ $? -ne 0 ]] {
 299         $p && print -P '%F{red}$a communication error'
 300     } else {
 301         if [[ ${+GPG_TTY} -eq 0 && -o interactive ]]
 302             export GPG_TTY=$(tty)
 303         if [[ ( -v DISPLAY || -v WAYLAND_DISPLAY ) &&
 304               ${PINENTRY_USER_DATA/USE_TTY=0} == $PINENTRY_USER_DATA ]]
 305             export PINENTRY_USER_DATA=USE_TTY=$((
 306               ${+DISPLAY} + ${+WAYLAND_DISPLAY} == 0))
 307         # XXX: don't know if gpg-agent supports comments after directives
 308         # XXX: path could have #
 309         sed -Ei 's#^([[:space:]]*pinentry-program[[:space:]]).*$#\1'${commands[pinentry]:-/dev/null}'#' \
 310           ${GNUPGHOME:-~/.gnupg}/gpg-agent.conf
 311         # XXX: could probably check for changes before doing this to save perf
 312         gpg-connect-agent RELOADAGENT UPDATESTARTUPTTY /bye >/dev/null 2>&1
 313         $p && gpg-connect-agent /subst /serverpid \
 314                 "/echo $a pid \${get serverpid} on $GPG_TTY" /bye
 315         export _sev_setup_gpgagent=
 316     }
 317     $p && print -nP '%f'
 318     unset p a
 319 }
 320
 321 ### ssh agent
 322 if [[ ! -v _sev_setup_ssh ]] {
 323     # NOTE: preferred order of agents to check: okcagent, gnupg, openssh
 324     #       first block takes care of okcagent and openssh, second gnupg
 325     # XXX: doesn't actually check if ssh is enabled in gpg
 326     [[ -o interactive ]] && print -nP '%F{blue}>>>%f SSH: %F{green}'
 327     if [[ ! -v SSH_AUTH_SOCK && ( -v commands[okc-ssh-agent] ||
 328           ( -v commands[ssh-agent] && ! -v commands[gpg] ) ) ]] {
 329         okc=${commands[okc-ssh-agent]:+okc-}
 330         t=${_sev_tmp:-${TMPDIR:-${TEMP:-${TMP:-/tmp}}}}
 331         e=$t/${okc}ssh-agent-exports
 332         typeset sock=
 333         typeset -i pid=
 334         if [[ -f $e ]] {
 335             IFS=$'\0' read -r sock pid <$e
 336         }
 337         if [[ -S $sock && $pid > 0 ]] && kill -0 $pid; then
 338             [[ -o interactive ]] && print -P "Reusing agent PID $pid%f"
 339             export SSH_AUTH_SOCK=$sock
 340             export SSH_AGENT_PID=$pid
 341         else
 342             e='TMPDIR=$t ${okc}ssh-agent'
 343             # TODO: ensure ssh-agent path looks legit to avoid unsafe eval?
 344             # XXX: doesn't appear to be any other way to handle redirection.
 345             #      because eval needs to write to current scope environment
 346             #      subshells can't be used to capture output and print.
 347             if [[ -o interactive ]] {
 348                 eval $(eval $=e)
 349                 print -nP '%f'
 350             } else {
 351                 eval $(eval $=e) >/dev/null 2>&1
 352             }
 353             echo -n $SSH_AUTH_SOCK$'\0'$SSH_AGENT_PID >!$e
 354         fi
 355         unset okc t e sock pid
 356     } elif [[ ! -v SSH_AUTH_SOCK && -v commands[gpg] ]] {
 357         # since gpg should have been started above, just export and notify
 358         if [[ -o interactive ]] {
 359             if [[ -v _sev_setup_gpg_forward ]] {
 360                 echo 'Forwarded GPG agent'
 361             } else {
 362                 gpg-connect-agent /subst /serverpid \
 363                   '/echo GPG agent pid ${get serverpid}' /bye
 364             }
 365             print -nP '%f'
 366         }
 367         export SSH_AUTH_SOCK=$(_gpg_socketpath \
 368           $(gpgconf --list-dirs agent-ssh-socket))
 369     } elif [[ -v SSH_AUTH_SOCK ]] {
 370         [[ -o interactive ]] && print -P 'Preconfigured agent%f'
 371     } else {
 372         [[ -o interactive ]] && print -P '%F{red}No agent available%f'
 373     }
 374
 375     export _sev_setup_ssh=
 376 }
 377 unfunction _gpg_socketpath
 378
 379 ### perl local lib
 380 [[ -v commands[perl] && -d $XDG_DATA_HOME/perl5/lib/perl5 &&
 381    ! -v PERL_LOCAL_LIB_ROOT ]] &&
 382   eval $(perl -I$XDG_DATA_HOME/perl5/lib/perl5 \
 383               -Mlocal::lib=$XDG_DATA_HOME/perl5 2>/dev/null)
 384
 385
 386 ### load site-specific
 387 if [[ -f ~/.zprofile.local ]] { source ~/.zprofile.local }
 388
 389 # vim: et sts=4 sw=4 ts=8 tw=79