[dotfiles.git] / etc / zsh / .zshrc

### options
setopt NO_BEEP NO_CLOBBER \
       AUTO_CD CDABLE_VARS \
       EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
       CORRECT_ALL INTERACTIVE_COMMENTS \
       GLOB_COMPLETE \
       AUTO_CONTINUE LONG_LIST_JOBS \
       NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS

### exports
## common
export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
## grep
# XXX: deprecated in GNU
export GREP_OPTIONS=--color=auto
## histfile
export HISTFILE=~/.histfile
export HISTSIZE=1000
export SAVEHIST=1000
## python
export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
## vim
export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"|execute"source"$MYVIMRC'
## wayland/sway
# XXX: only do this if we're actually in wayland, but without a start script
export XDG_SESSION_TYPE=wayland
export QT_QPA_PLATFORM=wayland-egl
export QT_WAYLAND_DISABLE_WINDOWDECORATION=-1
export SDL_VIDEODRIVER=wayland
export TERMINAL=${$(whence -p konsole footclient urxvt xterm)[(f)1]}

### imports
autoload -Uz zmv
autoload -Uz zmathfunc && zmathfunc

## vcs
zstyle ':vcs_info:*' enable git
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true
autoload -Uz vcs_info

## compinit
zstyle ':completion:*' auto-description '[arg] %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
autoload -Uz compinit
cache=${XDG_CACHE_HOME:-~/.cache}/zsh
[[ -d $cache ]] || mkdir -p $cache
compinit -d $cache/.zcompdump
unset cache

### keys
bindkey -v
KEYTIMEOUT=10
## populate key array
if (( $#terminfo == 0 )) {
    # terminfo is not set or empty
    function find_keymap {
        for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
            [[ -f $f ]] && keymap=$f && break
    }
    find_keymap
    if [[ -z $keymap ]] {
        if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
            echo
            autoload -Uz zkbd && zkbd
            unfunction zkbd
            find_keymap
        fi
        echo
    }
    if [[ -n $keymap ]] {
        source $keymap
    } else {
        echo "Failed to source keymap file $keymap" >&2
    }
    unfunction find_keymap; unset keymap
} else {
    # activate application mode for zle so terminfo keys work
    # NOTE: don't do this for zkbd since application mode shouldn't have been
    #       enabled by zkbd when the keymap file was generated
    if [[ -v terminfo[smkx] && -v terminfo[rmkx] ]] {
        autoload -Uz add-zle-hook-widget
        function _enter-application-mode { echoti smkx }
        add-zle-hook-widget line-init _enter-application-mode
        function _exit-application-mode { echoti rmkx }
        add-zle-hook-widget line-finish _exit-application-mode
        trap _exit-application-mode EXIT
    }
    # match zkbd hash as best we can to terminfo
    typeset -gA key
    key=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
         F10 kf10 F11 kf11 F12 kf12
         Backspace kbs
         Backtab   kcbt
         Shift-Tab kcbt
         Insert    kich1
         Home      khome
         PageUp    kpp
         Delete    kdch1
         End       kend
         PageDown  knp
         Up        kcuu1
         Down      kcud1
         Left      kcub1
         Right     kcuf1
    )
    for k v in ${(kv)key}; do
        key[$k]=$terminfo[$v]
    done; unset k v
}

## load history search
autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
zle -N up-line-or-beginning-search
zle -N down-line-or-beginning-search

## bind keys in both viins and vicmd modes
typeset -A a
a=(
    #key       viins                         vicmd
    Backspace 'backward-delete-char          vi-backward-char'
    Insert    'overwrite-mode                vi-insert'
    Home      'beginning-of-line'
    PageUp    'up-history                    -'
    Delete    'delete-char'
    End       'end-of-line'
    PageDown  'down-history                  -'
    Up        'up-line-or-beginning-search   vi-up-line-or-history'
    Down      'down-line-or-beginning-search vi-down-line-or-history'
    Left      'backward-char'
    Right     'forward-char'
)
for k v in ${(kv)a}; do
    k=$key[$k]
    if [[ -z "$k" ]] { continue }
    v=($=v)
    bindkey -- $k $v[1]
    if [[ $v[2] == '-' ]] {
        # copy viins to vicmd verbatim
        bindkey -a -- $k $v[1]
    } elif (( $#v != 1 )) {
        # set vicmd to any other value
        bindkey -a -- $k $v[2]
    } else {
        # copy viins to vicmd and prepend vi- to it
        bindkey -a -- $k vi-$v[1]
    }
done
unset a k v

### abbreviation aliases
alias h='fc -l -25'
alias j='jobs -l'
alias l='ls -AF'
if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
    alias ll='ls -lAFho'
} else {
    alias ll='ls -lAFh'
}
alias p=\$PAGER
alias e=\$EDITOR
alias se=sudoedit
# be paranoid
alias cp='cp -ip'
alias mv='mv -i'
if [[ "$OSTYPE" =~ '^freebsd' ]] {
    # don't confirm if only a few files are deleted
    alias rm='rm -I'
} else {
    # TODO: similar behavior for non-freebsd, or impliment in zsh
    alias rm='rm -i'
}
[[ -v commands[trash-put] ]] && alias t=trash-put
## py venv
alias va='source bin/activate'
alias vd=deactivate
## ps
source ~/.local/bin/.check-busybox
if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
    # use pstree, but NOT busybox pstree because it kinda sucks
    ps="pstree -wg3"
elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
    ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
       -o%cpu,%mem,tty,stat,start=START -oetime,command"
elif check-busybox ps; then
    # busybox compatible
    ps="ps -eouser='USR     ' -ogroup='GRP     ' \
       -opid='  PID' -onice=' NI' -ovsz=' MEM' \
       -otty,stat,etime,comm"
else
    # XXX: untested, posix
    # TODO: support gnu ps
    ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
       -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
fi
unfunction check-busybox
if [[ "$(basename "$PAGER")" = "less" ]] {
    ps="$ps | less -S"
} else {
    ps="$ps | \"${PAGER:-more}\""
}
alias pa=$ps
alias spa="sudo $ps"
unset ps
## git
alias gdh='git diff HEAD'
alias ga='git add'
alias gc='git commit'
alias gca='git commit --amend'
alias gp='git push'
## cd/zoxide
function up {
    \cd $(printf '../%.0s' {1..${1:-1}})
}
alias u=up
if [[ -v commands[zoxide] ]] {
    eval "$(zoxide init zsh)"
    alias cd=z
}

### hooks
autoload -Uz add-zsh-hook
_sev_exectime=
function sev_preexec {
    # change terminal title to show command
    print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
    # save last exec time for bell
    # XXX: does not run for blank cmdline
    _sev_exectime=$SECONDS
    # update gpg forward, to always have unique filename and avoid clashes
    if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
        export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
        export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
    }
}
add-zsh-hook preexec sev_preexec
function sev_precmd {
    # change terminal title
    # TODO: update and send BEL when job status changes
    print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
    # bell if exec takes 5s
    if (( SECONDS - _sev_exectime >= 5 )) print "\a"
    # we could update vcs_info here, but let prompt take care of it
    # if it doesn't use vcs, it can be ignored safely
}
add-zsh-hook precmd sev_precmd
function sev_chpwd {
    # echo dir on cwd change
    ls -AF
}
add-zsh-hook chpwd sev_chpwd

### system-specific configs and aliases
case $OSTYPE; in
    freebsd*)
        # colors
        export CLICOLOR=
        export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'

        ## sound
        function s { sysctl hw.snd.default_unit${1:+\=$1} }
        alias vol mixer

        ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
        # XXX: should probably use package-depends where possible, breaks when
        #     port name is different to package name
        #     (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
        function portpkg {
            case "$1" {
            build|run)
                sudo pkg install -AU $(make ${1}-depends-list |
                           sed 's_/usr/ports/_ _' | tr -d '\n')
                ;;
            *)  echo "Usage: \`portpkg <build|run>' in a port directory"
                return 1;;
            }
        };;
    netbsd)
        ## sound
        function s {
            if [[ -z "$1" ]] {
                ll /dev/mixer /dev/sound /dev/audio
                return
            }
            for x in mixer sound audio; do
                ln -sf /dev/$x"$1" /dev/$x
            done
        }
        function vol {
            if [[ -z "$1" ]] {
                for x in $(mixerctl -a | grep 'outputs\.master'); do
                    echo $x
                done
                return
            }
            mixerctl -w outputs.master"$2"="$1"
        };;
    *)
        ## sound
        # TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
        function s {}
        function vol {}
esac

### prompt
autoload -Uz promptinit && promptinit
prompt arrows

### load site-specific
load-site-dotfile zshrc
Commit	Line	Data
43016843	1	### options
a7e41770	2	setopt NO_BEEP NO_CLOBBER \
	3	AUTO_CD CDABLE_VARS \
	4	EXTENDED_GLOB GLOB_DOTS GLOB_STAR_SHORT MARK_DIRS NUMERIC_GLOB_SORT \
	5	CORRECT_ALL INTERACTIVE_COMMENTS \
	6	GLOB_COMPLETE \
	7	AUTO_CONTINUE LONG_LIST_JOBS \
	8	NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY HIST_REDUCE_BLANKS
