vim: fork vim-lastplace for suda support

[dotfiles.git] / etc / vim / .vimrc

""" paths
"" config dir in xdg config
let x = ($XDG_CONFIG_HOME??($HOME.'/.config')).'/vim'
execute 'set runtimepath='.x.','.&runtimepath.','.x.'/after'
execute 'set packpath='.x.','.&packpath.','.x.'/after'

"" state files in xdg state
let x = ($XDG_STATE_HOME??($HOME.'/.local/state')).'/vim'
if !isdirectory(x)
    call mkdir(x, 'p', 0700)
endif

" backup
" NOTE: keep backup files in vim state dir for both vim and neovim
let y = x.'/backup'
if !isdirectory(y)
    call mkdir(y, 'p', 0700)
endif
execute 'set backupdir='.y.'//'
set backup backupcopy=yes

" NOTE: neovim uses ShaDa (SHAred DAta) format for viminfo and swap, and uses a
"       different version of undo file, so these types of files when created by
"       vim cannot be used with neovim, and the 'viminfofile', 'directory', and
"       'undodir' directories cannot be shared.
" NOTE: neovim has a nice default for these directories and files so
"       customizing them is not necessary for it.
if !has('nvim')
    " viminfo
    " NOTE: 'viminfofile' is a deprecated alias for 'shada' in neovim
    execute 'set viminfofile='.x.'/.viminfo'

    " swap
    let y = x.'/swap'
    if !isdirectory(y)
        call mkdir(y, 'p', 0700)
    endif
    execute 'set directory='.y.'//'

    " undo
    let y = x.'/undo'
    if !isdirectory(y)
        call mkdir(y, 'p', 0700)
    endif
    execute 'set undodir='.y.'//'
endif

unlet x
unlet y


""" vim-only defaults
if !has('nvim')
    " neovim defaults are already set
    source $VIMRUNTIME/defaults.vim

    " disable jumping to last edit, we use vim-lastplace instead
    autocmd! vimStartup

    " packages
    packadd! matchit        " included with [n]vim but disabled by default
    packadd! editorconfig   " now included with [n]vim but disabled by default
    packadd! vim-commentary " nvim has this built in now, vim still needs it

    " options
    set hlsearch
    autocmd BufRead * set autoindent
endif


""" package config
"" suda
" https://github.com/lambdalisue/vim-suda/issues/32#issuecomment-829608925
if ! &diff
    let g:suda_smart_edit = 1
endif
" re-enable backup, swap, undo for suda buffers that we can read
" https://github.com/lambdalisue/vim-suda/issues/25
function s:SudaSettingsSave()
    let l:f = expand('<afile>')
    if stridx(l:f, 'suda://') == 0
        let g:sev_suda_file = expand('<afile>')
        let g:sev_suda_backup = &backup
        let g:sev_suda_swapfile = &swapfile
        let g:sev_suda_undofile = &undofile
    endif
endfunction
function s:SudaSettingsRestore()
    if exists('g:sev_suda_file') && filereadable(g:sev_suda_file)
        if exists('g:sev_suda_backup') && g:sev_suda_backup
            " XXX: suda.vim uses setlocal for this, even though it's global...
            setlocal backup
        endif
        if exists('g:sev_suda_swapfile') && g:sev_suda_swapfile
            setlocal swapfile
        endif
        if exists('g:sev_suda_undofile') && g:sev_suda_undofile
            setlocal undofile
        endif
    endif
endfunction
autocmd BufReadPre * call s:SudaSettingsSave()
autocmd BufReadPost suda://* call s:SudaSettingsRestore()


""" styling
" nice default theme
colorscheme murphy

" always use color column with less intrusive colors
autocmd VimEnter,WinNew * set colorcolumn=80
" always use cursor line for better visibility
autocmd VimEnter,WinNew * set cursorline

