[dotfiles.git] / base / .zprofile

# NOTE:
# our .zprofile is expensive, so we keep track of what has been run already,
# and only set up what is necessary. additionally, we want to ensure that our
# environment is set up as early as possible, so we also source .zprofile in
# .zshenv for new non-login shells.
#
# these issues are handled by using these methods:
#   * the parent shell that starts the user's session after logging in to some
#     graphical environments may not be a login shell—due to misconfiguration
#     or otherwise—which means .zprofile is not ran and the environment is not
#     properly configured for any child processes.
#   * some desktop environments/graphical terminal emulators will start new
#     terminal windows with login shells, which runs .zprofile every time and
#     leads to noticably slow startup times.
#   * switching users without wiping the environment will result in paths and
#     variables intended for the old user being used for the new user. while
#     this may be considered an edge-case that should not be supported, there
#     are legitimate reasons to want to do this, and in any case the shell
#     should not choke or cause unexpected problems should it happen anyway.

### cleanup
# XXX: only call after relevant vars have been set up, defined early so that
#      below code can utilize it after they do so
function _sev_zcleanup {
    ## gpg forwarding
    if [[ -d $_sev_gpg_forward_dir && ( -z $1 || $1 == 'gpg-forward' ) ]] {
        # clean up forward dirs if its session is dead or we ask for it
        find $_sev_gpg_forward_dir -type d -mindepth 1 -maxdepth 1 |
          while {read -r x} {
            # NOTE: the only way we can get here is if we have not been
            #       forwarded before, if the user asks for it, or during
            #       logout. if our own pid already has a dir, it is most likely
            #       stale, the user wants it removed, or something is very
            #       broken—in all 3 of these cases the best choice is remove it.
            p=$(basename $x)
            if {[[ -v _sev_gpg_forward_clean || $$ == $p ]] ||
                ! kill -0 $p 2>/dev/null} {
                find $x -mindepth 1 -maxdepth 1 | while {read -r y} {
                    # XXX: real dirs will stop unlink, consider it a feature
                    unlink $y
                }
                # don't force in case something important is still there
                rmdir $x
            }
        }
        # reset GNUPGHOME if we removed our own dir
        if [[ $GNUPGHOME =~ '/.ssh_forward/\d+/*$' && ! -e $GNUPGHOME ]] {
            x=$GNUPGHOME
            [[ -o GLOB_ASSIGN ]]; y=$?
            setopt GLOB_ASSIGN
            GNUPGHOME=$GNUPGHOME/../..(:a)
            (( y != 0 )) && unsetopt GLOB_ASSIGN
        }
    }

    ## tmp
    # NOTE: _sev_tmp is not unset so session dirs will not be recreated
    # NOTE: XDG dirs that use our tmp are not unset here, they are in zlogout
    if [[ -d $_sev_tmp && ( -z $1 || $1 == 'tmp' ) ]] {
        # clean up tmp dirs if its session is dead or we ask for it
        find $_sev_tmp -name '.session.*' -type d -mindepth 1 -maxdepth 1 |
          while {read -r x} {
            # NOTE: same rationale as above
            p=${$(basename $x)#.session.}
            if {[[ -v _sev_tmp_clean || $$ == $p ]] ||
                ! kill -0 $p 2>/dev/null} {
                rm -rf $x
            }
        }
    }

    unset x p y
}

### lang
export CHARSET=${CHARSET:-UTF-8}
export LANG=${LANG:-en_US.UTF-8}
export LC_CTYPE=${LC_TYPE:-$LANG}

### path
# NOTE: we utilize the fact that unique arrays keep the first occurrence and
#       remove any further occurences to capture elements from the old PATH
#       that we did not anticipate and shift them to the front, since they are
#       probably important to the system
if [[ ! -v _sev_setup_path || -o login ]] {
    typeset -U path fpath
    # add as many generic paths as possible to keep the order we want
    # NOTE: /usr/{local,pkg,games} are unix/bsdisms
    syspath=("$path[@]")
    path=({~,~/.local,,/usr,/opt,/usr/local,/usr/pkg}/sbin
          {~,~/.local,,/usr,/opt,/usr/local,/usr/pkg}/bin
          /usr/X11R{7,6}/bin /usr/games)
    ((len=$#path))
    path=("$path[@]" "$syspath[@]")
    # remove nonexistent and duplicate paths
    for (( i = 1; i <= $#path; i++ )) {
        if [[ ! -e $path[$i] ]] {
            path[$i]=()
            ((i <= len)) && ((len--))
            ((i--))
            continue
        }
    }
    # shift valid system paths to the front if there are any left
    ((len > 0 && len < $#path)) && path=("${(@)path[len + 1, -1]}" "${(@)path[1, len]}")
    unset syspath len i j
    # include our zsh dir in fpath. unlike above, we always prefer our paths
    fpath=(${ZDOTDIR:-~/.zsh}/functions/{*,Completions/*}(N) "$fpath[@]")
    # FPATH is not exported by default
    export FPATH
    typeset +U path fpath
    export _sev_setup_path=
}

### tmp
# NOTE: specs say that POSIX tmp and XDG runtime directories should exist
#       until the last session is logged out (POSIX can exist for longer).
#       since we can't reliably keep track of sessions in a cross-platform
#       manner, the current implementation should use a separate directory per
#       toplevel session (i.e. SHLVL=1). this should placate most applications,
#       though it is not expressly spec compliant.
if [[ ! -v _sev_tmp ]] {
    _sev_tmp=~/tmp
    # create personal tmp dir
    t=${TMPDIR:-${TEMP:-${TMP:-/tmp}}}/.home-$LOGNAME
    [[ ! -e $t ]] && mkdir -m700 $t 2>/dev/null
    if [[ ! -d $t ]] {
        [[ -o interactive ]] &&
          print -P "%F{red}!!! Can't create tmpdir $t%f"
        # fallback bare directories
        [[ -h $_sev_tmp ]] && unlink $_sev_tmp 2>/dev/null
        [[ ! -e $_sev_tmp ]] && mkdir -m700 $_sev_tmp 2>/dev/null
    }
    # link home tmp for convenience if there isn't anything meaningful there
    [[ -h $_sev_tmp || ! -e $_sev_tmp ]] && ln -sfn $t $_sev_tmp 2>/dev/null
    export _sev_tmp=$(realpath $_sev_tmp)
    # ensure dir is clean
    _sev_zcleanup tmp
    # finally create our subdir for this session
    h=$_sev_tmp/.session.$$
    mkdir -m700 $h 2>/dev/null
    export TMPDIR=$h TEMP=$h TMP=$h
    unset t h
}

### xdg
if [[ ! -v _sev_setup_xdg ]] {
    # merge with any existing dirs and remove duplicates using unique arrays
    # NOTE: include and then remove CONFIG_HOME and DATA_HOME to ensure they
    #       are not present in the array if it was added before we got to it
    typeset -UT XDG_CONFIG_DIRS xdg_config_dirs
    export XDG_CONFIG_HOME=~/etc
    mkdir $XDG_CONFIG_HOME 2>/dev/null
    xdg_config_dirs=($XDG_CONFIG_HOME ~/.config
      {/opt,/usr/local,/usr/pkg,}/etc/xdg
      "${XDG_CONFIG_DIRS:+${xdg_config_dirs[@]}}")
    export XDG_CONFIG_DIRS=${XDG_CONFIG_DIRS#$XDG_CONFIG_HOME}

    typeset -UT XDG_DATA_DIRS xdg_data_dirs
    export XDG_DATA_HOME=~/share
    mkdir $XDG_DATA_HOME 2>/dev/null
    xdg_data_dirs=($XDG_DATA_HOME ~/.local/share
      /{opt,usr/local,usr/pkg,usr}/share
      "${XDG_DATA_DIRS:+${xdg_data_dirs[@]}}")
    export XDG_DATA_DIRS=${XDG_DATA_DIRS#$XDG_DATA_HOME}

    mkdir ~/var 2>/dev/null
    export XDG_STATE_HOME=~/var/lib
    mkdir $XDG_STATE_HOME 2>/dev/null

    if [[ -v _sev_tmp ]] {
        export XDG_CACHE_HOME=$_sev_tmp/.xdg.cache
        mkdir $XDG_CACHE_HOME 2>/dev/null

        export XDG_RUNTIME_DIR=$TMPDIR/.xdg.runtime
        # same as in tmpdir creation, ensure it doesn't exist
        if [[ -h $XDG_RUNTIME_DIR ]]; then
            unlink $XDG_RUNTIME_DIR 2>/dev/null
        elif [[ -e $XDG_RUNTIME_DIR ]]; then
            rm -rf $XDG_RUNTIME_DIR 2>/dev/null
        fi
        mkdir -m700 $XDG_RUNTIME_DIR 2>/dev/null
    }

    # source user dirs after other vars
    [[ -e $XDG_CONFIG_HOME/user-dirs.dirs ]] &&
      emulate sh -c "source $XDG_CONFIG_HOME/user-dirs.dirs"
    export _sev_setup_xdg=
}

### dbus
if [[ ! -v DBUS_SESSION_BUS_ADDRESS && -v commands[dbus-launch] ]] {
    eval $(dbus-launch)
    export DBUS_SESSION_BUS_ADDRESS DBUS_SESSION_BUS_PID
}

### gpg home
if [[ ! -v GNUPGHOME ]] {
    export GNUPGHOME=~/etc/gnupg
    if [[ -d ~/.gnupg ]] {
        mv ~/.gnupg ~/etc/gnupg
    }
}

### gpg agent + forwarding
# NOTE: while ssh manages its auth sock in its protocol when ForwardSsh is
#       enabled, GPG must be forwarded manually over Unix socket. to support
#       this, we forward the restricted gpg-agent extra socket to the remote
#       host with a RemoteForward rule in ~/.ssh/config that uses the
#       _GNUPG_SOCK_* env vars. to avoid conflicts with other ssh sessions
#       where the same user is connecting to the same host from different
#       machines, gpg in each environment should utilize its own forwarded
#       socket, rather than replace the sockets in GNUPGHOME which will be
#       overridden on the next connection. previously, you could provide a path
#       to the agent socket in GPG_AGENT_INFO, but that was deprecated in GPG
#       v2.1. instead, we must clone GNUPGHOME with links and replace the agent
#       sockets there with the forwarded one.
# NOTE: since Unix sockets are not supported under Windows, this will not work
#       under msys, cygwin, mingw, etc., but may work under wsl2.
# HACK: without SendEnv, which is disabled by default in most sshd configs,
#       there is no foolproof way to prevent race conditions via filename
#       collisions or to pass the desired forward path to the remote host
#       environment. we just have to guess the path we choose is good on the
#       desination, and assume the newest matching socket is the correct one
#       after connecting. in theory, we could occlude the ssh binary on PATH
#       with an alias or script that would allow us to communicate with the
#       remote host before opening a shell, so that we can have the host
#       communicate back to the client where it wants a socket created or ask
#       the host if the path the client wants to use is writable. however, this
#       would open up too many edge cases where it wouldn't work or be clunky
#       (e.g. asking for password twice) to make it worth it.
function _gpg_socketpath {
    # dirs are percent-encoded: https://stackoverflow.com/a/64312099
    echo ${1//(#b)%([[:xdigit:]](#c2))/${(#):-0x$match[1]}}
}
if [[ ! -v _sev_setup_gpg_forward && -v commands[gpg] ]] {
    export _GNUPG_SOCK_DEST_BASE=/tmp/.gpg-agent-forward
    export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
    export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
    export _sev_gpg_forward_dir=${GNUPGHOME:-~/.gnupg}/.ssh_forward
    _sev_zcleanup gpg-forward

    # find our forwarded socket
    s=($_GNUPG_SOCK_DEST_BASE*(N=oc[1]))
    if [[ -n $s && -v SSH_CLIENT ]] {
        # create new forward dir
        export _sev_setup_gpg_forward=
        h=$_sev_gpg_forward_dir/$$
        mkdir -pm700 $h
        # XXX: is it safe to link scdaemon socket? can its name be changed?
        for x (S.scdaemon gpg.conf gpg-agent.conf sshcontrol
               pubring.kbx trustdb.gpg private-keys-v1.d crls.d) {
            ln -s ${GNUPGHOME:-~/.gnupg}/$x $h
        }
        export GNUPGHOME=$h
        unset h
        for x in $(gpgconf --list-dirs | grep 'agent-.*-\?socket:'); do
            x=$(_gpg_socketpath ${x/#agent-*socket:})
            if [[ ! -v orig ]] {
                # move forwarded socket to first valid agent socket path
                # XXX: if tmp is on different filesystem this may not work
                mv $s $x
                orig=$x
            } else {
                # make links to forwarded socket for any others
                ln -s $orig $x
            }
        done
        unset x orig
    }
    unset s

    # what we will forward if we start a new ssh connection
    # NOTE: do this after setting up GNUPGHOME to pick up new socket path;
    #       if already connected over SSH, extra should be the remote one
    export _GNUPG_SOCK_SRC=$(_gpg_socketpath \
      $(gpgconf --list-dirs agent-extra-socket))
} elif [[ ! -v _sev_setup_gpg_forward ]] {
    # required for RemoteForward to not error out if the vars are unset
    [[ ! -v _GNUPG_SOCK_SRC ]] && export _GNUPG_SOCK_SRC=/nonexistent
    [[ ! -v _GNUPG_SOCK_DEST ]] && export _GNUPG_SOCK_DEST=/nonexistent
}

### gpg agent
if [[ -v commands[gpg-connect-agent] && ( ! -v _sev_setup_gpgagent ||
        ( -v _sev_first_display && -z $_sev_first_display ) ) ]] {
    # avoid printing if we have already set up tty before
    [[ ! -v _sev_setup_gpgagent && -o interactive ]] && p=true || p=false
    if {$p} {
        print -nP '%F{blue}>>>%f GPG: '
        if [[ -v _sev_setup_gpg_forward ]] {
            a=agent
            print -nP '%F{yellow}Forwarded%f '
        } else { a=Agent }
        print -nP '%F{green}'
    }
    gpg-connect-agent /bye >/dev/null 2>&1
    if [[ $? -ne 0 ]] {
        $p && print -P '%F{red}$a communication error'
    } else {
        if [[ ${+GPG_TTY} -eq 0 && -o interactive ]]
            export GPG_TTY=$(tty)
        if [[ ( -v DISPLAY || -v WAYLAND_DISPLAY ) &&
              ${PINENTRY_USER_DATA/USE_TTY=0} == $PINENTRY_USER_DATA ]]
            export PINENTRY_USER_DATA=USE_TTY=$((
              ${+DISPLAY} + ${+WAYLAND_DISPLAY} == 0))
        # XXX: don't know if gpg-agent supports comments after directives
        # XXX: path could have #
        sed -Ei 's#^([[:space:]]*pinentry-program[[:space:]]).*$#\1'${commands[pinentry]:-/dev/null}'#' \
          ${GNUPGHOME:-~/.gnupg}/gpg-agent.conf
        # XXX: could probably check for changes before doing this to save perf
        gpg-connect-agent RELOADAGENT UPDATESTARTUPTTY /bye >/dev/null 2>&1
        $p && gpg-connect-agent /subst /serverpid \
                "/echo $a pid \${get serverpid} on $GPG_TTY" /bye
        export _sev_setup_gpgagent=
    }
    $p && print -nP '%f'
    unset p a
}

### ssh agent
if [[ ! -v _sev_setup_ssh ]] {
    # NOTE: preferred order of agents to check: okcagent, gnupg, openssh
    #       first block takes care of okcagent and openssh, second gnupg
    # XXX: doesn't actually check if ssh is enabled in gpg
    [[ -o interactive ]] && print -nP '%F{blue}>>>%f SSH: %F{green}'
    if [[ ! -v SSH_AUTH_SOCK && ( -v commands[okc-ssh-agent] ||
          ( -v commands[ssh-agent] && ! -v commands[gpg] ) ) ]] {
        okc=${commands[okc-ssh-agent]:+okc-}
        t=${_sev_tmp:-${TMPDIR:-${TEMP:-${TMP:-/tmp}}}}
        e=$t/${okc}ssh-agent-exports
        typeset sock=
        typeset -i pid=
        if [[ -f $e ]] {
            IFS=$'\0' read -r sock pid <$e
        }
        if [[ -S $sock && $pid > 0 ]] && kill -0 $pid; then
            [[ -o interactive ]] && print -P "Reusing agent PID $pid%f"
            export SSH_AUTH_SOCK=$sock
            export SSH_AGENT_PID=$pid
        else
            e='TMPDIR=$t ${okc}ssh-agent'
            # TODO: ensure ssh-agent path looks legit to avoid unsafe eval?
            # XXX: doesn't appear to be any other way to handle redirection.
            #      because eval needs to write to current scope environment
            #      subshells can't be used to capture output and print.
            if [[ -o interactive ]] {
                eval $(eval $=e)
                print -nP '%f'
            } else {
                eval $(eval $=e) >/dev/null 2>&1
            }
            echo -n $SSH_AUTH_SOCK$'\0'$SSH_AGENT_PID >!$e
        fi
        unset okc t e sock pid
    } elif [[ ! -v SSH_AUTH_SOCK && -v commands[gpg] ]] {
        # since gpg should have been started above, just export and notify
        if [[ -o interactive ]] {
            if [[ -v _sev_setup_gpg_forward ]] {
                echo 'Forwarded GPG agent'
            } else {
                gpg-connect-agent /subst /serverpid \
                  '/echo GPG agent pid ${get serverpid}' /bye
            }
            print -nP '%f'
        }
        export SSH_AUTH_SOCK=$(_gpg_socketpath \
          $(gpgconf --list-dirs agent-ssh-socket))
    } elif [[ -v SSH_AUTH_SOCK ]] {
        [[ -o interactive ]] && print -P 'Preconfigured agent%f'
    } else {
        [[ -o interactive ]] && print -P '%F{red}No agent available%f'
    }

    export _sev_setup_ssh=
}
unfunction _gpg_socketpath

### perl local lib
[[ -v commands[perl] && -d $XDG_DATA_HOME/perl5/lib/perl5 &&
   ! -v PERL_LOCAL_LIB_ROOT ]] &&
  eval $(perl -I$XDG_DATA_HOME/perl5/lib/perl5 \
              -Mlocal::lib=$XDG_DATA_HOME/perl5 2>/dev/null)


### load site-specific
if [[ -f ~/.zprofile.local ]] { source ~/.zprofile.local }

# vim: et sts=4 sw=4 ts=8 tw=79
Commit	Line	Data
79d4a356	1	# NOTE:
	2	# our .zprofile is expensive, so we keep track of what has been run already,
	3	# and only set up what is necessary. additionally, we want to ensure that our
	4	# environment is set up as early as possible, so we also source .zprofile in
	5	# .zshenv for new non-login shells.
	6	#
	7	# these issues are handled by using these methods:
	8	# * the parent shell that starts the user's session after logging in to some
	9	# graphical environments may not be a login shell—due to misconfiguration
	10	# or otherwise—which means .zprofile is not ran and the environment is not
	11	# properly configured for any child processes.
	12	# * some desktop environments/graphical terminal emulators will start new
	13	# terminal windows with login shells, which runs .zprofile every time and
	14	# leads to noticably slow startup times.
	15	# * switching users without wiping the environment will result in paths and
	16	# variables intended for the old user being used for the new user. while
	17	# this may be considered an edge-case that should not be supported, there
	18	# are legitimate reasons to want to do this, and in any case the shell
	19	# should not choke or cause unexpected problems should it happen anyway.
	20
6d54344e	21	### cleanup
	22	# XXX: only call after relevant vars have been set up, defined early so that
	23	# below code can utilize it after they do so
	24	function _sev_zcleanup {
	25	## gpg forwarding
	26	if [[ -d $_sev_gpg_forward_dir && ( -z $1 \|\| $1 == 'gpg-forward' ) ]] {
	27	# clean up forward dirs if its session is dead or we ask for it
	28	find $_sev_gpg_forward_dir -type d -mindepth 1 -maxdepth 1 \|
	29	while {read -r x} {
	30	# NOTE: the only way we can get here is if we have not been
	31	# forwarded before, if the user asks for it, or during
	32	# logout. if our own pid already has a dir, it is most likely
	33	# stale, the user wants it removed, or something is very
	34	# broken—in all 3 of these cases the best choice is remove it.
	35	p=$(basename $x)
	36	if {[[ -v _sev_gpg_forward_clean \|\| $$ == $p ]] \|\|
	37	! kill -0 $p 2>/dev/null} {
	38	find $x -mindepth 1 -maxdepth 1 \| while {read -r y} {
	39	# XXX: real dirs will stop unlink, consider it a feature
	40	unlink $y
	41	}
	42	# don't force in case something important is still there
	43	rmdir $x
	44	}
	45	}
	46	# reset GNUPGHOME if we removed our own dir
	47	if [[ $GNUPGHOME =~ '/.ssh_forward/\d+/*$' && ! -e $GNUPGHOME ]] {
	48	x=$GNUPGHOME
	49	[[ -o GLOB_ASSIGN ]]; y=$?
	50	setopt GLOB_ASSIGN
	51	GNUPGHOME=$GNUPGHOME/../..(:a)
	52	(( y != 0 )) && unsetopt GLOB_ASSIGN
	53	}
	54	}
	55
	56	## tmp
	57	# NOTE: _sev_tmp is not unset so session dirs will not be recreated
	58	# NOTE: XDG dirs that use our tmp are not unset here, they are in zlogout
	59	if [[ -d $_sev_tmp && ( -z $1 \|\| $1 == 'tmp' ) ]] {
	60	# clean up tmp dirs if its session is dead or we ask for it
	61	find $_sev_tmp -name '.session.*' -type d -mindepth 1 -maxdepth 1 \|
	62	while {read -r x} {
	63	# NOTE: same rationale as above
	64	p=${$(basename $x)#.session.}
	65	if {[[ -v _sev_tmp_clean \|\| $$ == $p ]] \|\|
	66	! kill -0 $p 2>/dev/null} {
	67	rm -rf $x
	68	}
	69	}
	70	}
	71
	72	unset x p y
	73	}
	74
833b2af3	75	### lang
6d54344e	76	export CHARSET=${CHARSET:-UTF-8}
	77	export LANG=${LANG:-en_US.UTF-8}
	78	export LC_CTYPE=${LC_TYPE:-$LANG}
	79
833b2af3	80	### path
79d4a356	81	# NOTE: we utilize the fact that unique arrays keep the first occurrence and
	82	# remove any further occurences to capture elements from the old PATH
	83	# that we did not anticipate and shift them to the front, since they are
	84	# probably important to the system
	85	if [[ ! -v _sev_setup_path \|\| -o login ]] {
79d4a356	86	typeset -U path fpath
	87	# add as many generic paths as possible to keep the order we want
	88	# NOTE: /usr/{local,pkg,games} are unix/bsdisms
	89	syspath=("$path[@]")
d23b28eb	90	path=({~,~/.local,,/usr,/opt,/usr/local,/usr/pkg}/sbin
	91	{~,~/.local,,/usr,/opt,/usr/local,/usr/pkg}/bin
	92	/usr/X11R{7,6}/bin /usr/games)
833b2af3	93	((len=$#path))
79d4a356	94	path=("$path[@]" "$syspath[@]")
	95	# remove nonexistent and duplicate paths
	96	for (( i = 1; i <= $#path; i++ )) {
	97	if [[ ! -e $path[$i] ]] {
	98	path[$i]=()
833b2af3	99	((i <= len)) && ((len--))
79d4a356	100	((i--))
	101	continue
	102	}
79d4a356	103	}
833b2af3	104	# shift valid system paths to the front if there are any left
	105	((len > 0 && len < $#path)) && path=("${(@)path[len + 1, -1]}" "${(@)path[1, len]}")
	106	unset syspath len i j
79d4a356	107	# include our zsh dir in fpath. unlike above, we always prefer our paths
	108	fpath=(${ZDOTDIR:-~/.zsh}/functions/{,Completions/}(N) "$fpath[@]")
	109	# FPATH is not exported by default
	110	export FPATH
	111	typeset +U path fpath
	112	export _sev_setup_path=
	113	}
	114
6d54344e	115	### tmp
	116	# NOTE: specs say that POSIX tmp and XDG runtime directories should exist
	117	# until the last session is logged out (POSIX can exist for longer).
	118	# since we can't reliably keep track of sessions in a cross-platform
	119	# manner, the current implementation should use a separate directory per
	120	# toplevel session (i.e. SHLVL=1). this should placate most applications,
	121	# though it is not expressly spec compliant.
	122	if [[ ! -v _sev_tmp ]] {
	123	_sev_tmp=~/tmp
	124	# create personal tmp dir
833b2af3	125	t=${TMPDIR:-${TEMP:-${TMP:-/tmp}}}/.home-$LOGNAME
6d54344e	126	[[ ! -e $t ]] && mkdir -m700 $t 2>/dev/null
833b2af3	127	if [[ ! -d $t ]] {
833b2af3	128	[[ -o interactive ]] &&
6d54344e	129	print -P "%F{red}!!! Can't create tmpdir $t%f"
833b2af3	130	# fallback bare directories
6d54344e	131	[[ -h $_sev_tmp ]] && unlink $_sev_tmp 2>/dev/null
6d54344e	132	[[ ! -e $_sev_tmp ]] && mkdir -m700 $_sev_tmp 2>/dev/null
833b2af3	133	}
6d54344e	134	# link home tmp for convenience if there isn't anything meaningful there
	135	[[ -h $_sev_tmp \|\| ! -e $_sev_tmp ]] && ln -sfn $t $_sev_tmp 2>/dev/null
	136	export _sev_tmp=$(realpath $_sev_tmp)
	137	# ensure dir is clean
	138	_sev_zcleanup tmp
833b2af3	139	# finally create our subdir for this session
6d54344e	140	h=$_sev_tmp/.session.$$
	141	mkdir -m700 $h 2>/dev/null
	142	export TMPDIR=$h TEMP=$h TMP=$h
833b2af3	143	unset t h
833b2af3	144	}
	145
	146	### xdg
79d4a356	147	if [[ ! -v _sev_setup_xdg ]] {
79d4a356	148	# merge with any existing dirs and remove duplicates using unique arrays
833b2af3	149	# NOTE: include and then remove CONFIG_HOME and DATA_HOME to ensure they
833b2af3	150	# are not present in the array if it was added before we got to it
79d4a356	151	typeset -UT XDG_CONFIG_DIRS xdg_config_dirs
d23b28eb	152	export XDG_CONFIG_HOME=~/etc
6d54344e	153	mkdir $XDG_CONFIG_HOME 2>/dev/null
d23b28eb	154	xdg_config_dirs=($XDG_CONFIG_HOME ~/.config
79d4a356	155	{/opt,/usr/local,/usr/pkg,}/etc/xdg
	156	"${XDG_CONFIG_DIRS:+${xdg_config_dirs[@]}}")
	157	export XDG_CONFIG_DIRS=${XDG_CONFIG_DIRS#$XDG_CONFIG_HOME}
d23b28eb	158
	159	typeset -UT XDG_DATA_DIRS xdg_data_dirs
	160	export XDG_DATA_HOME=~/share
6d54344e	161	mkdir $XDG_DATA_HOME 2>/dev/null
d23b28eb	162	xdg_data_dirs=($XDG_DATA_HOME ~/.local/share
79d4a356	163	/{opt,usr/local,usr/pkg,usr}/share
	164	"${XDG_DATA_DIRS:+${xdg_data_dirs[@]}}")
	165	export XDG_DATA_DIRS=${XDG_DATA_DIRS#$XDG_DATA_HOME}
d23b28eb	166
6d54344e	167	mkdir ~/var 2>/dev/null
d23b28eb	168	export XDG_STATE_HOME=~/var/lib
6d54344e	169	mkdir $XDG_STATE_HOME 2>/dev/null
	170
	171	if [[ -v _sev_tmp ]] {
	172	export XDG_CACHE_HOME=$_sev_tmp/.xdg.cache
	173	mkdir $XDG_CACHE_HOME 2>/dev/null
d23b28eb	174
6d54344e	175	export XDG_RUNTIME_DIR=$TMPDIR/.xdg.runtime
	176	# same as in tmpdir creation, ensure it doesn't exist
	177	if [[ -h $XDG_RUNTIME_DIR ]]; then
	178	unlink $XDG_RUNTIME_DIR 2>/dev/null
	179	elif [[ -e $XDG_RUNTIME_DIR ]]; then
	180	rm -rf $XDG_RUNTIME_DIR 2>/dev/null
833b2af3	181	fi
6d54344e	182	mkdir -m700 $XDG_RUNTIME_DIR 2>/dev/null
6d54344e	183	}
d23b28eb	184
79d4a356	185	# source user dirs after other vars
	186	[[ -e $XDG_CONFIG_HOME/user-dirs.dirs ]] &&
	187	emulate sh -c "source $XDG_CONFIG_HOME/user-dirs.dirs"
	188	export _sev_setup_xdg=
d569f3f7	189	}
79d4a356	190
6d54344e	191	### dbus
	192	if [[ ! -v DBUS_SESSION_BUS_ADDRESS && -v commands[dbus-launch] ]] {
	193	eval $(dbus-launch)
	194	export DBUS_SESSION_BUS_ADDRESS DBUS_SESSION_BUS_PID
	195	}
	196
	197	### gpg home
	198	if [[ ! -v GNUPGHOME ]] {
	199	export GNUPGHOME=~/etc/gnupg
	200	if [[ -d ~/.gnupg ]] {
	201	mv ~/.gnupg ~/etc/gnupg
	202	}
	203	}
	204
	205	### gpg agent + forwarding
79d4a356	206	# NOTE: while ssh manages its auth sock in its protocol when ForwardSsh is
	207	# enabled, GPG must be forwarded manually over Unix socket. to support
	208	# this, we forward the restricted gpg-agent extra socket to the remote
	209	# host with a RemoteForward rule in ~/.ssh/config that uses the
	210	# _GNUPG_SOCK_* env vars. to avoid conflicts with other ssh sessions
	211	# where the same user is connecting to the same host from different
	212	# machines, gpg in each environment should utilize its own forwarded
	213	# socket, rather than replace the sockets in GNUPGHOME which will be
	214	# overridden on the next connection. previously, you could provide a path
	215	# to the agent socket in GPG_AGENT_INFO, but that was deprecated in GPG
833b2af3	216	# v2.1. instead, we must clone GNUPGHOME with links and replace the agent
833b2af3	217	# sockets there with the forwarded one.
79d4a356	218	# NOTE: since Unix sockets are not supported under Windows, this will not work
833b2af3	219	# under msys, cygwin, mingw, etc., but may work under wsl2.
79d4a356	220	# HACK: without SendEnv, which is disabled by default in most sshd configs,
	221	# there is no foolproof way to prevent race conditions via filename
	222	# collisions or to pass the desired forward path to the remote host
	223	# environment. we just have to guess the path we choose is good on the
	224	# desination, and assume the newest matching socket is the correct one
	225	# after connecting. in theory, we could occlude the ssh binary on PATH
	226	# with an alias or script that would allow us to communicate with the
	227	# remote host before opening a shell, so that we can have the host
	228	# communicate back to the client where it wants a socket created or ask
	229	# the host if the path the client wants to use is writable. however, this
	230	# would open up too many edge cases where it wouldn't work or be clunky
	231	# (e.g. asking for password twice) to make it worth it.
6d54344e	232	function _gpg_socketpath {
	233	# dirs are percent-encoded: https://stackoverflow.com/a/64312099
	234	echo ${1//(#b)%([[:xdigit:]](#c2))/${(#):-0x$match[1]}}
	235	}
	236	if [[ ! -v _sev_setup_gpg_forward && -v commands[gpg] ]] {
	237	export _GNUPG_SOCK_DEST_BASE=/tmp/.gpg-agent-forward
	238	export _GNUPG_SOCK_DEST_EXT=$(date +%s).$RANDOM
	239	export _GNUPG_SOCK_DEST=$_GNUPG_SOCK_DEST_BASE.$_GNUPG_SOCK_DEST_EXT
	240	export _sev_gpg_forward_dir=${GNUPGHOME:-~/.gnupg}/.ssh_forward
	241	_sev_zcleanup gpg-forward
79d4a356	242
6d54344e	243	# find our forwarded socket
	244	s=($_GNUPG_SOCK_DEST_BASE*(N=oc[1]))
	245	if [[ -n $s && -v SSH_CLIENT ]] {
	246	# create new forward dir
	247	export _sev_setup_gpg_forward=
	248	h=$_sev_gpg_forward_dir/$$
	249	mkdir -pm700 $h
	250	# XXX: is it safe to link scdaemon socket? can its name be changed?
	251	for x (S.scdaemon gpg.conf gpg-agent.conf sshcontrol
	252	pubring.kbx trustdb.gpg private-keys-v1.d crls.d) {
	253	ln -s ${GNUPGHOME:-~/.gnupg}/$x $h
79d4a356	254	}
6d54344e	255	export GNUPGHOME=$h
	256	unset h
	257	for x in $(gpgconf --list-dirs \| grep 'agent-.*-\?socket:'); do
	258	x=$(_gpg_socketpath ${x/#agent-*socket:})
	259	if [[ ! -v orig ]] {
	260	# move forwarded socket to first valid agent socket path
	261	# XXX: if tmp is on different filesystem this may not work
	262	mv $s $x
	263	orig=$x
	264	} else {
	265	# make links to forwarded socket for any others
	266	ln -s $orig $x
	267	}
	268	done
	269	unset x orig
	270	}
	271	unset s
79d4a356	272
6d54344e	273	# what we will forward if we start a new ssh connection
	274	# NOTE: do this after setting up GNUPGHOME to pick up new socket path;
	275	# if already connected over SSH, extra should be the remote one
	276	export _GNUPG_SOCK_SRC=$(_gpg_socketpath \
	277	$(gpgconf --list-dirs agent-extra-socket))
	278	} elif [[ ! -v _sev_setup_gpg_forward ]] {
	279	# required for RemoteForward to not error out if the vars are unset
	280	[[ ! -v _GNUPG_SOCK_SRC ]] && export _GNUPG_SOCK_SRC=/nonexistent
	281	[[ ! -v _GNUPG_SOCK_DEST ]] && export _GNUPG_SOCK_DEST=/nonexistent
	282	}
79d4a356	283
6d54344e	284	### gpg agent
	285	if [[ -v commands[gpg-connect-agent] && ( ! -v _sev_setup_gpgagent \|\|
	286	( -v _sev_first_display && -z $_sev_first_display ) ) ]] {
	287	# avoid printing if we have already set up tty before
	288	[[ ! -v _sev_setup_gpgagent && -o interactive ]] && p=true \|\| p=false
	289	if {$p} {
	290	print -nP '%F{blue}>>>%f GPG: '
	291	if [[ -v _sev_setup_gpg_forward ]] {
	292	a=agent
	293	print -nP '%F{yellow}Forwarded%f '
	294	} else { a=Agent }
	295	print -nP '%F{green}'
79d4a356	296	}
6d54344e	297	gpg-connect-agent /bye >/dev/null 2>&1
	298	if [[ $? -ne 0 ]] {
	299	$p && print -P '%F{red}$a communication error'
	300	} else {
	301	if [[ ${+GPG_TTY} -eq 0 && -o interactive ]]
79d4a356	302	export GPG_TTY=$(tty)
6d54344e	303	if [[ ( -v DISPLAY \|\| -v WAYLAND_DISPLAY ) &&
	304	${PINENTRY_USER_DATA/USE_TTY=0} == $PINENTRY_USER_DATA ]]
	305	export PINENTRY_USER_DATA=USE_TTY=$((
	306	${+DISPLAY} + ${+WAYLAND_DISPLAY} == 0))
	307	# XXX: don't know if gpg-agent supports comments after directives
	308	# XXX: path could have #
	309	sed -Ei 's#^([[:space:]]pinentry-program[[:space:]]).$#\1'${commands[pinentry]:-/dev/null}'#' \
	310	${GNUPGHOME:-~/.gnupg}/gpg-agent.conf
	311	# XXX: could probably check for changes before doing this to save perf
	312	gpg-connect-agent RELOADAGENT UPDATESTARTUPTTY /bye >/dev/null 2>&1
	313	$p && gpg-connect-agent /subst /serverpid \
	314	"/echo $a pid \${get serverpid} on $GPG_TTY" /bye
	315	export _sev_setup_gpgagent=
79d4a356	316	}
6d54344e	317	$p && print -nP '%f'
	318	unset p a
	319	}
79d4a356	320
6d54344e	321	### ssh agent
6d54344e	322	if [[ ! -v _sev_setup_ssh ]] {
79d4a356	323	# NOTE: preferred order of agents to check: okcagent, gnupg, openssh
79d4a356	324	# first block takes care of okcagent and openssh, second gnupg
6d54344e	325	# XXX: doesn't actually check if ssh is enabled in gpg
79d4a356	326	[[ -o interactive ]] && print -nP '%F{blue}>>>%f SSH: %F{green}'
	327	if [[ ! -v SSH_AUTH_SOCK && ( -v commands[okc-ssh-agent] \|\|
	328	( -v commands[ssh-agent] && ! -v commands[gpg] ) ) ]] {
	329	okc=${commands[okc-ssh-agent]:+okc-}
6d54344e	330	t=${_sev_tmp:-${TMPDIR:-${TEMP:-${TMP:-/tmp}}}}
6d54344e	331	e=$t/${okc}ssh-agent-exports
79d4a356	332	typeset sock=
79d4a356	333	typeset -i pid=
6d54344e	334	if [[ -f $e ]] {
6d54344e	335	IFS=$'\0' read -r sock pid <$e
79d4a356	336	}
	337	if [[ -S $sock && $pid > 0 ]] && kill -0 $pid; then
	338	[[ -o interactive ]] && print -P "Reusing agent PID $pid%f"
	339	export SSH_AUTH_SOCK=$sock
	340	export SSH_AGENT_PID=$pid
	341	else
6d54344e	342	e='TMPDIR=$t ${okc}ssh-agent'
79d4a356	343	# TODO: ensure ssh-agent path looks legit to avoid unsafe eval?
	344	# XXX: doesn't appear to be any other way to handle redirection.
	345	# because eval needs to write to current scope environment
	346	# subshells can't be used to capture output and print.
	347	if [[ -o interactive ]] {
6d54344e	348	eval $(eval $=e)
79d4a356	349	print -nP '%f'
79d4a356	350	} else {
6d54344e	351	eval $(eval $=e) >/dev/null 2>&1
79d4a356	352	}
6d54344e	353	echo -n $SSH_AUTH_SOCK$'\0'$SSH_AGENT_PID >!$e
79d4a356	354	fi
6d54344e	355	unset okc t e sock pid
79d4a356	356	} elif [[ ! -v SSH_AUTH_SOCK && -v commands[gpg] ]] {
6d54344e	357	# since gpg should have been started above, just export and notify
79d4a356	358	if [[ -o interactive ]] {
6d54344e	359	if [[ -v _sev_setup_gpg_forward ]] {
6d54344e	360	echo 'Forwarded GPG agent'
79d4a356	361	} else {
79d4a356	362	gpg-connect-agent /subst /serverpid \
6d54344e	363	'/echo GPG agent pid ${get serverpid}' /bye
79d4a356	364	}
	365	print -nP '%f'
	366	}
6d54344e	367	export SSH_AUTH_SOCK=$(_gpg_socketpath \
79d4a356	368	$(gpgconf --list-dirs agent-ssh-socket))
	369	} elif [[ -v SSH_AUTH_SOCK ]] {
	370	[[ -o interactive ]] && print -P 'Preconfigured agent%f'
	371	} else {
	372	[[ -o interactive ]] && print -P '%F{red}No agent available%f'
	373	}
	374
6d54344e	375	export _sev_setup_ssh=
79d4a356	376	}
6d54344e	377	unfunction _gpg_socketpath
79d4a356	378
6d54344e	379	### perl local lib
	380	[[ -v commands[perl] && -d $XDG_DATA_HOME/perl5/lib/perl5 &&
	381	! -v PERL_LOCAL_LIB_ROOT ]] &&
	382	eval $(perl -I$XDG_DATA_HOME/perl5/lib/perl5 \
833b2af3	383	-Mlocal::lib=$XDG_DATA_HOME/perl5 2>/dev/null)
79d4a356	384
6d54344e	385
833b2af3	386	### load site-specific
8eb81f95	387	if [[ -f ~/.zprofile.local ]] { source ~/.zprofile.local }
8eb81f95	388
79d4a356	389	# vim: et sts=4 sw=4 ts=8 tw=79