43016843	9
79d4a356	10	### exports
79d4a356	11	## common
8d4a98e1	12	export EDITOR=${$(whence -p nvim vim vi micro nano emacs)[(f)1]}
8d4a98e1	13	export PAGER=${$(whence -p less micro nano more)[(f)1]:s/micro/& -readonly true -multiopen tab/:s/nano/& --view}
79d4a356	14	## grep
	15	# XXX: deprecated in GNU
	16	export GREP_OPTIONS=--color=auto
	17	## histfile
	18	export HISTFILE=~/.histfile
	19	export HISTSIZE=1000
	20	export SAVEHIST=1000
	21	## python
8d4a98e1	22	export PYTHONSTARTUP=${XDG_CONFIG_HOME:-~/.config}/pythonrc
8d4a98e1	23	## vim
e69caf64	24	export VIMINIT='let$MYVIMRC=($XDG_CONFIG_HOME??($HOME."/.config"))."/vim/.vimrc"\|execute"source"$MYVIMRC'
d23b28eb	25	## wayland/sway
	26	# XXX: only do this if we're actually in wayland, but without a start script
	27	export XDG_SESSION_TYPE=wayland
	28	export QT_QPA_PLATFORM=wayland-egl
	29	export QT_WAYLAND_DISABLE_WINDOWDECORATION=-1
	30	export SDL_VIDEODRIVER=wayland
8d4a98e1	31	export TERMINAL=${$(whence -p konsole footclient urxvt xterm)[(f)1]}
79d4a356	32
2bf94bab	33	### imports
	34	autoload -Uz zmv
	35	autoload -Uz zmathfunc && zmathfunc
	36
	37	## vcs
	38	zstyle ':vcs_info:*' enable git
	39	#zstyle ':vcs_info:git*' check-for-changes true #too slow
	40	zstyle ':vcs_info:git*:dotfiles' check-for-changes true
	41	zstyle ':vcs_info:git*' check-for-staged-changes true
	42	autoload -Uz vcs_info
	43
	44	## compinit
	45	zstyle ':completion:*' auto-description '[arg] %d'
	46	zstyle ':completion:*' expand suffix
	47	zstyle ':completion:*' format '# %d'
	48	zstyle ':completion:*' group-name ''
	49	zstyle ':completion:*' ignore-parents parent
	50	zstyle ':completion:*' insert-unambiguous false
	51	zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
	52	zstyle ':completion:*' list-prompt '%B%i%b'
	53	zstyle ':completion:*' list-suffixes true
	54	zstyle ':completion:' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:\|[._-]= r:\|=' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:\|= r:\|=*'
	55	zstyle ':completion:*' menu select=1
	56	zstyle ':completion:*' original false
	57	zstyle ':completion:*' select-prompt '%B%l%b'
	58	zstyle ':completion:*' verbose true
	59	autoload -Uz compinit
	60	cache=${XDG_CACHE_HOME:-~/.cache}/zsh
	61	[[ -d $cache ]] \|\| mkdir -p $cache
	62	compinit -d $cache/.zcompdump
	63	unset cache
	64