" unique highlighting for leading spaces and in-line spaces
" NOTE: this leaves tabs and other special whitespace untouched intentionally
autocmd VimEnter,ColorScheme * highlight SpaceInner ctermfg=Grey guifg=#686868
autocmd VimEnter,ColorScheme * highlight link SpaceOuter NonText
autocmd VimEnter,WinNew * match SpaceInner / /
autocmd VimEnter,WinNew * 2match SpaceOuter /\(^ \+\)\|\( \+$\)/

" always show statusline
set laststatus=2

" truncate > lastline; lastline is nvim default, sensible.vim may also set it
set display=truncate

" more context while scrolling
set scrolloff=5
set sidescrolloff=8

" show number column on all buffers
autocmd VimEnter,WinNew * set number
" use relative numbers in normal modes when focused, but not if number is off
function! s:SetRelativeNumber(enable)
    if !getwinvar(winnr(), '&number')
        return
    endif
    if a:enable
        set relativenumber
    else
        set norelativenumber
    endif
endfunction
autocmd InsertEnter,FocusLost,WinLeave * call s:SetRelativeNumber(0)
autocmd VimEnter,WinNew,
       \InsertLeave,FocusGained,WinEnter * call s:SetRelativeNumber(1)

" always show custom listchars
autocmd VimEnter,WinNew * set list
set listchars=tab:├─,extends:»,precedes:«,space:·,trail:∙,nbsp:■


""" editor
" always save undo file for all file buffers
autocmd BufReadPre * setlocal undofile


" explicitly use modeline, even on systems where it's disabled by system vimrc
autocmd BufRead * set modeline
" should be default disabled but just in case
set nomodelineexpr

"" indent
" always use shiftwidth instead of tabsize
set smarttab
" filetype preferences
autocmd FileType python     set softtabstop=4 shiftwidth=4 expandtab
autocmd FileType markdown   set softtabstop=4 shiftwidth=4 expandtab
autocmd FileType javascript set softtabstop=2 shiftwidth=2 expandtab
autocmd FileType json       set softtabstop=2 shiftwidth=2 expandtab
autocmd FileType html       set softtabstop=2 shiftwidth=2 expandtab
let g:EditorConfig_enable_for_new_buf = 1

"" syntax
autocmd Syntax php          syn clear phpHereDoc phpNowDoc

"" mappings
" use more accessible escapes, as C-n and C-o are shadowed by some terminals
if has('nvim')
    tnoremap <C-\>n <C-\><C-N>
    tnoremap <C-\>o <C-\><C-O>
endif

" move windows any time
if has('nvim')
    " terminal
    tnoremap <A-h> <C-\><C-N><C-w>h
    tnoremap <A-j> <C-\><C-N><C-w>j
    tnoremap <A-k> <C-\><C-N><C-w>k
    tnoremap <A-l> <C-\><C-N><C-w>l
endif
" insert
inoremap <A-h> <C-\><C-N><C-w>h
inoremap <A-j> <C-\><C-N><C-w>j
inoremap <A-k> <C-\><C-N><C-w>k
inoremap <A-l> <C-\><C-N><C-w>l
" normal
nnoremap <A-h> <C-w>h
nnoremap <A-j> <C-w>j
nnoremap <A-k> <C-w>k
nnoremap <A-l> <C-w>l

"" CTRL-L to clear highlighting and also update diff
" NOTE: sensible.vim and nvim already do this, so copy sensible.vim
"       functionality if it hasn't been set or we aren't nvim. taken from
"       sensible.vim by Tim Pope, under Vim license; see :help license
"       https://github.com/tpope/vim-sensible/blob/0ce2d843d6f588bb0c8c7eec6449171615dc56d9/plugin/sensible.vim#L57
if !has('nvim') && maparg('<C-L>', 'n') ==# ''
  nnoremap <silent> <C-L> :nohlsearch<C-R>=has('diff')?'<Bar>diffupdate':''<CR><CR><C-L>
endif