etc/zsh/.zshrc

   1 ### options
   2 setopts=(
   3   ## 16.2.1  Changing Directories
   4   AUTO_CD CDABLE_VARS
   5   ## 16.2.2  Completion
   6   COMPLETE_IN_WORD GLOB_COMPLETE REC_EXACT
   7   ## 16.2.3  Expansion and Globbing
   8   EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MAGIC_EQUAL_SUBST MARK_DIRS
   9   NUMERIC_GLOB_SORT
  10   ## 16.2.4  History
  11   # NOTE: NO_HIST_SAVE_BY_COPY to allow saving histfile if updating another
  12   #       user's histfile. this is for compatibility with zsu.
  13   HIST_FCNTL_LOCK HIST_IGNORE_DUPS HIST_IGNORE_SPACE HIST_LEX_WORDS
  14   HIST_NO_STORE HIST_REDUCE_BLANKS NO_HIST_SAVE_BY_COPY SHARE_HISTORY
  15   ## 16.2.6  Input/Output
  16   NO_CLOBBER CLOBBER_EMPTY CORRECT_ALL INTERACTIVE_COMMENTS
  17   HASH_EXECUTABLES_ONLY
  18   ## 16.2.7  Job Control
  19   AUTO_CONTINUE LONG_LIST_JOBS
  20   ## 16.2.12 Zle
  21   NO_BEEP
  22 )
  23 setopt $setopts
  24 unset setopts
  25
  26 ### exports
  27 ## common
  28 export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
  29 export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
  30 ## grep
  31 # XXX: deprecated in GNU
  32 export GREP_OPTIONS=--color=auto
  33 ## histfile
  34 export HISTFILE=~/.histfile
  35 export HISTSIZE=10000
  36 export SAVEHIST=$HISTSIZE
  37 ## python
  38 export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
  39 ## vim
  40 export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"|execute"source"$MYVIMRC'
  41
  42 ### imports
  43 autoload -Uz zmv
  44 autoload -Uz zmathfunc && zmathfunc
  45
  46 ## vcs
  47 zstyle ':vcs_info:*' enable git
  48 #zstyle ':vcs_info:git*' check-for-changes true #too slow
  49 zstyle ':vcs_info:git*:dotfiles' check-for-changes true
  50 zstyle ':vcs_info:git*' check-for-staged-changes true
  51 autoload -Uz vcs_info
  52
  53 ## compinit
  54 zstyle ':completion:*' auto-description '[arg] %d'
  55 zstyle ':completion:*' expand suffix
  56 zstyle ':completion:*' format '# %d'
  57 zstyle ':completion:*' group-name ''
  58 zstyle ':completion:*' ignore-parents parent
  59 zstyle ':completion:*' insert-unambiguous false
  60 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
  61 zstyle ':completion:*' list-prompt '%B%i%b'
  62 zstyle ':completion:*' list-suffixes true
  63 zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
  64 zstyle ':completion:*' menu select=1
  65 zstyle ':completion:*' original false
  66 zstyle ':completion:*' select-prompt '%B%l%b'
  67 zstyle ':completion:*' verbose true
  68 autoload -Uz compinit
  69 cache=${XDG_CACHE_HOME:-~/.cache}/zsh
  70 [[ -d $cache ]] || mkdir -p $cache
  71 compinit -d $cache/.zcompdump
  72 unset cache
  73
  74 ### keys
  75 ## set up zkbd-style key array
  76 if [[ ! -v _sev_force_zkbd && ( -v terminfo || -v termcap ) ]] {
  77     # use application (keypad transmit) mode if the terminal supports it
  78     # NOTE: we have to do this because termcap/terminfo keys are usually
  79     #       defined in application mode. terminals that do not define these
  80     #       capabilities are assumed to always be in application mode.
  81     if [[ ( -v terminfo[smkx] && -v terminfo[rmkx] ) ||
  82           ( -v termcap[ks]    && -v terminfo[ke] ) ]] {
  83         autoload -Uz add-zle-hook-widget
  84         function _enter-application-mode {
  85             [[ -v terminfo[smkx] ]] && echoti smkx || echotc ks
  86         }
  87         add-zle-hook-widget line-init _enter-application-mode
  88         function _exit-application-mode {
  89             [[ -v terminfo[rmkx] ]] && echoti rmkx || echotc ke
  90         }
  91         add-zle-hook-widget line-finish _exit-application-mode
  92         trap _exit-application-mode EXIT
  93     }
  94     # pull keys from terminfo/termcap
  95     # TODO: Menu and more Shift- modifiers
  96     typeset -gA key
  97     typeset -lA newkey
  98     if [[ -v terminfo ]] {
  99         src=terminfo
 100         newkey=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
 101                 F10 kf10 F11 kf11 F12 kf12
 102                 Backspace kbs
 103                 Shift-Tab kcbt
 104                 Insert    kich1
 105                 Home      khome
 106                 PageUp    kpp
 107                 Delete    kdch1
 108                 End       kend
 109                 PageDown  knp
 110                 Up        kcuu1
 111                 Down      kcud1
 112                 Left      kcub1
 113                 Right     kcuf1
 114         )
 115     } elif [[ -v termcap ]] {
 116         src=termcap
 117         newkey=(F1 k1 F2 k2 F3 k3 F4 k4 F5 k5 F6 k6 F7 k7 F8 k8 F9 k9
 118                 F10 k\; F11 F1 F12 F2
 119                 Backspace kb
 120                 Shift-Tab kB
 121                 Insert    kI
 122                 Home      kh
 123                 PageUp    kP
 124                 Delete    kD
 125                 End       @7
 126                 PageDown  kN
 127                 Up        ku
 128                 Down      kd
 129                 Left      kl
 130                 Right     kr
 131         )
 132     }
 133     for k v (${(kv)newkey}) {
 134         key[$k]=${${(P)src}[$v]}
 135     }
 136     unset k v src newkey
 137 } else {
 138     # use zkbd if termcap/terminfo unavailable
 139     function find_keymap {
 140         for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
 141             [[ -f $f ]] && keymap=$f && break
 142     }
 143     find_keymap
 144     if [[ -z $keymap ]] {
 145         if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
 146             echo
 147             autoload -Uz zkbd && zkbd
 148             unfunction zkbd
 149             find_keymap
 150         fi
 151         echo
 152     }
 153     if [[ -n $keymap ]] {
 154         source $keymap
 155     } else {
 156         echo -E "Failed to source keymap file $keymap" >&2
 157     }
 158     unfunction find_keymap; unset keymap
 159 }
 160
 161 ## load history search
 162 autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
 163 zle -N up-line-or-beginning-search
 164 zle -N down-line-or-beginning-search
 165
 166 ## bind keys in both viins and vicmd modes
 167 # NOTE: cursor keys are bound to normal/raw/nontransmit mode strings by
 168 #       default, and keys like Home and End are not bound at all, so we rebind
 169 #       everything to cover all scenarios
 170 typeset -A a
 171 a=(
 172     #key       viins                         vicmd
 173     Backspace 'backward-delete-char          vi-backward-char'
 174     Insert    'overwrite-mode                vi-insert'
 175     Home      'beginning-of-line'
 176     PageUp    'up-history                    -'
 177     Delete    'delete-char'
 178     End       'end-of-line'
 179     PageDown  'down-history                  -'
 180     Up        'up-line-or-beginning-search   vi-up-line-or-history'
 181     Down      'down-line-or-beginning-search vi-down-line-or-history'
 182     Left      'backward-char'
 183     Right     'forward-char'
 184 )
 185 for k v (${(kv)a}) {
 186     k=$key[$k]
 187     if [[ -z $k ]] { continue }
 188     v=($=v)
 189     bindkey -- $k $v[1]
 190     if [[ $v[2] == - ]] {
 191         # copy viins to vicmd verbatim
 192         bindkey -a -- $k $v[1]
 193     } elif (( $#v != 1 )) {
 194         # set vicmd to any other value
 195         bindkey -a -- $k $v[2]
 196     } else {
 197         # copy viins to vicmd and prepend vi- to it
 198         bindkey -a -- $k vi-$v[1]
 199     }
 200 }
 201 unset a k v
 202
 203 ### aliases
 204 ## builtins
 205 alias rehash='_sev_setpath; rehash'
 206 ## utils
 207 alias h='fc -l -25'
 208 alias j='jobs -l'
 209 alias l='ls -AF'
 210 if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
 211     alias ll='ls -lAFho'
 212 } else {
 213     alias ll='ls -lAFh'
 214 }
 215 alias p=\$PAGER
 216 alias e=\$EDITOR
 217 alias se=sudoedit
 218 alias syncwatch='sync & watch -d grep -Fe Dirty: -e Writeback: /proc/meminfo'
 219 # be paranoid
 220 alias cp='cp -ip'
 221 alias mv='mv -i'
 222 # zsh zmv with noglob wildcards
 223 alias zm='noglob zmv -WiM'
 224 alias zc='noglob zmv -WiC'
 225 alias zl='noglob zmv -WiL'
 226 alias sm='noglob zmv -Wip"sudo mv"'
 227 alias sc='noglob zmv -Wip"sudo cp"'
 228 alias sl='noglob zmv -Wip"sudo ln"'
 229 if [[ "$OSTYPE" =~ '^freebsd' ]] {
 230     # don't confirm if only a few files are deleted
 231     alias rm='rm -I'
 232 } else {
 233     # TODO: similar behavior for non-freebsd, or impliment in zsh
 234     alias rm='rm -i'
 235 }
 236 [[ -v commands[trash-put] ]] && alias t=trash-put
 237 # ps
 238 source ~/.local/bin/.check-busybox
 239 if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
 240     # use pstree, but NOT busybox pstree because it kinda sucks
 241     ps="pstree -wg3"
 242 elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
 243     ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
 244        -o%cpu,%mem,tty,stat,start=START -oetime,command"
 245 elif check-busybox ps; then
 246     # busybox compatible
 247     ps="ps -eouser='USR     ' -ogroup='GRP     ' \
 248        -opid='  PID' -onice=' NI' -ovsz=' MEM' \
 249        -otty,stat,etime,comm"
 250 else
 251     # XXX: untested, posix
 252     # TODO: support gnu ps
 253     ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
 254        -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
 255 fi
 256 unfunction check-busybox
 257 if [[ "$(basename "$PAGER")" = "less" ]] {
 258     ps="$ps | less -S"
 259 } else {
 260     ps="$ps | \"${PAGER:-more}\""
 261 }
 262 alias pa=$ps
 263 alias spa="sudo $ps"
 264 unset ps
 265 ## py venv
 266 alias va='source bin/activate'
 267 alias vd=deactivate
 268 alias vu="python3 -mvenv --upgrade"
 269 ## git
 270 alias g=git
 271 alias gd='git diff'
 272 alias gdh='git diff HEAD'
 273 alias ga='git add'
 274 alias ga.='git add .'
 275 alias gc='git commit'
 276 alias gca='git commit --amend'
 277 alias gp='git push'
 278 alias gu='git pull'
 279 alias gl='git log'
 280 alias gt='git tree' # from gitconfig
 281 ## cd/zoxide
 282 function up {
 283     \cd $(printf '../%.0s' {1..${1:-1}})
 284 }
 285 alias u=up
 286 if [[ -v commands[zoxide] ]] {
 287     # https://github.com/ajeetdsouza/zoxide/issues/513
 288     eval "${$(zoxide init zsh):s#_files -/#_cd#}"
 289     alias cd=z
 290 }
 291 alias cd..=up
 292 ## dotfiles
 293 alias dfu='function {
 294     pushd -q ${$(echo -E - ~/.zshenv):P:h:h}
 295     git pull &&
 296     git submodule init &&
 297     git submodule sync &&
 298     git submodule update
 299     popd -q
 300 }'
 301 ## nocorrect
 302 # zsh doesnt really handle sudo very well, so ignore it
 303 alias sudo='nocorrect sudo'
 304 ## docker compose
 305 alias dcp='sudo docker compose pull'
 306 alias dcu='sudo docker compose up -d'
 307 alias dcr='sudo docker compose restart'
 308 alias dcl='sudo docker compose logs -f'
 309
 310 ### hooks
 311 autoload -Uz add-zsh-hook
 312 typeset -gi _sev_exectime
 313 function sev_preexec {
 314     # change terminal title to show command
 315     print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
 316     # save last exec time for bell
 317     # XXX: does not run for blank cmdline
 318     _sev_exectime=$SECONDS
 319     # update gpg forward, to always have unique filename and avoid clashes
 320     if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
 321         export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
 322         export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
 323     }
 324 }
 325 add-zsh-hook preexec sev_preexec
 326 function sev_precmd {
 327     # change terminal title
 328     # TODO: update and send BEL when job status changes
 329     print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
 330     # bell if exec takes 5s
 331     if (( SECONDS - _sev_exectime >= 5 )) print "\a"
 332     # we could update vcs_info here, but let prompt take care of it
 333     # if it doesn't use vcs, it can be ignored safely
 334 }
 335 add-zsh-hook precmd sev_precmd
 336 function sev_chpwd {
 337     # echo dir on cwd change
 338     ls -AF
 339 }
 340 add-zsh-hook chpwd sev_chpwd
 341
 342 ### system-specific configs and aliases
 343 case $OSTYPE; in
 344     freebsd*)
 345         ## colors
 346         export CLICOLOR=
 347         export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'
 348
 349         ## sound
 350         function s { sysctl hw.snd.default_unit${1:+\=$1} }
 351         alias vol mixer
 352
 353         ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
 354         # XXX: should probably use package-depends where possible, breaks when
 355         #      port name is different to package name
 356         #      (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
 357         function portpkg {
 358             case "$1" {
 359             build|run)
 360                 sudo pkg install -AU $(make ${1}-depends-list |
 361                            sed 's_/usr/ports/_ _' | tr -d '\n')
 362                 ;;
 363             *)  echo "Usage: \`portpkg <build|run>' in a port directory"
 364                 return 1;;
 365             }
 366         };;
 367     netbsd)
 368         ## sound
 369         function s {
 370             if [[ -z "$1" ]] {
 371                 ll /dev/mixer /dev/sound /dev/audio
 372                 return
 373             }
 374             for x in mixer sound audio; do
 375                 ln -sf /dev/$x"$1" /dev/$x
 376             done
 377         }
 378         function vol {
 379             if [[ -z "$1" ]] {
 380                 for x in $(mixerctl -a | grep 'outputs\.master'); do
 381                     echo -E - $x
 382                 done
 383                 return
 384             }
 385             mixerctl -w outputs.master"$2"="$1"
 386         };;
 387     *)
 388         ## sound
 389         # TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
 390         function s {}
 391         function vol {}
 392 esac
 393
 394 ### prompt
 395 autoload -Uz promptinit && promptinit
 396 prompt arrows
 397
 398 ### load site-specific
 399 load-site-dotfile zshrc