43016843	65	### keys
43016843	66	bindkey -v
	67	KEYTIMEOUT=10
	68	## populate key array
	69	if (( $#terminfo == 0 )) {
	70	# terminfo is not set or empty
	71	function find_keymap {
8d4a98e1	72	for f in ${ZDOTDIR:-~}/.zkbd/$TERM{-${DISPLAY:-$VENDOR-$OSTYPE},}
43016843	73	[[ -f $f ]] && keymap=$f && break
	74	}
	75	find_keymap
	76	if [[ -z $keymap ]] {
	77	if read -q "?Can't read terminfo. Add new zkbd keymap? [y/N]"; then
	78	echo
	79	autoload -Uz zkbd && zkbd
	80	unfunction zkbd
	81	find_keymap
	82	fi
	83	echo
	84	}
	85	if [[ -n $keymap ]] {
	86	source $keymap
	87	} else {
c3608beb	88	echo "Failed to source keymap file $keymap" >&2
43016843	89	}
	90	unfunction find_keymap; unset keymap
	91	} else {
	92	# activate application mode for zle so terminfo keys work
c3608beb	93	# NOTE: don't do this for zkbd since application mode shouldn't have been
c3608beb	94	# enabled by zkbd when the keymap file was generated
43016843	95	if [[ -v terminfo[smkx] && -v terminfo[rmkx] ]] {
	96	autoload -Uz add-zle-hook-widget
	97	function _enter-application-mode { echoti smkx }
	98	add-zle-hook-widget line-init _enter-application-mode
	99	function _exit-application-mode { echoti rmkx }
	100	add-zle-hook-widget line-finish _exit-application-mode
	101	trap _exit-application-mode EXIT
	102	}
	103	# match zkbd hash as best we can to terminfo
	104	typeset -gA key
5b9a654a	105	key=(F1 kf1 F2 kf2 F3 kf3 F4 kf4 F5 kf5 F6 kf6 F7 kf7 F8 kf8 F9 kf9
	106	F10 kf10 F11 kf11 F12 kf12
	107	Backspace kbs
	108	Backtab kcbt
	109	Shift-Tab kcbt
	110	Insert kich1
	111	Home khome
	112	PageUp kpp
	113	Delete kdch1
	114	End kend
	115	PageDown knp
	116	Up kcuu1
	117	Down kcud1
	118	Left kcub1
	119	Right kcuf1
	120	)
	121	for k v in ${(kv)key}; do
	122	key[$k]=$terminfo[$v]
	123	done; unset k v
43016843	124	}
2bf94bab	125
5b9a654a	126	## load history search
43016843	127	autoload -Uz up-line-or-beginning-search down-line-or-beginning-search
43016843	128	zle -N up-line-or-beginning-search
43016843	129	zle -N down-line-or-beginning-search
43016843	130
5b9a654a	131	## bind keys in both viins and vicmd modes
	132	typeset -A a
	133	a=(
	134	#key viins vicmd
	135	Backspace 'backward-delete-char vi-backward-char'
	136	Insert 'overwrite-mode vi-insert'
	137	Home 'beginning-of-line'
	138	PageUp 'up-history -'
	139	Delete 'delete-char'
	140	End 'end-of-line'
	141	PageDown 'down-history -'
	142	Up 'up-line-or-beginning-search vi-up-line-or-history'
	143	Down 'down-line-or-beginning-search vi-down-line-or-history'
	144	Left 'backward-char'
	145	Right 'forward-char'
	146	)
	147	for k v in ${(kv)a}; do
	148	k=$key[$k]
	149	if [[ -z "$k" ]] { continue }
	150	v=($=v)
	151	bindkey -- $k $v[1]
	152	if [[ $v[2] == '-' ]] {
	153	# copy viins to vicmd verbatim
	154	bindkey -a -- $k $v[1]
	155	} elif (( $#v != 1 )) {
	156	# set vicmd to any other value
	157	bindkey -a -- $k $v[2]
	158	} else {
	159	# copy viins to vicmd and prepend vi- to it
	160	bindkey -a -- $k vi-$v[1]
	161	}
	162	done
	163	unset a k v
	164
	165	### abbreviation aliases
8d4a98e1	166	alias h='fc -l -25'
5b9a654a	167	alias j='jobs -l'
5b9a654a	168	alias l='ls -AF'
43016843	169	if [[ "$OSTYPE" =~ '^(free\|net)bsd' ]] {
5b9a654a	170	alias ll='ls -lAFho'
43016843	171	} else {
5b9a654a	172	alias ll='ls -lAFh'
43016843	173	}
b053a418	174	alias p=\$PAGER
b053a418	175	alias e=\$EDITOR
43016843	176	alias se=sudoedit
5b9a654a	177	# be paranoid
43016843	178	alias cp='cp -ip'
	179	alias mv='mv -i'
	180	if [[ "$OSTYPE" =~ '^freebsd' ]] {
	181	# don't confirm if only a few files are deleted
	182	alias rm='rm -I'
	183	} else {
	184	# TODO: similar behavior for non-freebsd, or impliment in zsh
	185	alias rm='rm -i'
	186	}
8d4a98e1	187	[[ -v commands[trash-put] ]] && alias t=trash-put
43016843	188	## py venv
79d4a356	189	alias va='source bin/activate'
79d4a356	190	alias vd=deactivate
43016843	191	## ps
8d4a98e1	192	source ~/.local/bin/.check-busybox
79d4a356	193	if [[ -v commands[pstree] ]] && ! check-busybox pstree; then
43016843	194	# use pstree, but NOT busybox pstree because it kinda sucks
	195	ps="pstree -wg3"
	196	elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
	197	ps="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
	198	-o%cpu,%mem,tty,stat,start=START -oetime,command"
	199	elif check-busybox ps; then
	200	# busybox compatible
	201	ps="ps -eouser='USR ' -ogroup='GRP ' \
	202	-opid=' PID' -onice=' NI' -ovsz=' MEM' \
	203	-otty,stat,etime,comm"
	204	else
	205	# XXX: untested, posix
	206	# TODO: support gnu ps
	207	ps="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
	208	-opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
	209	fi
	210	unfunction check-busybox
	211	if [[ "$(basename "$PAGER")" = "less" ]] {
109fad20	212	ps="$ps \| less -S"
43016843	213	} else {
	214	ps="$ps \| \"${PAGER:-more}\""
	215	}
79d4a356	216	alias pa=$ps
43016843	217	alias spa="sudo $ps"
43016843	218	unset ps
2bf94bab	219	## git
	220	alias gdh='git diff HEAD'
	221	alias ga='git add'
	222	alias gc='git commit'
	223	alias gca='git commit --amend'
	224	alias gp='git push'
	225	## cd/zoxide
5b9a654a	226	function up {
b053a418	227	\cd $(printf '../%.0s' {1..${1:-1}})
5b9a654a	228	}
79d4a356	229	alias u=up
b053a418	230	if [[ -v commands[zoxide] ]] {
b053a418	231	eval "$(zoxide init zsh)"
6c74cef6	232	alias cd=z
b053a418	233	}
5b9a654a	234
43016843	235	### hooks
	236	autoload -Uz add-zsh-hook
	237	_sev_exectime=
	238	function sev_preexec {
	239	# change terminal title to show command
	240	print -n "\e]2;$(print -P '%#')${SSH_CLIENT+$USER@$HOST:}$1\e\\"
	241	# save last exec time for bell
	242	# XXX: does not run for blank cmdline
	243	_sev_exectime=$SECONDS
1ef46e01	244	# update gpg forward, to always have unique filename and avoid clashes
	245	if [[ -v _GNUPG_SOCK_DEST_EXT ]] {
	246	export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
	247	export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
	248	}
43016843	249	}
	250	add-zsh-hook preexec sev_preexec
	251	function sev_precmd {
	252	# change terminal title
	253	# TODO: update and send BEL when job status changes
	254	print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
	255	# bell if exec takes 5s
	256	if (( SECONDS - _sev_exectime >= 5 )) print "\a"
	257	# we could update vcs_info here, but let prompt take care of it
	258	# if it doesn't use vcs, it can be ignored safely
	259	}
	260	add-zsh-hook precmd sev_precmd
	261	function sev_chpwd {
	262	# echo dir on cwd change
	263	ls -AF
	264	}
	265	add-zsh-hook chpwd sev_chpwd
	266
	267	### system-specific configs and aliases
79d4a356	268	case $OSTYPE; in
43016843	269	freebsd*)
	270	# colors
	271	export CLICOLOR=
	272	export LS_COLORS='di=34:ln=35:so=32:pi=33:ex=31:bd=46;34:cd=43;34:su=41;30:sg=46;30:tw=42;30:ow=43;30'
	273
	274	## sound
	275	function s { sysctl hw.snd.default_unit${1:+\=$1} }
	276	alias vol mixer
	277
	278	## install port dependencies from pkg (like pkgsrc `bmake bin-install')
	279	# XXX: should probably use package-depends where possible, breaks when
	280	# port name is different to package name
	281	# (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
	282	function portpkg {
	283	case "$1" {
	284	build\|run)
	285	sudo pkg install -AU $(make ${1}-depends-list \|
	286	sed 's_/usr/ports/_ _' \| tr -d '\n')
	287	;;
	288	*) echo "Usage: \`portpkg <build\|run>' in a port directory"
	289	return 1;;
	290	}
	291	};;
	292	netbsd)
	293	## sound
	294	function s {
	295	if [[ -z "$1" ]] {
	296	ll /dev/mixer /dev/sound /dev/audio
	297	return
	298	}
	299	for x in mixer sound audio; do
	300	ln -sf /dev/$x"$1" /dev/$x
	301	done
	302	}
	303	function vol {
	304	if [[ -z "$1" ]] {
	305	for x in $(mixerctl -a \| grep 'outputs\.master'); do
	306	echo $x
	307	done
	308	return
	309	}
	310	mixerctl -w outputs.master"$2"="$1"
	311	};;
	312	*)
	313	## sound
8d4a98e1	314	# TODO: test alsa/oss/sndio/portaudio/pulse/pipewire in order of importance
43016843	315	function s {}
	316	function vol {}
	317	esac
	318
43016843	319	### prompt
	320	autoload -Uz promptinit && promptinit
	321	prompt arrows
	322
8eb81f95	323	### load site-specific
4ced48ed	324	load-site-dotfile zshrc