etc/zsh/.zshrc

   1 ### options
   2 setopt NO_BEEP NO_CLOBBER \
   3        AUTO_CD CDABLE_VARS \
   4        EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
   5        CORRECT_ALL INTERACTIVE_COMMENTS \
   6        GLOB_COMPLETE \
   7        AUTO_CONTINUE LONG_LIST_JOBS \
   8        NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS
   9
  10 ### exports
  11 ## common
  12 export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
  13 export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
  14 ## grep
  15 # XXX: deprecated in GNU
  16 export GREP_OPTIONS=--color=auto
  17 ## histfile
  18 export HISTFILE=~/.histfile
  19 export HISTSIZE=1000
  20 export SAVEHIST=1000
  21 ## python
  22 export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
  23 ## vim
  24 export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"|execute"source"$MYVIMRC'
  25 ## wayland/gui env
  26 export XDG_SESSION_TYPE=${XDG_SESSION_TYPE:-wayland}
  27 export QT_QPA_PLATFORM=${QT_QPA_PLATFORM:-wayland-egl}
  28 export QT_WAYLAND_DISABLE_WINDOWDECORATION=${QT_WAYLAND_DISABLE_WINDOWDECORATION:--1}
  29 export SDL_VIDEODRIVER=${SDL_VIDEODRIVER:-wayland}
  30 export TERMINAL=${TERMINAL:-$(whence -p konsole footclient urxvt xterm)[(f)1]}
  31
  32 ### imports
  33 autoload -Uz zmv
  34 autoload -Uz zmathfunc && zmathfunc
  35
  36 ## vcs
  37 zstyle ':vcs_info:*' enable git
  38 #zstyle ':vcs_info:git*' check-for-changes true #too slow
  39 zstyle ':vcs_info:git*:dotfiles' check-for-changes true
  40 zstyle ':vcs_info:git*' check-for-staged-changes true
  41 autoload -Uz vcs_info
  42
  43 ## compinit
  44 zstyle ':completion:*' auto-description '[arg] %d'
  45 zstyle ':completion:*' expand suffix
  46 zstyle ':completion:*' format '# %d'
  47 zstyle ':completion:*' group-name ''
  48 zstyle ':completion:*' ignore-parents parent
  49 zstyle ':completion:*' insert-unambiguous false
  50 zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
  51 zstyle ':completion:*' list-prompt '%B%i%b'
  52 zstyle ':completion:*' list-suffixes true
  53 zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
  54 zstyle ':completion:*' menu select=1
  55 zstyle ':completion:*' original false
  56 zstyle ':completion:*' select-prompt '%B%l%b'
  57 zstyle ':completion:*' verbose true
  58 autoload -Uz compinit
  59 cache=${XDG_CACHE_HOME:-~/.cache}/zsh
  60 [[ -d $cache ]] || mkdir -p $cache
  61 compinit -d $cache/.zcompdump
  62 unset cache
  63
  64 ### keys
  65 bindkey -v
  66 KEYTIMEOUT=10
  67 ## populate key array
  68 if (( $#terminfo == 0 )) {
  69     # terminfo is not set or empty
  70     function find_keymap {
  71         for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
  72             [[ -f $f ]] && keymap=$f && break
  73     }
  74     find_keymap
  75     if [[ -z $keymap ]] {
  76         if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
  77             echo
  78             autoload -Uz zkbd && zkbd
  79             unfunction zkbd
  80             find_keymap
  81         fi
  82         echo
  83     }
  84     if [[ -n $keymap ]] {
  85         source $keymap
  86     } else {
  87         echo "Failed to source keymap file $keymap" >&2
  88     }
  89     unfunction find_keymap; unset keymap
  90 } else {
  91     # activate application mode for zle so terminfo keys work
  92     # NOTE: don't do this for zkbd since application mode shouldn't have been
  93     #       enabled by zkbd when the keymap file was generated
  94     if [[ -v terminfo[smkx] && -v terminfo[rmkx] ]] {
  95         autoload -Uz add-zle-hook-widget
  96         function _enter-application-mode { echoti smkx }
  97         add-zle-hook-widget line-init _enter-application-mode
  98         function _exit-application-mode { echoti rmkx }
  99         add-zle-hook-widget line-finish _exit-application-mode
 100         trap _exit-application-mode EXIT
 101     }
 102     # match zkbd hash as best we can to terminfo
 103     typeset -gA key
 104     key=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
 105          F10 kf10 F11 kf11 F12 kf12
 106          Backspace kbs
 107          Backtab   kcbt
 108          Shift-Tab kcbt
 109          Insert    kich1
 110          Home      khome
 111          PageUp    kpp
 112          Delete    kdch1
 113          End       kend
 114          PageDown  knp
 115          Up        kcuu1
 116          Down      kcud1
 117          Left      kcub1
 118          Right     kcuf1
 119     )
 120     for k v in ${(kv)key}; do
 121         key[$k]=$terminfo[$v]
 122     done; unset k v
 123 }
 124
 125 ## load history search
 126 autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
 127 zle -N up-line-or-beginning-search
 128 zle -N down-line-or-beginning-search
 129
 130 ## bind keys in both viins and vicmd modes
 131 typeset -A a
 132 a=(
 133     #key       viins                         vicmd
 134     Backspace 'backward-delete-char          vi-backward-char'
 135     Insert    'overwrite-mode                vi-insert'
 136     Home      'beginning-of-line'
 137     PageUp    'up-history                    -'
 138     Delete    'delete-char'
 139     End       'end-of-line'
 140     PageDown  'down-history                  -'
 141     Up        'up-line-or-beginning-search   vi-up-line-or-history'
 142     Down      'down-line-or-beginning-search vi-down-line-or-history'
 143     Left      'backward-char'
 144     Right     'forward-char'
 145 )
 146 for k v in ${(kv)a}; do
 147     k=$key[$k]
 148     if [[ -z "$k" ]] { continue }
 149     v=($=v)
 150     bindkey -- $k $v[1]
 151     if [[ $v[2] == '-' ]] {
 152         # copy viins to vicmd verbatim
 153         bindkey -a -- $k $v[1]
 154     } elif (( $#v != 1 )) {
 155         # set vicmd to any other value
 156         bindkey -a -- $k $v[2]
 157     } else {
 158         # copy viins to vicmd and prepend vi- to it
 159         bindkey -a -- $k vi-$v[1]
 160     }
 161 done
 162 unset a k v
 163
 164 ### aliases
 165 ## builtins
 166 alias rehash='_sev_setpath; rehash'
 167 ## utils
 168 alias h='fc -l -25'
 169 alias j='jobs -l'
 170 alias l='ls -AF'
 171 if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
 172     alias ll='ls -lAFho'
 173 } else {
 174     alias ll='ls -lAFh'
 175 }
 176 alias p=\$PAGER
 177 alias e=\$EDITOR
 178 alias se=sudoedit
 179 # be paranoid
 180 alias cp='cp -ip'
 181 alias mv='mv -i'
 182 if [[ "$OSTYPE" =~ '^freebsd' ]] {
 183     # don't confirm if only a few files are deleted
 184     alias rm='rm -I'
 185 } else {
 186     # TODO: similar behavior for non-freebsd, or impliment in zsh
 187     alias rm='rm -i'
 188 }
 189 [[ -v commands[trash-put] ]] && alias t=trash-put
 190 ## py venv
 191 alias va='source bin/activate'
 192 alias vd=deactivate
 193 ## ps
 194 source ~/.local/bin/.check-busybox
 195 if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
 196     # use pstree, but NOT busybox pstree because it kinda sucks
 197     ps="pstree -wg3"
 198 elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
 199     ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
 200        -o%cpu,%mem,tty,stat,start=START -oetime,command"
 201 elif check-busybox ps; then
 202     # busybox compatible
 203     ps="ps -eouser='USR     ' -ogroup='GRP     ' \
 204        -opid='  PID' -onice=' NI' -ovsz=' MEM' \
 205        -otty,stat,etime,comm"
 206 else
 207     # XXX: untested, posix
 208     # TODO: support gnu ps
 209     ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
 210        -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
 211 fi
 212 unfunction check-busybox
 213 if [[ "$(basename "$PAGER")" = "less" ]] {
 214     ps="$ps | less -S"
 215 } else {
 216     ps="$ps | \"${PAGER:-more}\""
 217 }
 218 alias pa=$ps
 219 alias spa="sudo $ps"
 220 unset ps
 221 ## git
 222 alias gdh='git diff HEAD'
 223 alias ga='git add'
 224 alias gc='git commit'
 225 alias gca='git commit --amend'
 226 alias gp='git push'
 227 ## cd/zoxide
 228 function up {
 229     \cd $(printf '../%.0s' {1..${1:-1}})
 230 }
 231 alias u=up
 232 if [[ -v commands[zoxide] ]] {
 233     # https://github.com/ajeetdsouza/zoxide/issues/513
 234     eval "${$(zoxide init zsh):s#_files -/#_cd#}"
 235     alias cd=z
 236 }
 237
 238 ### hooks
 239 autoload -Uz add-zsh-hook
 240 _sev_exectime=
 241 function sev_preexec {
 242     # change terminal title to show command
 243     print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
 244     # save last exec time for bell
 245     # XXX: does not run for blank cmdline
 246     _sev_exectime=$SECONDS
 247     # update gpg forward, to always have unique filename and avoid clashes
 248     if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
 249         export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
 250         export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
 251     }
 252 }
 253 add-zsh-hook preexec sev_preexec
 254 function sev_precmd {
 255     # change terminal title
 256     # TODO: update and send BEL when job status changes
 257     print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
 258     # bell if exec takes 5s
 259     if (( SECONDS - _sev_exectime >= 5 )) print "\a"
 260     # we could update vcs_info here, but let prompt take care of it
 261     # if it doesn't use vcs, it can be ignored safely
 262 }
 263 add-zsh-hook precmd sev_precmd
 264 function sev_chpwd {
 265     # echo dir on cwd change
 266     ls -AF
 267 }
 268 add-zsh-hook chpwd sev_chpwd
 269
 270 ### system-specific configs and aliases
 271 case $OSTYPE; in
 272     freebsd*)
 273         ## colors
 274         export CLICOLOR=
 275         export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'
 276
 277         ## sound
 278         function s { sysctl hw.snd.default_unit${1:+\=$1} }
 279         alias vol mixer
 280
 281         ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
 282         # XXX: should probably use package-depends where possible, breaks when
 283         #      port name is different to package name
 284         #      (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
 285         function portpkg {
 286             case "$1" {
 287             build|run)
 288                 sudo pkg install -AU $(make ${1}-depends-list |
 289                            sed 's_/usr/ports/_ _' | tr -d '\n')
 290                 ;;
 291             *)  echo "Usage: \`portpkg <build|run>' in a port directory"
 292                 return 1;;
 293             }
 294         };;
 295     netbsd)
 296         ## sound
 297         function s {
 298             if [[ -z "$1" ]] {
 299                 ll /dev/mixer /dev/sound /dev/audio
 300                 return
 301             }
 302             for x in mixer sound audio; do
 303                 ln -sf /dev/$x"$1" /dev/$x
 304             done
 305         }
 306         function vol {
 307             if [[ -z "$1" ]] {
 308                 for x in $(mixerctl -a | grep 'outputs\.master'); do
 309                     echo $x
 310                 done
 311                 return
 312             }
 313             mixerctl -w outputs.master"$2"="$1"
 314         };;
 315     *)
 316         ## sound
 317         # TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
 318         function s {}
 319         function vol {}
 320 esac
 321
 322 ### prompt
 323 autoload -Uz promptinit && promptinit
 324 prompt arrows
 325
 326 ### load site-specific
 327 load-site-dotfile zshrc