update syslinux.cfg

[dotfiles.git] / base / .zshrc

### imports
source ~/bin/.check-busybox

### user-local fpath
fpath=(~/.zsh ~/.zsh/functions/Prompts "${fpath[@]}")

### options
setopt NO_BEEP NO_CLOBBER
## cd
setopt AUTO_CD CDABLE_VARS
## completion
setopt GLOB_COMPLETE
## line
setopt EXTENDED_GLOB GLOB_DOTS MARK_DIRS NOMATCH NUMERIC_GLOB_SORT
## prompt
setopt PROMPT_SUBST
## jobs
setopt AUTO_CONTINUE
## history
setopt NO_HIST_SAVE_BY_COPY HIST_IGNORE_DUPS SHARE_HISTORY
HISTFILE=~/.histfile
HISTSIZE=1000
SAVEHIST=1000

### keys
bindkey -v
KEYTIMEOUT=1
## xorg
bindkey    "^[[7~" beginning-of-line #Home
bindkey -a "^[[7~" beginning-of-line
bindkey    "^[[8~" end-of-line       #End
bindkey -a "^[[8~" end-of-line
bindkey    "^[[3~" delete-char       #Del
bindkey -a "^[[3~" delete-char
## history search
autoload -Uz up-line-or-beginning-search down-line-or-beginning-search && {
    if [[ -n "$key[Up]" ]] {
        zle -N up-line-or-beginning-search
        bindkey -- "$key[Up]"   up-line-or-beginning-search
    }
    if [[ -n "$key[Down]" ]] {
        bindkey -- "$key[Down]" down-line-or-beginning-search
        zle -N down-line-or-beginning-search
    }
}

### aliases
alias h="history -25"
alias j="jobs -l"
alias l="ls -AF"
alias e="${EDITOR:-vi}" # TODO: make sure vi is there or use safe default
if [[ "$OSTYPE" =~ '^(free|net)bsd' ]] {
    alias ll="ls -lAFho"
} else {
    alias ll="ls -lAFh"
}
alias se=sudoedit
## ps
local p=
if which pstree >/dev/null 2>&1 && ! check-busybox pstree; then
    # use pstree, but NOT busybox pstree because it kinda sucks
    p="pstree -wg3"
elif [[ "$OSTYPE" =~ '^freebsd' ]]; then
    p="ps -aSdfxwwouser=USR -ogroup=GRP -opid,nice=NI \
       -o%cpu,%mem,tty,stat,start=START -oetime,command"
elif check-busybox ps; then
    # busybox compatible
    p="ps -eouser='USR     ' -ogroup='GRP     ' \
       -opid='  PID' -onice=' NI' -ovsz=' MEM' \
       -otty,stat,etime,comm"
else
    # XXX: untested, posix
    # TODO: support gnu ps
    p="ps -eouser=USR -ogroup=GRP -opid,nice=NI \
       -opcpu=CPU -ovsz=MEM -otty,stat,etime,comm"
fi
if [[ "$(basename "$PAGER")" = "less" ]] {
    p="$p | less -SE"
} else {
    p="$p | \"${PAGER:-more}\""
}
alias pa="$p"
alias spa="sudo $p"
unset p
## py venv
alias va="source bin/activate"
alias vd="deactivate"
## be paranoid
alias cp='cp -ip'
alias mv='mv -i'
if [[ "$OSTYPE" =~ '^freebsd' ]] {
    # don't confirm if only a few files are deleted
    alias rm='rm -I'
} else {
    # TODO: similar behavior for non-freebsd, or impliment in zsh
    alias rm='rm -i'
}
## go up directories
function up() {
    cd $(printf '../%.0s' {1..${1:-1}})
}

