complete .zshenv silence

[dotfiles.git] / base / .zshrc

### options
setopt NO_BEEP NO_CLOBBER
## cd
setopt AUTO_CD CDABLE_VARS
## completion
setopt GLOB_COMPLETE
## line
setopt EXTENDED_GLOB GLOB_DOTS MARK_DIRS NOMATCH NUMERIC_GLOB_SORT
## prompt
setopt PROMPT_SUBST
## jobs
setopt AUTO_CONTINUE
## history
setopt NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS

### keys
# TODO: investigate "^[[200~" bracketed-paste
bindkey -v
KEYTIMEOUT=10
## populate key array
if (( $#terminfo == 0 )) {
    # terminfo is not set or empty
    function find_keymap {
        for f in ${ZDOTDIR:-$HOME}/.zkbd/${TERM}{-${DISPLAY:-${VENDOR}-${OSTYPE}},}
            [[ -f $f ]] && keymap=$f && break
    }
    find_keymap
    if [[ -z $keymap ]] {
        if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
            echo
            autoload -Uz zkbd && zkbd
            unfunction zkbd
            find_keymap
        fi
        echo
    }
    if [[ -n $keymap ]] {
        source $keymap
    } else {
        echo "Failed to source keymap file $keymap" >&2
    }
    unfunction find_keymap; unset keymap
} else {
    # activate application mode for zle so terminfo keys work
    # NOTE: don't do this for zkbd since application mode shouldn't have been
    #       enabled by zkbd when the keymap file was generated
    if [[ -v terminfo[smkx] && -v terminfo[rmkx] ]] {
        autoload -Uz add-zle-hook-widget
        function _enter-application-mode { echoti smkx }
        add-zle-hook-widget line-init _enter-application-mode
        function _exit-application-mode { echoti rmkx }
        add-zle-hook-widget line-finish _exit-application-mode
        trap _exit-application-mode EXIT
    }
    # match zkbd hash as best we can to terminfo
    typeset -gA key
    key[F1]=$terminfo[kf1]
    key[F2]=$terminfo[kf2]
    key[F3]=$terminfo[kf3]
    key[F4]=$terminfo[kf4]
    key[F5]=$terminfo[kf5]
    key[F6]=$terminfo[kf6]
    key[F7]=$terminfo[kf7]
    key[F8]=$terminfo[kf8]
    key[F9]=$terminfo[kf9]
    key[F10]=$terminfo[kf10]
    key[F11]=$terminfo[kf11]
    key[F12]=$terminfo[kf12]
    key[Backspace]=$terminfo[kbs]
    key[Insert]=$terminfo[kich1]
    key[Home]=$terminfo[khome]
    key[PageUp]=$terminfo[kpp]
    key[Delete]=$terminfo[kdch1]
    key[End]=$terminfo[kend]
    key[PageDown]=$terminfo[knp]
    key[Up]=$terminfo[kcuu1]
    key[Down]=$terminfo[kcud1]
    key[Left]=$terminfo[kcub1]
    key[Right]=$terminfo[kcuf1]
    #key[Menu]=$terminfo[] #TODO: not in termcap?
}

## bind keys in both viins and vicmd modes
function multibind {
    local k=$key[$1]
    if [[ -n $k ]] {
        bindkey -- $k $2
        if [[ -v 3 ]] {
            # - will use same command as viins
            bindkey -a -- $k ${3:/-/$2}
        }
    }
}
multibind Backspace backward-delete-char vi-backward-char
multibind Insert    overwrite-mode       vi-insert
multibind Home      beginning-of-line    -
multibind PageUp    up-line-or-history   -
multibind Delete    delete-char          vi-delete-char
multibind End       end-of-line          -
multibind PageDown  down-line-or-history -
multibind Left      backward-char        vi-backward-char
multibind Right     forward-char         vi-forward-char
## history search
autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
multibind Up        up-line-or-beginning-search -
zle -N down-line-or-beginning-search
multibind Down      down-line-or-beginning-search -
unfunction multibind

### aliases
## generic abbreviations
alias h="history -25"
alias j="jobs -l"
alias l="ls -AF"
alias p="${PAGER:-more}" # TODO: make sure more is there or use safe default
alias e="${EDITOR:-vi}"  # TODO: make sure vi is there or use safe default
if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
    alias ll="ls -lAFho"
} else {
    alias ll="ls -lAFh"
}
alias se=sudoedit
## be paranoid
alias cp='cp -ip'
alias mv='mv -i'
if [[ "$OSTYPE" =~ '^freebsd' ]] {
    # don't confirm if only a few files are deleted
    alias rm='rm -I'
} else {
    # TODO: similar behavior for non-freebsd, or impliment in zsh
    alias rm='rm -i'
}
## go up directories
function up {
    cd $(printf '../%.0s' {1..${1:-1}})
}
## py venv
alias va="source bin/activate"
alias vd="deactivate"
## ps
# source helper function
source ~/bin/.check-busybox
if which pstree >/dev/null 2>&1 && ! check-busybox pstree; then
    # use pstree, but NOT busybox pstree because it kinda sucks
    ps="pstree -wg3"
elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
    ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
       -o%cpu,%mem,tty,stat,start=START -oetime,command"
elif check-busybox ps; then
    # busybox compatible
    ps="ps -eouser='USR     ' -ogroup='GRP     ' \
       -opid='  PID' -onice=' NI' -ovsz=' MEM' \
       -otty,stat,etime,comm"
else
    # XXX: untested, posix
    # TODO: support gnu ps
    ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
       -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
fi
unfunction check-busybox
if [[ "$(basename "$PAGER")" = "less" ]] {
    ps="$ps | less -SE"
} else {
    ps="$ps | \"${PAGER:-more}\""
}
alias pa="$ps"
alias spa="sudo $ps"
unset ps

### hooks
autoload -Uz add-zsh-hook
_sev_exectime=
function sev_preexec {
    # change terminal title to show command
    print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
    # save last exec time for bell
    # XXX: does not run for blank cmdline
    _sev_exectime=$SECONDS
}
add-zsh-hook preexec sev_preexec
function sev_precmd {
    # change terminal title
    # TODO: update and send BEL when job status changes
    print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
    # bell if exec takes 5s
    if (( SECONDS - _sev_exectime >= 5 )) print "\a"
    # we could update vcs_info here, but let prompt take care of it
    # if it doesn't use vcs, it can be ignored safely
}
add-zsh-hook precmd sev_precmd
function sev_chpwd {
    # echo dir on cwd change
    ls -AF
}
add-zsh-hook chpwd sev_chpwd

### system-specific configs and aliases
case "$OSTYPE"; in
    freebsd*)
        # colors
        export CLICOLOR=
        export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'

        ## sound
        function s { sysctl hw.snd.default_unit${1:+\=$1} }
        alias vol mixer

        ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
        # XXX: should probably use package-depends where possible, breaks when
        #     port name is different to package name
        #     (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
        function portpkg {
            case "$1" {
            build|run)
                sudo pkg install -AU $(make ${1}-depends-list |
                           sed 's_/usr/ports/_ _' | tr -d '\n')
                ;;
            *)  echo "Usage: \`portpkg <build|run>' in a port directory"
                return 1;;
            }
        };;
    netbsd)
        ## sound
        function s {
            if [[ -z "$1" ]] {
                ll /dev/mixer /dev/sound /dev/audio
                return
            }
            for x in mixer sound audio; do
                ln -sf /dev/$x"$1" /dev/$x
            done
        }
        function vol {
            if [[ -z "$1" ]] {
                for x in $(mixerctl -a | grep 'outputs\.master'); do
                    echo $x
                done
                return
            }
            mixerctl -w outputs.master"$2"="$1"
        };;
    *)
        ## sound
        # TODO: test alsa/oss/sndio/portaudio/pulse in order of importance
        function s {}
        function vol {}
esac

### modules & styles
## vcs
zstyle ':vcs_info:*' enable git
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true
autoload -Uz vcs_info

## compinit
zstyle ':completion:*' auto-description '[arg] %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
autoload -Uz compinit && compinit

### prompt
autoload -Uz promptinit && promptinit
prompt arrows

### load site-specific
if [[ -f ~/.zshrc.local ]] { source ~/.zshrc.local }

# vim: set et sts=4 sw=4 ts=8 tw=79 :