### hooks
local _exectime=
function precmd {
    # change terminal title
    # TODO: update and send BEL when job status changes
    print -Pn "\e]2;%(1j,%j,)%#${SSH_CLIENT+$USER@$HOST:}%~\e\\"
    # bell if exec takes 5s
    if ((SECONDS - _exectime >= 5)) print "\a"
    # we could update vcs_info here, but let prompt take care of it
    # if it doesn't use vcs, it can be ignored safely
}
function preexec {
    # change terminal title to show command
    print -Pnf "\e]2;%s\e\\" "%#${SSH_CLIENT+$USER@$HOST:}$1"
    # save last exec time for bell
    # XXX: does not run for blank cmdline
    _exectime=$SECONDS
}
function chpwd {
    # echo dir on cwd change
    l
}

### system-specific configs and aliases
case "$OSTYPE"; in
    freebsd*)
        ## vt binds
        bindkey    "^[[H" beginning-of-line  #Home
        bindkey -a "^[[H" beginning-of-line
        bindkey    "^[[F" end-of-line        #End
        bindkey -a "^[[F" end-of-line

        ## sound
        function s { sysctl hw.snd.default_unit${1:+\=$1} }
        alias vol mixer

        ## install port dependencies from pkg (like pkgsrc `bmake bin-install')
        #XXX: should probably use package-depends where possible, breaks when
        #     port name is different to package name
        #     (eg. graphics/sdl20 == sdl2, devel/glib20 == glib2, etc)
        function portpkg {
            case "$1" {
            build|run)
                sudo pkg install -AU $(make ${1}-depends-list |
                           sed 's_/usr/ports/_ _' | tr -d '\n')
                ;;
            *)  echo "Usage: \`portpkg <build|run>' in a port directory"
                return 1;;
            }
        };;
    netbsd)
        ## sound
        function s {
            if [[ -z "$1" ]] {
                ll /dev/mixer /dev/sound /dev/audio
                return
            }
            for x in mixer sound audio; do
                ln -sf /dev/$x"$1" /dev/$x
            done
        }
        function vol {
            if [[ -z "$1" ]] {
                for x in $(mixerctl -a | grep 'outputs\.master'); do
                    echo $x
                done
                return
            }
            mixerctl -w outputs.master"$2"="$1"
        };;
    *)
        ## sound
        # TODO: test alsa/oss/sndio/portaudio/pulse in order of importance
        function s() {}
        function vol() {}
esac

### modules & styles
## vcs
autoload -Uz vcs_info
zstyle ':vcs_info:*' enable git
#zstyle ':vcs_info:git*' check-for-changes true #too slow
zstyle ':vcs_info:git*:dotfiles' check-for-changes true
zstyle ':vcs_info:git*' check-for-staged-changes true

## compinit
# The following lines were added by compinstall
zstyle ':completion:*' auto-description '[arg] %d'
zstyle ':completion:*' expand suffix
zstyle ':completion:*' format '# %d'
zstyle ':completion:*' group-name ''
zstyle ':completion:*' ignore-parents parent
zstyle ':completion:*' insert-unambiguous false
zstyle ':completion:*' list-colors ${(s.:.)LS_COLORS}
zstyle ':completion:*' list-prompt '%B%i%b'
zstyle ':completion:*' list-suffixes true
zstyle ':completion:*' matcher-list '' 'm:{[:lower:]}={[:upper:]}' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} r:|[._-]=* r:|=*' 'm:{[:lower:][:upper:]}={[:upper:][:lower:]} l:|=* r:|=*'
zstyle ':completion:*' menu select=1
zstyle ':completion:*' original false
zstyle ':completion:*' select-prompt '%B%l%b'
zstyle ':completion:*' verbose true
zstyle :compinstall filename '/home/ds6/.zshrc'

autoload -Uz compinit
compinit
# End of lines added by compinstall

## prompt
# do this last so prompt can potentially override
autoload -Uz promptinit && promptinit
prompt arrows


### unset imports
unfunction check-busybox

# vim: set et sts=4 sw=4 ts=8 tw=79 :